Contract Source Code:
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)
pragma solidity ^0.8.0;
/**
* @dev Contract module that helps prevent reentrant calls to a function.
*
* Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
* available, which can be applied to functions to make sure there are no nested
* (reentrant) calls to them.
*
* Note that because there is a single `nonReentrant` guard, functions marked as
* `nonReentrant` may not call one another. This can be worked around by making
* those functions `private`, and then adding `external` `nonReentrant` entry
* points to them.
*
* TIP: If you would like to learn more about reentrancy and alternative ways
* to protect against it, check out our blog post
* https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
*/
abstract contract ReentrancyGuard {
// Booleans are more expensive than uint256 or any type that takes up a full
// word because each write operation emits an extra SLOAD to first read the
// slot's contents, replace the bits taken up by the boolean, and then write
// back. This is the compiler's defense against contract upgrades and
// pointer aliasing, and it cannot be disabled.
// The values being non-zero value makes deployment a bit more expensive,
// but in exchange the refund on every call to nonReentrant will be lower in
// amount. Since refunds are capped to a percentage of the total
// transaction's gas, it is best to keep them low in cases like this one, to
// increase the likelihood of the full refund coming into effect.
uint256 private constant _NOT_ENTERED = 1;
uint256 private constant _ENTERED = 2;
uint256 private _status;
constructor() {
_status = _NOT_ENTERED;
}
/**
* @dev Prevents a contract from calling itself, directly or indirectly.
* Calling a `nonReentrant` function from another `nonReentrant`
* function is not supported. It is possible to prevent this from happening
* by making the `nonReentrant` function external, and making it call a
* `private` function that does the actual work.
*/
modifier nonReentrant() {
_nonReentrantBefore();
_;
_nonReentrantAfter();
}
function _nonReentrantBefore() private {
// On the first call to nonReentrant, _status will be _NOT_ENTERED
require(_status != _ENTERED, "ReentrancyGuard: reentrant call");
// Any calls to nonReentrant after this point will fail
_status = _ENTERED;
}
function _nonReentrantAfter() private {
// By storing the original value once again, a refund is triggered (see
// https://eips.ethereum.org/EIPS/eip-2200)
_status = _NOT_ENTERED;
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)
pragma solidity ^0.8.0;
import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";
/**
* @dev Implementation of the {IERC20} interface.
*
* This implementation is agnostic to the way tokens are created. This means
* that a supply mechanism has to be added in a derived contract using {_mint}.
* For a generic mechanism see {ERC20PresetMinterPauser}.
*
* TIP: For a detailed writeup see our guide
* https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
* to implement supply mechanisms].
*
* We have followed general OpenZeppelin Contracts guidelines: functions revert
* instead returning `false` on failure. This behavior is nonetheless
* conventional and does not conflict with the expectations of ERC20
* applications.
*
* Additionally, an {Approval} event is emitted on calls to {transferFrom}.
* This allows applications to reconstruct the allowance for all accounts just
* by listening to said events. Other implementations of the EIP may not emit
* these events, as it isn't required by the specification.
*
* Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
* functions have been added to mitigate the well-known issues around setting
* allowances. See {IERC20-approve}.
*/
contract ERC20 is Context, IERC20, IERC20Metadata {
mapping(address => uint256) private _balances;
mapping(address => mapping(address => uint256)) private _allowances;
uint256 private _totalSupply;
string private _name;
string private _symbol;
/**
* @dev Sets the values for {name} and {symbol}.
*
* The default value of {decimals} is 18. To select a different value for
* {decimals} you should overload it.
*
* All two of these values are immutable: they can only be set once during
* construction.
*/
constructor(string memory name_, string memory symbol_) {
_name = name_;
_symbol = symbol_;
}
/**
* @dev Returns the name of the token.
*/
function name() public view virtual override returns (string memory) {
return _name;
}
/**
* @dev Returns the symbol of the token, usually a shorter version of the
* name.
*/
function symbol() public view virtual override returns (string memory) {
return _symbol;
}
/**
* @dev Returns the number of decimals used to get its user representation.
* For example, if `decimals` equals `2`, a balance of `505` tokens should
* be displayed to a user as `5.05` (`505 / 10 ** 2`).
*
* Tokens usually opt for a value of 18, imitating the relationship between
* Ether and Wei. This is the value {ERC20} uses, unless this function is
* overridden;
*
* NOTE: This information is only used for _display_ purposes: it in
* no way affects any of the arithmetic of the contract, including
* {IERC20-balanceOf} and {IERC20-transfer}.
*/
function decimals() public view virtual override returns (uint8) {
return 18;
}
/**
* @dev See {IERC20-totalSupply}.
*/
function totalSupply() public view virtual override returns (uint256) {
return _totalSupply;
}
/**
* @dev See {IERC20-balanceOf}.
*/
function balanceOf(address account) public view virtual override returns (uint256) {
return _balances[account];
}
/**
* @dev See {IERC20-transfer}.
*
* Requirements:
*
* - `to` cannot be the zero address.
* - the caller must have a balance of at least `amount`.
*/
function transfer(address to, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_transfer(owner, to, amount);
return true;
}
/**
* @dev See {IERC20-allowance}.
*/
function allowance(address owner, address spender) public view virtual override returns (uint256) {
return _allowances[owner][spender];
}
/**
* @dev See {IERC20-approve}.
*
* NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
* `transferFrom`. This is semantically equivalent to an infinite approval.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function approve(address spender, uint256 amount) public virtual override returns (bool) {
address owner = _msgSender();
_approve(owner, spender, amount);
return true;
}
/**
* @dev See {IERC20-transferFrom}.
*
* Emits an {Approval} event indicating the updated allowance. This is not
* required by the EIP. See the note at the beginning of {ERC20}.
*
* NOTE: Does not update the allowance if the current allowance
* is the maximum `uint256`.
*
* Requirements:
*
* - `from` and `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
* - the caller must have allowance for ``from``'s tokens of at least
* `amount`.
*/
function transferFrom(
address from,
address to,
uint256 amount
) public virtual override returns (bool) {
address spender = _msgSender();
_spendAllowance(from, spender, amount);
_transfer(from, to, amount);
return true;
}
/**
* @dev Atomically increases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC20-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
*/
function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
address owner = _msgSender();
_approve(owner, spender, allowance(owner, spender) + addedValue);
return true;
}
/**
* @dev Atomically decreases the allowance granted to `spender` by the caller.
*
* This is an alternative to {approve} that can be used as a mitigation for
* problems described in {IERC20-approve}.
*
* Emits an {Approval} event indicating the updated allowance.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `spender` must have allowance for the caller of at least
* `subtractedValue`.
*/
function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
address owner = _msgSender();
uint256 currentAllowance = allowance(owner, spender);
require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
unchecked {
_approve(owner, spender, currentAllowance - subtractedValue);
}
return true;
}
/**
* @dev Moves `amount` of tokens from `from` to `to`.
*
* This internal function is equivalent to {transfer}, and can be used to
* e.g. implement automatic token fees, slashing mechanisms, etc.
*
* Emits a {Transfer} event.
*
* Requirements:
*
* - `from` cannot be the zero address.
* - `to` cannot be the zero address.
* - `from` must have a balance of at least `amount`.
*/
function _transfer(
address from,
address to,
uint256 amount
) internal virtual {
require(from != address(0), "ERC20: transfer from the zero address");
require(to != address(0), "ERC20: transfer to the zero address");
_beforeTokenTransfer(from, to, amount);
uint256 fromBalance = _balances[from];
require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
unchecked {
_balances[from] = fromBalance - amount;
// Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
// decrementing then incrementing.
_balances[to] += amount;
}
emit Transfer(from, to, amount);
_afterTokenTransfer(from, to, amount);
}
/** @dev Creates `amount` tokens and assigns them to `account`, increasing
* the total supply.
*
* Emits a {Transfer} event with `from` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
*/
function _mint(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC20: mint to the zero address");
_beforeTokenTransfer(address(0), account, amount);
_totalSupply += amount;
unchecked {
// Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
_balances[account] += amount;
}
emit Transfer(address(0), account, amount);
_afterTokenTransfer(address(0), account, amount);
}
/**
* @dev Destroys `amount` tokens from `account`, reducing the
* total supply.
*
* Emits a {Transfer} event with `to` set to the zero address.
*
* Requirements:
*
* - `account` cannot be the zero address.
* - `account` must have at least `amount` tokens.
*/
function _burn(address account, uint256 amount) internal virtual {
require(account != address(0), "ERC20: burn from the zero address");
_beforeTokenTransfer(account, address(0), amount);
uint256 accountBalance = _balances[account];
require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
unchecked {
_balances[account] = accountBalance - amount;
// Overflow not possible: amount <= accountBalance <= totalSupply.
_totalSupply -= amount;
}
emit Transfer(account, address(0), amount);
_afterTokenTransfer(account, address(0), amount);
}
/**
* @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
*
* This internal function is equivalent to `approve`, and can be used to
* e.g. set automatic allowances for certain subsystems, etc.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `owner` cannot be the zero address.
* - `spender` cannot be the zero address.
*/
function _approve(
address owner,
address spender,
uint256 amount
) internal virtual {
require(owner != address(0), "ERC20: approve from the zero address");
require(spender != address(0), "ERC20: approve to the zero address");
_allowances[owner][spender] = amount;
emit Approval(owner, spender, amount);
}
/**
* @dev Updates `owner` s allowance for `spender` based on spent `amount`.
*
* Does not update the allowance amount in case of infinite allowance.
* Revert if not enough allowance is available.
*
* Might emit an {Approval} event.
*/
function _spendAllowance(
address owner,
address spender,
uint256 amount
) internal virtual {
uint256 currentAllowance = allowance(owner, spender);
if (currentAllowance != type(uint256).max) {
require(currentAllowance >= amount, "ERC20: insufficient allowance");
unchecked {
_approve(owner, spender, currentAllowance - amount);
}
}
}
/**
* @dev Hook that is called before any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* will be transferred to `to`.
* - when `from` is zero, `amount` tokens will be minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens will be burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _beforeTokenTransfer(
address from,
address to,
uint256 amount
) internal virtual {}
/**
* @dev Hook that is called after any transfer of tokens. This includes
* minting and burning.
*
* Calling conditions:
*
* - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
* has been transferred to `to`.
* - when `from` is zero, `amount` tokens have been minted for `to`.
* - when `to` is zero, `amount` of ``from``'s tokens have been burned.
* - `from` and `to` are never both zero.
*
* To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
*/
function _afterTokenTransfer(
address from,
address to,
uint256 amount
) internal virtual {}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
* https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
*
* Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
* presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
* need to send a transaction, and thus is not required to hold Ether at all.
*/
interface IERC20Permit {
/**
* @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
* given ``owner``'s signed approval.
*
* IMPORTANT: The same issues {IERC20-approve} has related to transaction
* ordering also apply here.
*
* Emits an {Approval} event.
*
* Requirements:
*
* - `spender` cannot be the zero address.
* - `deadline` must be a timestamp in the future.
* - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
* over the EIP712-formatted function arguments.
* - the signature must use ``owner``'s current nonce (see {nonces}).
*
* For more information on the signature format, see the
* https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
* section].
*/
function permit(
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) external;
/**
* @dev Returns the current nonce for `owner`. This value must be
* included whenever a signature is generated for {permit}.
*
* Every successful call to {permit} increases ``owner``'s nonce by one. This
* prevents a signature from being used multiple times.
*/
function nonces(address owner) external view returns (uint256);
/**
* @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
*/
// solhint-disable-next-line func-name-mixedcase
function DOMAIN_SEPARATOR() external view returns (bytes32);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
/**
* @dev Interface for the optional metadata functions from the ERC20 standard.
*
* _Available since v4.1._
*/
interface IERC20Metadata is IERC20 {
/**
* @dev Returns the name of the token.
*/
function name() external view returns (string memory);
/**
* @dev Returns the symbol of the token.
*/
function symbol() external view returns (string memory);
/**
* @dev Returns the decimals places of the token.
*/
function decimals() external view returns (uint8);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)
pragma solidity ^0.8.0;
/**
* @dev Interface of the ERC20 standard as defined in the EIP.
*/
interface IERC20 {
/**
* @dev Emitted when `value` tokens are moved from one account (`from`) to
* another (`to`).
*
* Note that `value` may be zero.
*/
event Transfer(address indexed from, address indexed to, uint256 value);
/**
* @dev Emitted when the allowance of a `spender` for an `owner` is set by
* a call to {approve}. `value` is the new allowance.
*/
event Approval(address indexed owner, address indexed spender, uint256 value);
/**
* @dev Returns the amount of tokens in existence.
*/
function totalSupply() external view returns (uint256);
/**
* @dev Returns the amount of tokens owned by `account`.
*/
function balanceOf(address account) external view returns (uint256);
/**
* @dev Moves `amount` tokens from the caller's account to `to`.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transfer(address to, uint256 amount) external returns (bool);
/**
* @dev Returns the remaining number of tokens that `spender` will be
* allowed to spend on behalf of `owner` through {transferFrom}. This is
* zero by default.
*
* This value changes when {approve} or {transferFrom} are called.
*/
function allowance(address owner, address spender) external view returns (uint256);
/**
* @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* IMPORTANT: Beware that changing an allowance with this method brings the risk
* that someone may use both the old and the new allowance by unfortunate
* transaction ordering. One possible solution to mitigate this race
* condition is to first reduce the spender's allowance to 0 and set the
* desired value afterwards:
* https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
*
* Emits an {Approval} event.
*/
function approve(address spender, uint256 amount) external returns (bool);
/**
* @dev Moves `amount` tokens from `from` to `to` using the
* allowance mechanism. `amount` is then deducted from the caller's
* allowance.
*
* Returns a boolean value indicating whether the operation succeeded.
*
* Emits a {Transfer} event.
*/
function transferFrom(
address from,
address to,
uint256 amount
) external returns (bool);
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)
pragma solidity ^0.8.0;
import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";
/**
* @title SafeERC20
* @dev Wrappers around ERC20 operations that throw on failure (when the token
* contract returns false). Tokens that return no value (and instead revert or
* throw on failure) are also supported, non-reverting calls are assumed to be
* successful.
* To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
* which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
*/
library SafeERC20 {
using Address for address;
function safeTransfer(
IERC20 token,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
}
function safeTransferFrom(
IERC20 token,
address from,
address to,
uint256 value
) internal {
_callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
}
/**
* @dev Deprecated. This function has issues similar to the ones found in
* {IERC20-approve}, and its usage is discouraged.
*
* Whenever possible, use {safeIncreaseAllowance} and
* {safeDecreaseAllowance} instead.
*/
function safeApprove(
IERC20 token,
address spender,
uint256 value
) internal {
// safeApprove should only be called when setting an initial allowance,
// or when resetting it to zero. To increase and decrease it, use
// 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
require(
(value == 0) || (token.allowance(address(this), spender) == 0),
"SafeERC20: approve from non-zero to non-zero allowance"
);
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
}
function safeIncreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
uint256 newAllowance = token.allowance(address(this), spender) + value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
function safeDecreaseAllowance(
IERC20 token,
address spender,
uint256 value
) internal {
unchecked {
uint256 oldAllowance = token.allowance(address(this), spender);
require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
uint256 newAllowance = oldAllowance - value;
_callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
}
}
function safePermit(
IERC20Permit token,
address owner,
address spender,
uint256 value,
uint256 deadline,
uint8 v,
bytes32 r,
bytes32 s
) internal {
uint256 nonceBefore = token.nonces(owner);
token.permit(owner, spender, value, deadline, v, r, s);
uint256 nonceAfter = token.nonces(owner);
require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
}
/**
* @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
* on the return value: the return value is optional (but if data is returned, it must not be false).
* @param token The token targeted by the call.
* @param data The call data (encoded using abi.encode or one of its variants).
*/
function _callOptionalReturn(IERC20 token, bytes memory data) private {
// We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
// we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
// the target address contains contract code and also asserts for success in the low-level call.
bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
if (returndata.length > 0) {
// Return data is optional
require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)
pragma solidity ^0.8.1;
/**
* @dev Collection of functions related to the address type
*/
library Address {
/**
* @dev Returns true if `account` is a contract.
*
* [IMPORTANT]
* ====
* It is unsafe to assume that an address for which this function returns
* false is an externally-owned account (EOA) and not a contract.
*
* Among others, `isContract` will return false for the following
* types of addresses:
*
* - an externally-owned account
* - a contract in construction
* - an address where a contract will be created
* - an address where a contract lived, but was destroyed
* ====
*
* [IMPORTANT]
* ====
* You shouldn't rely on `isContract` to protect against flash loan attacks!
*
* Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
* like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
* constructor.
* ====
*/
function isContract(address account) internal view returns (bool) {
// This method relies on extcodesize/address.code.length, which returns 0
// for contracts in construction, since the code is only stored at the end
// of the constructor execution.
return account.code.length > 0;
}
/**
* @dev Replacement for Solidity's `transfer`: sends `amount` wei to
* `recipient`, forwarding all available gas and reverting on errors.
*
* https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
* of certain opcodes, possibly making contracts go over the 2300 gas limit
* imposed by `transfer`, making them unable to receive funds via
* `transfer`. {sendValue} removes this limitation.
*
* https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
*
* IMPORTANT: because control is transferred to `recipient`, care must be
* taken to not create reentrancy vulnerabilities. Consider using
* {ReentrancyGuard} or the
* https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
*/
function sendValue(address payable recipient, uint256 amount) internal {
require(address(this).balance >= amount, "Address: insufficient balance");
(bool success, ) = recipient.call{value: amount}("");
require(success, "Address: unable to send value, recipient may have reverted");
}
/**
* @dev Performs a Solidity function call using a low level `call`. A
* plain `call` is an unsafe replacement for a function call: use this
* function instead.
*
* If `target` reverts with a revert reason, it is bubbled up by this
* function (like regular Solidity function calls).
*
* Returns the raw returned data. To convert to the expected return value,
* use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
*
* Requirements:
*
* - `target` must be a contract.
* - calling `target` with `data` must not revert.
*
* _Available since v3.1._
*/
function functionCall(address target, bytes memory data) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, "Address: low-level call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
* `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
return functionCallWithValue(target, data, 0, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but also transferring `value` wei to `target`.
*
* Requirements:
*
* - the calling contract must have an ETH balance of at least `value`.
* - the called Solidity function must be `payable`.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value
) internal returns (bytes memory) {
return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
}
/**
* @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
* with `errorMessage` as a fallback revert reason when `target` reverts.
*
* _Available since v3.1._
*/
function functionCallWithValue(
address target,
bytes memory data,
uint256 value,
string memory errorMessage
) internal returns (bytes memory) {
require(address(this).balance >= value, "Address: insufficient balance for call");
(bool success, bytes memory returndata) = target.call{value: value}(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
return functionStaticCall(target, data, "Address: low-level static call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a static call.
*
* _Available since v3.3._
*/
function functionStaticCall(
address target,
bytes memory data,
string memory errorMessage
) internal view returns (bytes memory) {
(bool success, bytes memory returndata) = target.staticcall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
return functionDelegateCall(target, data, "Address: low-level delegate call failed");
}
/**
* @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
* but performing a delegate call.
*
* _Available since v3.4._
*/
function functionDelegateCall(
address target,
bytes memory data,
string memory errorMessage
) internal returns (bytes memory) {
(bool success, bytes memory returndata) = target.delegatecall(data);
return verifyCallResultFromTarget(target, success, returndata, errorMessage);
}
/**
* @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
* the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
*
* _Available since v4.8._
*/
function verifyCallResultFromTarget(
address target,
bool success,
bytes memory returndata,
string memory errorMessage
) internal view returns (bytes memory) {
if (success) {
if (returndata.length == 0) {
// only check isContract if the call was successful and the return data is empty
// otherwise we already know that it was a contract
require(isContract(target), "Address: call to non-contract");
}
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
/**
* @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
* revert reason or using the provided one.
*
* _Available since v4.3._
*/
function verifyCallResult(
bool success,
bytes memory returndata,
string memory errorMessage
) internal pure returns (bytes memory) {
if (success) {
return returndata;
} else {
_revert(returndata, errorMessage);
}
}
function _revert(bytes memory returndata, string memory errorMessage) private pure {
// Look for revert reason and bubble it up if present
if (returndata.length > 0) {
// The easiest way to bubble the revert reason is using memory via assembly
/// @solidity memory-safe-assembly
assembly {
let returndata_size := mload(returndata)
revert(add(32, returndata), returndata_size)
}
} else {
revert(errorMessage);
}
}
}
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)
pragma solidity ^0.8.0;
/**
* @dev Provides information about the current execution context, including the
* sender of the transaction and its data. While these are generally available
* via msg.sender and msg.data, they should not be accessed in such a direct
* manner, since when dealing with meta-transactions the account sending and
* paying for execution may not be the actual sender (as far as an application
* is concerned).
*
* This contract is only required for intermediate, library-like contracts.
*/
abstract contract Context {
function _msgSender() internal view virtual returns (address) {
return msg.sender;
}
function _msgData() internal view virtual returns (bytes calldata) {
return msg.data;
}
}
// SPDX-License-Identifier: MIT
pragma solidity ^0.8.11;
import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
interface IGumBallFactory {
function getTreasury() external view returns (address);
}
interface IXGBT {
function balanceOf(address account) external view returns (uint256);
function notifyRewardAmount(address _rewardsToken, uint256 reward) external;
}
interface IGBT {
function getXGBT() external view returns (address);
function getFactory() external view returns (address);
function artistTreasury() external view returns (address);
}
contract GBTFees is ReentrancyGuard {
using SafeERC20 for IERC20;
address internal immutable _GBT;
address internal immutable _BASE;
uint256 public constant TREASURY = 200;
uint256 public constant GUMBAR = 400;
uint256 public constant ARTIST = 400;
uint256 public constant REWARD = 10;
uint256 public constant DIVISOR = 1000;
event Distribute(address indexed user);
constructor(address __GBT, address __BASE) {
_GBT = __GBT;
_BASE = __BASE;
}
function distributeReward() external view returns (uint256) {
return IERC20(_BASE).balanceOf(address(this)) * REWARD / DIVISOR;
}
function distributeFees() external nonReentrant {
uint256 balanceGBT = IERC20(_GBT).balanceOf(address(this));
uint256 balanceBASE = IERC20(_BASE).balanceOf(address(this));
uint256 reward = balanceBASE * REWARD / DIVISOR;
balanceBASE -= reward;
address treasury = IGumBallFactory(IGBT(_GBT).getFactory()).getTreasury();
address artist = IGBT(_GBT).artistTreasury();
address _xgbt = IGBT(_GBT).getXGBT();
// Distribute GBT
IERC20(_GBT).safeApprove(_xgbt, 0);
IERC20(_GBT).safeApprove(_xgbt, balanceGBT * GUMBAR / DIVISOR);
IXGBT(_xgbt).notifyRewardAmount(_GBT, balanceGBT * GUMBAR / DIVISOR);
IERC20(_GBT).safeTransfer(artist, balanceGBT * ARTIST / DIVISOR);
IERC20(_GBT).safeTransfer(treasury, balanceGBT * TREASURY / DIVISOR);
// Distribute BASE
IERC20(_BASE).safeApprove(_xgbt, 0);
IERC20(_BASE).safeApprove(_xgbt, balanceBASE * GUMBAR / DIVISOR);
IXGBT(_xgbt).notifyRewardAmount(_BASE, balanceBASE * GUMBAR / DIVISOR);
IERC20(_BASE).safeTransfer(artist, balanceBASE * ARTIST / DIVISOR);
IERC20(_BASE).safeTransfer(treasury, balanceBASE * TREASURY / DIVISOR);
IERC20(_BASE).safeTransfer(msg.sender, reward);
emit Distribute(msg.sender);
}
}
contract GBT is ERC20, ReentrancyGuard {
using SafeERC20 for IERC20;
// Bonding Curve Variables
address public immutable BASE_TOKEN;
uint256 public immutable reserveVirtualBASE;
uint256 public reserveRealBASE;
uint256 public reserveGBT;
uint256 public immutable initial_totalSupply;
// Addresses
address public XGBT;
address public artist;
address public artistTreasury;
address public immutable fees; // Fee Contract
address public immutable factory;
// Affiliates
mapping(address => address) public referrals; // account => affiliate
// Allowlist Variables
mapping(address => uint256) public allowlist;
uint256 public immutable start;
uint256 public immutable delay;
bool public open;
// Borrow Variables
uint256 public borrowedTotalBASE;
mapping(address => uint256) public borrowedBASE;
// Fee
uint256 public immutable fee;
uint256 public constant AFFILIATE = 100;
uint256 public constant DIVISOR = 1000;
// Events
event Buy(address indexed user, address indexed to, uint256 amount, address indexed affiliate);
event Sell(address indexed user, address indexed to, uint256 amount, address indexed affiliate);
event Borrow(address indexed user, uint256 amount);
event Repay(address indexed user, uint256 amount);
event AllowListUpdated(address[] accounts, uint256 amount);
event XGBTSet(address indexed _XGBT);
event ChangeArtist(address newArtist);
event ChangeArtistTreasury(address newArtistTreasury);
event AffiliateSet(address indexed account, address indexed affiliate);
event MarketOpened(uint256 _timestamp);
constructor(
string memory _name,
string memory _symbol,
address _baseToken,
uint256 _initialVirtualBASE,
uint256 _supplyGBT,
address _artist,
address _factory,
uint256 _delay,
uint256 _fee
) ERC20(_name, _symbol) {
require(_fee <= 100, "Redemption fee too high");
require(_fee >= 25, "Redemption fee too low");
BASE_TOKEN = _baseToken;
artist = _artist;
artistTreasury = _artist;
factory = _factory;
reserveVirtualBASE = _initialVirtualBASE;
reserveRealBASE = 0;
initial_totalSupply = _supplyGBT;
reserveGBT = _supplyGBT;
start = block.timestamp;
delay = _delay;
fee = _fee;
open = false;
fees = address(new GBTFees(address(this), BASE_TOKEN));
_mint(address(this), _supplyGBT);
}
//////////////////
///// Public /////
//////////////////
/** @dev returns the current price of {GBT} */
function currentPrice() external view returns (uint256) {
return ((reserveVirtualBASE + reserveRealBASE) * 1e18) / reserveGBT;
}
/** @dev returns the allowance @param user can borrow */
function borrowCredit(address account) external view returns (uint256) {
uint256 borrowPowerGBT = IXGBT(XGBT).balanceOf(account);
if (borrowPowerGBT == 0) {
return 0;
}
uint256 borrowTotalBASE = (reserveVirtualBASE * totalSupply() / (totalSupply() - borrowPowerGBT)) - reserveVirtualBASE;
uint256 borrowableBASE = borrowTotalBASE - borrowedBASE[account];
return borrowableBASE;
}
/** @dev returns amount borrowed by @param user */
function debt(address account) external view returns (uint256) {
return borrowedBASE[account];
}
function baseBal() external view returns (uint256) {
return IERC20(BASE_TOKEN).balanceOf(address(this));
}
function gbtBal() external view returns (uint256) {
return IERC20(address(this)).balanceOf(address(this));
}
function getFactory() external view returns (address) {
return factory;
}
function getXGBT() external view returns (address) {
return XGBT;
}
function getFees() external view returns (address) {
return fees;
}
function getArtist() external view returns (address) {
return artist;
}
function initSupply() external view returns (uint256) {
return initial_totalSupply;
}
function floorPrice() external view returns (uint256) {
return (reserveVirtualBASE * 1e18) / totalSupply();
}
function mustStayGBT(address account) external view returns (uint256) {
uint256 accountBorrowedBASE = borrowedBASE[account];
if (accountBorrowedBASE == 0) {
return 0;
}
uint256 amount = totalSupply() - (reserveVirtualBASE * totalSupply() / (accountBorrowedBASE + reserveVirtualBASE));
return amount;
}
////////////////////
///// External /////
////////////////////
/** @dev Buy function. User spends {BASE} and receives {GBT}
* @param _amountBASE is the amount of the {BASE} being spent
* @param _minGBT is the minimum amount of {GBT} out
* @param expireTimestamp is the expire time on txn
*
* If a delay was set on the proxy deployment and has not elapsed:
* 1. the user must be whitelisted by the protocol to call the function
* 2. the whitelisted user cannont buy more than 1 GBT until the delay has elapsed
*/
function buy(uint256 _amountBASE, uint256 _minGBT, uint256 expireTimestamp, address to, address affiliate) external nonReentrant {
require(expireTimestamp == 0 || expireTimestamp >= block.timestamp, "Expired");
require(_amountBASE > 0, "Amount cannot be zero");
address account = msg.sender;
if (referrals[to] == address(0) && affiliate != address(0)) {
referrals[to] = affiliate;
emit AffiliateSet(to, affiliate);
}
uint256 feeAmountBASE = _amountBASE * fee / DIVISOR;
uint256 oldReserveBASE = reserveVirtualBASE + reserveRealBASE;
uint256 newReserveBASE = oldReserveBASE + _amountBASE - feeAmountBASE;
uint256 oldReserveGBT = reserveGBT;
uint256 newReserveGBT = oldReserveBASE * oldReserveGBT / newReserveBASE;
uint256 outGBT = oldReserveGBT - newReserveGBT;
require(outGBT > _minGBT, "Less than Min");
if (start + delay >= block.timestamp) {
require(open, "Market not open yet");
require(outGBT <= allowlist[to], "Allowlist amount overflow");
allowlist[to] -= outGBT;
}
reserveRealBASE = newReserveBASE - reserveVirtualBASE;
reserveGBT = newReserveGBT;
if (referrals[to] == address(0)) {
IERC20(BASE_TOKEN).safeTransferFrom(account, fees, feeAmountBASE);
} else {
IERC20(BASE_TOKEN).safeTransferFrom(account, referrals[to], feeAmountBASE * AFFILIATE / DIVISOR);
IERC20(BASE_TOKEN).safeTransferFrom(account, fees, feeAmountBASE - (feeAmountBASE * AFFILIATE / DIVISOR));
}
IERC20(BASE_TOKEN).safeTransferFrom(account, address(this), _amountBASE - feeAmountBASE);
IERC20(address(this)).safeTransfer(to, outGBT);
emit Buy(account, to, _amountBASE, referrals[to]);
}
/** @dev Sell function. User sells their {GBT} token for {BASE}
* @param _amountGBT is the amount of {GBT} in
* @param _minETH is the minimum amount of {ETH} out
* @param expireTimestamp is the expire time on txn
*/
function sell(uint256 _amountGBT, uint256 _minETH, uint256 expireTimestamp, address to) external nonReentrant {
require(expireTimestamp == 0 || expireTimestamp >= block.timestamp, "Expired");
require(_amountGBT > 0, "Amount cannot be zero");
address account = msg.sender;
uint256 feeAmountGBT = _amountGBT * fee / DIVISOR;
uint256 oldReserveGBT = reserveGBT;
uint256 newReserveGBT = reserveGBT + _amountGBT - feeAmountGBT;
uint256 oldReserveBASE = reserveVirtualBASE + reserveRealBASE;
uint256 newReserveBASE = oldReserveBASE * oldReserveGBT / newReserveGBT;
uint256 outBASE = oldReserveBASE - newReserveBASE;
require(outBASE > _minETH, "Less than Min");
reserveRealBASE = newReserveBASE - reserveVirtualBASE;
reserveGBT = newReserveGBT;
if (referrals[to] == address(0)) {
IERC20(address(this)).safeTransferFrom(account, fees, feeAmountGBT);
} else {
IERC20(address(this)).safeTransferFrom(account, referrals[to], feeAmountGBT * AFFILIATE / DIVISOR);
IERC20(address(this)).safeTransferFrom(account, fees, feeAmountGBT - (feeAmountGBT * AFFILIATE / DIVISOR));
}
IERC20(address(this)).safeTransferFrom(account, address(this), _amountGBT - feeAmountGBT);
IERC20(BASE_TOKEN).safeTransfer(to, outBASE);
emit Sell(account, to, _amountGBT, referrals[to]);
}
/** @dev User borrows an amount of {BASE} equal to @param _amount */
function borrowSome(uint256 _amount) external nonReentrant {
require(_amount > 0, "!Zero");
address account = msg.sender;
uint256 borrowPowerGBT = IXGBT(XGBT).balanceOf(account);
uint256 borrowTotalBASE = (reserveVirtualBASE * totalSupply() / (totalSupply() - borrowPowerGBT)) - reserveVirtualBASE;
uint256 borrowableBASE = borrowTotalBASE - borrowedBASE[account];
require(borrowableBASE >= _amount, "Borrow Underflow");
borrowedBASE[account] += _amount;
borrowedTotalBASE += _amount;
IERC20(BASE_TOKEN).safeTransfer(account, _amount);
emit Borrow(account, _amount);
}
/** @dev User borrows the maximum amount of {BASE} their locked {XGBT} will allow */
function borrowMax() external nonReentrant {
address account = msg.sender;
uint256 borrowPowerGBT = IXGBT(XGBT).balanceOf(account);
uint256 borrowTotalBASE = (reserveVirtualBASE * totalSupply() / (totalSupply() - borrowPowerGBT)) - reserveVirtualBASE;
uint256 borrowableBASE = borrowTotalBASE - borrowedBASE[account];
borrowedBASE[account] += borrowableBASE;
borrowedTotalBASE += borrowableBASE;
IERC20(BASE_TOKEN).safeTransfer(account, borrowableBASE);
emit Borrow(account, borrowableBASE);
}
/** @dev User repays a portion of their debt equal to @param _amount */
function repaySome(uint256 _amount) external nonReentrant {
require(_amount > 0, "!Zero");
address account = msg.sender;
borrowedBASE[account] -= _amount;
borrowedTotalBASE -= _amount;
IERC20(BASE_TOKEN).safeTransferFrom(account, address(this), _amount);
emit Repay(account, _amount);
}
/** @dev User repays their debt and opens unlocking of {XGBT} */
function repayMax() external nonReentrant {
address account = msg.sender;
uint256 amountRepayBASE = borrowedBASE[account];
borrowedBASE[account] = 0;
borrowedTotalBASE -= amountRepayBASE;
IERC20(BASE_TOKEN).safeTransferFrom(account, address(this), amountRepayBASE);
emit Repay(account, amountRepayBASE);
}
////////////////////
//// Restricted ////
////////////////////
function updateAllowlist(address[] memory accounts, uint256 amount) external {
require(msg.sender == factory || msg.sender == artist, "!AUTH");
for (uint256 i = 0; i < accounts.length; i++) {
allowlist[accounts[i]] = amount;
}
emit AllowListUpdated(accounts, amount);
}
function setXGBT(address _XGBT) external OnlyFactory {
XGBT = _XGBT;
emit XGBTSet(_XGBT);
}
function setArtist(address _artist) external {
require(msg.sender == artist, "!AUTH");
artist = _artist;
emit ChangeArtist(_artist);
}
function setArtistTreasury(address _artistTreasury) external {
require(msg.sender == artist, "!AUTH");
artistTreasury = _artistTreasury;
emit ChangeArtistTreasury(_artistTreasury);
}
function openMarket() external {
require(msg.sender == artist, "!AUTH");
open = true;
emit MarketOpened(block.timestamp);
}
modifier OnlyFactory() {
require(msg.sender == factory, "!AUTH");
_;
}
}
contract GBTFactory {
address public factory;
address public lastGBT;
event FactorySet(address indexed _factory);
constructor() {
factory = msg.sender;
}
function setFactory(address _factory) external OnlyFactory {
factory = _factory;
emit FactorySet(_factory);
}
function createGBT(
string memory _name,
string memory _symbol,
address _baseToken,
uint256 _initialVirtualBASE,
uint256 _supplyGBT,
address _artist,
address _factory,
uint256 _delay,
uint256 _fee
) external OnlyFactory returns (address) {
GBT newGBT = new GBT(_name, _symbol, _baseToken, _initialVirtualBASE, _supplyGBT, _artist, _factory, _delay, _fee);
lastGBT = address(newGBT);
return lastGBT;
}
modifier OnlyFactory() {
require(msg.sender == factory, "!AUTH");
_;
}
}