Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

interface IInterestRateModel {
  // Returns asset/second of interest per borrowed unit
  // e.g : (0.01 * PRECISION) = 1% of interest per second
  function getBorrowRate(uint256 utilization) external view returns (uint256);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

interface IRateModelV1 {
  /**
   * @param x The x value, between 0-1. scaled by PRECISION
   */
  function getRate(uint256 x) external view returns (uint256);
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import {IRateModelV1} from "../../../../Lynx/interfaces/IRateModelV1.sol";

/**
 * @title BaseSingleKinkRateModel
 * @dev Base contract for single kink rate models
 */
contract BaseSingleKinkRateModel is IRateModelV1 {
  uint public constant PRECISION = 1e18;

  /**
   * @notice The base rate which is the y-intercept when X = 0
   */
  uint256 public baseRate;

  /**
   * @notice The multiplier of utilization rate that gives the slope of the rate
   */
  uint256 public multiplier;

  /**
   * @notice The point at which the 'postKinkMultiplier' is applied
   */
  uint256 public kink;

  /**
   * @notice The multiplier when X > kink
   */
  uint256 public postKinkMultiplier;

  /**
   * @notice The rate when X = kink
   * @dev Saves gas on reading storage variables
   */
  uint256 public rateOnKink;

  event NewRateParams(
    uint256 baseRate,
    uint256 multiplier,
    uint256 kink,
    uint256 postKinkMultiplier,
    uint256 rateOnKink
  );

  function getRate(uint256 x) external view returns (uint256) {
    return getRateInternal(x);
  }

  function setRateParamsInternal(
    uint256 _baseRate,
    uint256 _multiplier,
    uint256 _kink,
    uint256 _postKinkMultiplier
  ) internal {
    // Sanity, kink cannot be higher than 100%
    require(_kink <= PRECISION, "KINK_TOO_HIGH");

    // Set rate params
    baseRate = _baseRate;
    multiplier = _multiplier;
    kink = _kink;
    postKinkMultiplier = _postKinkMultiplier;

    // Calculate rateOnKink
    rateOnKink = (kink * multiplier) / PRECISION + baseRate;

    // Event
    emit NewRateParams(
      _baseRate,
      _multiplier,
      _kink,
      _postKinkMultiplier,
      rateOnKink
    );
  }

  function getRateInternal(uint256 x) internal view returns (uint256) {
    uint256 safeX = x > PRECISION ? PRECISION : x;
    uint256 _kink = kink;

    if (x <= _kink) {
      return (x * multiplier) / PRECISION + baseRate;
    } else {
      uint excess = safeX - _kink;
      return (excess * postKinkMultiplier) / PRECISION + rateOnKink;
    }
  }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/access/Ownable.sol";
import "./BaseSingleKinkRateModel.sol";

/**
 * @title MutableSingleKinkRateModel
 * @dev Single kink rate model with the ability to change rate parameters
 */
contract MutableSingleKinkRateModel is Ownable, BaseSingleKinkRateModel {
  constructor(address _initialOwner) Ownable(_initialOwner) {}

  function setRateParams(
    uint256 _baseRate,
    uint256 _multiplier,
    uint256 _kink,
    uint256 _postKinkMultiplier
  ) external onlyOwner {
    setRateParamsInternal(_baseRate, _multiplier, _kink, _postKinkMultiplier);
  }
}

// SPDX-License-Identifier: BUSL-1.1
pragma solidity ^0.8.24;

import "../../../Lynx/interfaces/IInterestRateModel.sol";
import "../BaseModels/SingleKinkRateModel/MutableSingleKinkRateModel.sol";

/**
 * @title MutableSingleKinkInterestRateModel
 * @dev Single kink rate model for interest rates with the ability to change rate parameters
 */
contract MutableSingleKinkInterestRateModel is
  MutableSingleKinkRateModel,
  IInterestRateModel
{
  constructor() MutableSingleKinkRateModel(msg.sender) {}

  function getBorrowRate(
    uint256 utilization
  ) external view override returns (uint256) {
    return getRateInternal(utilization);
  }
}