Contract Source Code:

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.26;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

/**
 * Token Toolbox: Multi Sender/Airdrop tokens distributor
 * https://tokentoolbox.app
 */
contract MultiSender {
    address public immutable treasury;

    error InvalidTokenError();
    error InvalidParamsError();
    error TransferError();

    constructor(address treasury_) {
        treasury = treasury_;
    }

    /**
     * @dev Send the same amount of tokens or ETH to a list of addresses
     */
    function transferSingle(address token, uint256 amount, address[] calldata addresses) external payable {
        if (token == address(0)) {
            for (uint256 i = 0; i < addresses.length; i++) payable(addresses[i]).transfer(amount);
        } else {
            if (token.code.length == 0) revert InvalidTokenError(); // must be a contract
            for (uint256 i = 0; i < addresses.length; i++) _sendTokens(token, addresses[i], amount);
        }
        _sendFees();
    }

    /**
     * @dev Send tokens or ETH to a list of addresses
     */
    function transfer(address token, address[] calldata addresses, uint256[] calldata amounts) external payable {
        if (addresses.length != amounts.length) revert InvalidParamsError();

        if (token == address(0)) {
            for (uint256 i = 0; i < addresses.length; i++) payable(addresses[i]).transfer(amounts[i]);
        } else {
            if (token.code.length == 0) revert InvalidTokenError(); // must be a contract
            for (uint256 i = 0; i < addresses.length; i++) _sendTokens(token, addresses[i], amounts[i]);
        }
        _sendFees();
    }

    /**
     * @dev Recover tokens or ETH
     */
    function recover(address token, uint256 amount) external {
        if (amount == 0) revert InvalidParamsError();

        if (token == address(0)) {
            payable(treasury).transfer(amount);
        } else {
            (bool success, ) = token.call(abi.encodeCall(IERC20.transfer, (treasury, amount)));
            if (!success) revert TransferError();
        }
    }

    function _sendTokens(address token, address to, uint256 amount) private {
        (bool success, ) = token.call(abi.encodeCall(IERC20.transferFrom, (msg.sender, to, amount)));
        if (!success) revert TransferError();
    }

    function _sendFees() private {
        uint256 balance = address(this).balance;
        if (treasury != address(0) && balance > 0) {
            payable(treasury).transfer(balance);
        }
    }
}