Contract Source Code:

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

// Import statements
import { AccessControlUpgradeable } from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
import { ReentrancyGuardUpgradeable } from "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";
import { PausableUpgradeable } from "@openzeppelin/contracts-upgradeable/security/PausableUpgradeable.sol";
import { AddressUpgradeable } from "@openzeppelin/contracts-upgradeable/utils/AddressUpgradeable.sol";
import { SafeERC20Upgradeable, IERC20Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";

import { GroupId, GroupIdLibrary } from "./types/GroupId.sol";
import { GroupKey } from "./types/GroupKey.sol";
import { Currency, CurrencyLibrary } from "./types/Currency.sol";
import { Address, AddressLibrary } from "./types/Address.sol";
import { TokenRegistryStateLibrary } from "./libs/TokenRegistryState.sol";
import { ITokenRegistry } from "./interfaces/ITokenRegistry.sol";
import { CustomRevert } from "./libs/CustomRevert.sol";
import { DTokenRegistry } from "./declarations/DTokenRegistry.sol";
import { DefaultFeeParams, FeeParams, FeePermissions, CollateralInfo, GroupState } from "./types/CommonTypes.sol";
import { GroupSettings, GroupStateHelper } from "./types/GroupStateHelper.sol";

/**
 * @title TokenRegistry
 * @notice Manages the registration and configuration of token groups within the protocol.
 * @dev Inherits from AccessControlUpgradeable, PausableUpgradeable, and ReentrancyGuardUpgradeable.
 */
contract TokenRegistry is AccessControlUpgradeable, PausableUpgradeable, ReentrancyGuardUpgradeable, ITokenRegistry {
  using AddressUpgradeable for address;
  using SafeERC20Upgradeable for IERC20Upgradeable;
  using GroupIdLibrary for GroupKey;
  using CurrencyLibrary for Currency;
  using AddressLibrary for Address;
  using TokenRegistryStateLibrary for TokenRegistryStateLibrary.Storage;
  using GroupStateHelper for GroupSettings;
  using CustomRevert for bytes4;

  // Roles
  bytes32 public constant PAUSER_ROLE = keccak256("PAUSER_ROLE");

  // State variables
  uint256 public contractVersion;
  TokenRegistryStateLibrary.Storage private _storage;

  /// @custom:oz-upgrades-unsafe-allow constructor
  constructor() initializer {}

  /**
   * @notice Initializes the TokenRegistry contract.
   * @param admin The address to assign the DEFAULT_ADMIN_ROLE.
   * @param version The version of the contract.
   */
  function initialize(address admin, uint256 version) external initializer {
    if (admin == address(0)) {
      ITokenRegistry.ZeroAddress.selector.revertWith();
    }

    __AccessControl_init();
    __Pausable_init();
    __ReentrancyGuard_init();

    _grantRole(DEFAULT_ADMIN_ROLE, admin);
    _grantRole(PAUSER_ROLE, admin);

    contractVersion = version;
  }

  /**
   * @notice Fallback function to prevent receiving Ether.
   */
  receive() external payable {
    ITokenRegistry.NotPermitted.selector.revertWith();
  }

  /**
   * @notice Fallback function to prevent receiving Ether.
   */
  fallback() external payable {
    ITokenRegistry.NotPermitted.selector.revertWith();
  }

  /**
   * @notice Adds a new group to the registry.
   * @param setup The full group setup data.
   * @param hookContract The address of the hook contract.
   * @param hookPermissions The permissions for the hook.
   */
  function addGroup(
    DTokenRegistry.GroupSetup calldata setup,
    address hookContract,
    uint256 hookPermissions
  ) external override nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupKey memory key = GroupKey({ core: setup.core });
    GroupId groupId = key.toId();

    _storage._addGroup(groupId, setup, hookContract, hookPermissions);

    emit GroupAdded(groupId);
  }

  /**
   * @notice Updates fee parameters of a group.
   * @param key The group identifier.
   * @param newFees The new fee parameters.
   */
  function updateFeeParams(
    GroupKey calldata key,
    FeeParams calldata newFees
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.setFeeParams(groupId, newFees);

    emit GroupUpdated(groupId);
  }

  /**
   * @notice Updates the protocol stability ratio for a group.
   * @param key The group identifier.
   * @param stabilityRatio The group's new stability ratio.
   */
  function updateStabilityRatio(
    GroupKey calldata key,
    uint96 stabilityRatio
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.setStabilityRatio(groupId, stabilityRatio);

    emit GroupUpdated(groupId);
  }

  /**
   * @notice Updates the protocol stability triggering ratio for a group.
   * @param key The group identifier.
   * @param stabilityTriggeringRatio The group's new stability triggering ratio.
   */
  function updateStabilityTriggeringRatio(
    GroupKey calldata key,
    uint96 stabilityTriggeringRatio
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.setStabilityTriggeringRatio(groupId, stabilityTriggeringRatio);

    emit GroupUpdated(groupId);
  }

  /**
   * @notice Updates default fee parameters of a group.
   * @param key The group identifier.
   * @param defaultFees The new default fee parameters.
   */
  function updateDefaultFeeParams(
    GroupKey calldata key,
    DefaultFeeParams calldata defaultFees
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.setDefaultFeeParams(groupId, defaultFees);

    emit GroupUpdated(groupId);
  }

  /**
   * @notice Updates the extended settings of a group.
   * @param key The group identifier.
   * @param newExtended The new extended settings.
   */
  function updateExtendedSettings(
    GroupKey calldata key,
    DTokenRegistry.GroupExtended calldata newExtended
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.updateExtendedSettings(groupId, newExtended);

    emit GroupUpdated(groupId);
  }

  /**
   * @notice Sets a new hook contract for the group.
   * @param key The group identifier.
   * @param newHookContract The new hook contract address.
   * @param hookPermissions The new hook permissions.
   * @param groupFeePermissions The new group fee permissions.
   */
  function setHookContract(
    GroupKey calldata key,
    address newHookContract,
    uint256 hookPermissions,
    FeePermissions calldata groupFeePermissions
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.setHookContract(groupId, newHookContract, hookPermissions, groupFeePermissions);

    emit HookContractSet(groupId, newHookContract, groupFeePermissions.allowDelegation, groupFeePermissions.isDynamic);
  }

  /**
   * @notice Sets the fee permissions for a group.
   * @param key The group identifier.
   * @param groupFeePermissions The new group fee permissions.
   */
  function setFeePermissions(
    GroupKey calldata key,
    FeePermissions calldata groupFeePermissions
  ) external nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage.setFeePermissions(groupId, groupFeePermissions);

    emit UpdateFeePermissions(groupId, groupFeePermissions.isDynamic, groupFeePermissions.allowDelegation);
  }

  /**
   * @notice Adds a new acceptable collateral to a group.
   * @param key The group identifier.
   * @param collateral The collateral information.
   */
  function addCollateral(
    GroupKey calldata key,
    CollateralInfo calldata collateral
  ) external override nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage._addCollateral(groupId, collateral);

    emit CollateralAdded(groupId, collateral.token, collateral.decimals);
  }

  /**
   * @notice Removes an acceptable collateral from a group.
   * @param key The group identifier.
   * @param token The collateral token to remove.
   */
  function removeCollateral(
    GroupKey calldata key,
    Currency token
  ) external override nonReentrant whenNotPaused onlyRole(DEFAULT_ADMIN_ROLE) {
    GroupId groupId = key.toId();

    _storage._removeCollateral(groupId, token);

    emit CollateralRemoved(groupId, token);
  }

  // ------ GETTER FUNCTIONS FOR PROTOCOL USE ------ //

  /**
   * @notice Retrieves the group state for a given group ID.
   * @param groupId The ID of the group.
   * @return The GroupState struct containing all group data.
   */
  function getGroup(GroupId groupId) external view override returns (GroupState memory) {
    return _storage.getGroup(groupId);
  }

  /**
   * @notice Retrieves the stability ratio for a given group ID.
   * @param groupId The ID of the group.
   * @return The stability ratio.
   */
  function getStabilityRatio(GroupId groupId) external view override returns (uint96) {
    return _storage.getStabilityRatio(groupId);
  }

  /**
   * @notice Retrieves the stability trigger ratio for a given group ID.
   * @param groupId The ID of the group.
   * @return The stability trigger ratio.
   */
  function getStabilityTriggeringRatio(GroupId groupId) external view override returns (uint96) {
    return _storage.getStabilityTriggeringRatio(groupId);
  }

  /**
   * @notice Retrieves the fee permissions for a given group ID.
   * @param groupId The ID of the group.
   * @return The redeem fee for VT tokens.
   */
  function getFeePermissions(GroupId groupId) external view override returns (FeePermissions memory) {
    return _storage.getFeePermissions(groupId);
  }

  /**
   * @notice Retrieves the default fee parameters for a given group ID.
   * @param groupId The ID of the group.
   * @return The default fee parameters.
   */
  function getFeeParams(GroupId groupId) external view override returns (FeeParams memory) {
    return _storage.getFeeParams(groupId);
  }

  /**
   * @notice Retrieves the mint fee for VT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The mint fee for VT tokens.
   */
  function getMintFeeVT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.mintFeeVT;
  }

  /**
   * @notice Retrieves the protocol fee for a given group ID.
   * @param groupId The ID of the group.
   * @return The protocol fee.
   */
  function getProtocolFee(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.protocolFee;
  }

  /**
   * @notice Retrieves the redeem fee for VT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The redeem fee for VT tokens.
   */
  function getRedeemFeeVT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.redeemFeeVT;
  }

  /**
   * @notice Retrieves the mint fee for YT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The mint fee for YT tokens.
   */
  function getMintFeeYT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.mintFeeYT;
  }

  /**
   * @notice Retrieves the redeem fee for YT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The redeem fee for YT tokens.
   */
  function getRedeemFeeYT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.redeemFeeYT;
  }

  /**
   * @notice Retrieves the yield fee for YT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The yield fee for YT tokens.
   */
  function getYieldFeeYT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.yieldFeeYT;
  }

  /**
   * @notice Retrieves the stability minting fee for VT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The stability fee for VT tokens.
   */
  function getStabilityMintFeeVT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.stabilityMintFeeVT;
  }

  /**
   * @notice Retrieves the stability minting fee for VT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The stability fee for VT tokens.
   */
  function getStabilityMintFeeYT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.stabilityMintFeeYT;
  }

  /**
   * @notice Retrieves the stability redeeming fee for BT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The stability fee for YT tokens.
   */
  function getStabilityRedeemFeeVT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.stabilityRedeemFeeVT;
  }

  /**
   * @notice Retrieves the stability redeeming fee for BT tokens for a given group ID.
   * @param groupId The ID of the group.
   * @return The stability fee for YT tokens.
   */
  function getStabilityRedeemFeeYT(GroupId groupId) external view override returns (uint24) {
    FeeParams memory feeParams = _storage.getFeeParams(groupId);
    return feeParams.stabilityRedeemFeeYT;
  }

  /**
   * @notice Retrieves the hook contract address for a given group ID.
   * @param groupId The ID of the group.
   * @return The address of the hook contract.
   */
  function getHookContract(GroupId groupId) external view override returns (address) {
    return _storage.getHookContract(groupId);
  }

  /**
   * @notice Retrieves the hook permissions for a given group ID.
   * @param groupId The ID of the group.
   * @return The hook permissions.
   */
  function getHookPermissions(GroupId groupId) external view override returns (uint256) {
    return _storage.getHookPermissions(groupId);
  }

  /**
   * @notice Checks if wrapping is required for a given group ID.
   * @param groupId The ID of the group.
   * @return True if wrapping is required, false otherwise.
   */
  function isWrappingRequired(GroupId groupId) external view override returns (bool) {
    return _storage.isWrappingRequired(groupId);
  }

  /**
   * @notice Validates if a given currency is acceptable collateral for a group.
   * @param groupId The ID of the group.
   * @param currency The currency to validate.
   * @return True if the currency is acceptable collateral, false otherwise.
   */
  function validateCollateral(GroupId groupId, Currency currency) external view override returns (bool) {
    return _storage.groupCollaterals[groupId][currency];
  }

  /**
   * @notice Retrieves the fee model for a given group ID.
   * @param groupId The ID of the group.
   * @return The fee model.
   */
  function getFeeModel(GroupId groupId) external view override returns (uint8) {
    GroupState memory group = _storage.getGroup(groupId);
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);
    return groupSettings.getFeeModel();
  }

  /**
   * @notice Checks if the contract supports a specific interface.
   * @param interfaceId The interface identifier.
   * @return True if the interface is supported, false otherwise.
   */
  function supportsInterface(bytes4 interfaceId) public view override(AccessControlUpgradeable) returns (bool) {
    return interfaceId == type(ITokenRegistry).interfaceId || super.supportsInterface(interfaceId);
  }

  // ------ PAUSE AND UNPAUSE FUNCTIONS ------ //

  /**
   * @notice Pauses the contract, preventing certain functions from being called.
   */
  function pause() external onlyRole(PAUSER_ROLE) {
    _pause();
  }

  /**
   * @notice Unpauses the contract, allowing functions to be called.
   */
  function unpause() external onlyRole(DEFAULT_ADMIN_ROLE) {
    _unpause();
  }

  // ------ TOKEN RECOVERY FUNCTION ------ //

  /**
   * @notice Allows the admin to recover ERC20 tokens sent to this contract.
   * @param tokenAddress The address of the ERC20 token.
   * @param tokenAmount The amount of tokens to recover.
   */
  function recoverERC20(address tokenAddress, uint256 tokenAmount) external nonReentrant onlyRole(DEFAULT_ADMIN_ROLE) {
    if (tokenAddress == address(this)) {
      ITokenRegistry.CannotRecoverToken.selector.revertWith();
    }
    IERC20Upgradeable(tokenAddress).safeTransfer(_msgSender(), tokenAmount);
  }

  /**
   * @notice Prevents renouncing roles for security
   * @dev Overrides the default renounceRole function to prevent accidental role removal
   */
  function renounceRole(bytes32, address) public virtual override {
    revert("Roles can't be renounced");
  }

  // slither-disable-next-line unused-state
  uint256[50] private __gap; // Storage gap for upgradeability
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControlUpgradeable.sol";
import "../utils/ContextUpgradeable.sol";
import "../utils/StringsUpgradeable.sol";
import "../utils/introspection/ERC165Upgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControlUpgradeable is Initializable, ContextUpgradeable, IAccessControlUpgradeable, ERC165Upgradeable {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    function __AccessControl_init() internal onlyInitializing {
    }

    function __AccessControl_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControlUpgradeable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        StringsUpgradeable.toHexString(account),
                        " is missing role ",
                        StringsUpgradeable.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract PausableUpgradeable is Initializable, ContextUpgradeable {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    function __Pausable_init() internal onlyInitializing {
        __Pausable_init_unchained();
    }

    function __Pausable_init_unchained() internal onlyInitializing {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20Upgradeable.sol";
import "../extensions/IERC20PermitUpgradeable.sol";
import "../../../utils/AddressUpgradeable.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20Upgradeable {
    using AddressUpgradeable for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20Upgradeable token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20Upgradeable token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20Upgradeable token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20Upgradeable token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20Upgradeable token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20Upgradeable token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20PermitUpgradeable token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20Upgradeable token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20Upgradeable token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && AddressUpgradeable.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { GroupKey } from "./GroupKey.sol";

type GroupId is bytes32;

// @notice library for computing the ID of a group
library GroupIdLibrary {
  using GroupIdLibrary for GroupId;
  function toId(GroupKey memory groupKey) internal pure returns (GroupId groupId) {
    groupId = GroupId.wrap(keccak256(abi.encode(groupKey)));
  }
  
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";

/**
 * @title GroupKey
 * @dev Struct representing the core group key information.
 */
struct GroupKey {
    /**
     * @dev The core group information from the DTokenRegistry.
     */
    DTokenRegistry.GroupCore core;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

/// @notice https://forum.openzeppelin.com/t/safeerc20-vs-safeerc20upgradeable/17326
import { SafeERC20Upgradeable, IERC20Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";
import { CustomRevert } from "../libs/CustomRevert.sol";

// Custom type `Currency` to represent either an ERC20 token or the native currency (e.g., ETH)
type Currency is address;

/**
 * @title CurrencyLibrary
 * @dev A library for handling operations related to currencies, supporting both ERC20 tokens and native currency.
 *      Provides utility functions for balance checks, transfers, approvals, and comparisons.
 */
library CurrencyLibrary {
  // Use SafeERC20Upgradeable for IERC20Upgradeable token operations to ensure safety
  using SafeERC20Upgradeable for IERC20Upgradeable;

  // Use CustomRevert for standardized error handling via selectors
  using CustomRevert for bytes4;

  // Define a constant representing the native currency (address(0))
  Currency public constant NATIVE = Currency.wrap(address(0));

  // Custom error definitions for various invalid operations involving native currency
  error NativeCurrencyTransfersNotAllowed();
  error NativeCurrencyTransferFromNotAllowed();
  error NativeCurrencyApprovalNotAllowed();
  error NativeCurrencyDoesNotHaveTotalSupply();
  error NativeCurrencyIncreaseAllowanceNotAllowed();
  error NativeCurrencyDecreaseAllowanceNotAllowed();
  error ArbitraryTransfersNotAllowed();

  /**
   * @notice Checks if two currencies are equal.
   * @param currency The first currency to compare.
   * @param other The second currency to compare.
   * @return True if both currencies are the same, false otherwise.
   */
  function equals(Currency currency, Currency other) internal pure returns (bool) {
    return Currency.unwrap(currency) == Currency.unwrap(other);
  }

  /**
   * @notice Retrieves the balance of the specified owner for the given currency.
   * @param currency The currency to check (ERC20 token or native).
   * @param owner The address of the owner whose balance is queried.
   * @return The balance of the owner in the specified currency.
   */
  function balanceOf(Currency currency, address owner) internal view returns (uint256) {
    if (isNative(currency)) {
      return owner.balance; // For native currency, return the ETH balance
    } else {
      return IERC20Upgradeable(Currency.unwrap(currency)).balanceOf(owner); // For ERC20 tokens, use balanceOf
    }
  }

  /**
   * @notice Safely transfers a specified amount of the currency to a recipient.
   * @param currency The currency to transfer (must be an ERC20 token).
   * @param to The recipient address.
   * @param amount The amount to transfer.
   * @dev Native currency transfers are not allowed and will revert.
   */
  function safeTransfer(Currency currency, address to, uint256 amount) internal {
    if (isNative(currency)) {
      // Revert if attempting to transfer native currency using ERC20 methods
      NativeCurrencyTransfersNotAllowed.selector.revertWith();
    } else {
      IERC20Upgradeable(Currency.unwrap(currency)).safeTransfer(to, amount);
    }
  }

  /**
   * @notice Safely transfers a specified amount of the currency from one address to another.
   * @param currency The currency to transfer (must be an ERC20 token).
   * @param safeFrom The address to transfer from.
   * @param to The recipient address.
   * @param amount The amount to transfer.
   * @dev Native currency transfers are not allowed and will revert.
   * @dev Arbitrary transfers (i.e., not initiated by the sender) are also not allowed and will revert.
   * @notice Slither false positive. The function is internal and only used within the library
   */
  //slither-disable-next-line arbitrary-send-erc20
  function safeTransferFrom(Currency currency, address safeFrom, address to, uint256 amount) internal {
    if (isNative(currency)) {
      // Revert if attempting to transfer ERC20 tokens from an address other than the sender
      // This is to prevent arbitrary transfers, which are not allowed in the context of this library
      // This logic has the priority, so overrides any other inhereted logic
      NativeCurrencyTransferFromNotAllowed.selector.revertWith();
    } else {
      if (safeFrom != msg.sender) ArbitraryTransfersNotAllowed.selector.revertWith();
      IERC20Upgradeable(Currency.unwrap(currency)).safeTransferFrom(safeFrom, to, amount);
    }
  }

  /**
   * @notice Retrieves the allowance of a spender for the given owner's currency.
   * @param currency The currency to check (must be an ERC20 token).
   * @param owner The address of the owner of the currency.
   * @param spender The address of the spender.
   * @return The allowance of the spender for the owner's currency.
   */
  function allowance(Currency currency, address owner, address spender) internal view returns (uint256) {
    if (isNative(currency)) {
      return 0; // For native currency, return 0 as allowance is not applicable
    } else {
      return IERC20Upgradeable(Currency.unwrap(currency)).allowance(owner, spender); // For ERC20 tokens, use allowance
    }
  }

  /**
   * @notice Safely approves a spender to spend a specified amount of the currency.
   * @param currency The currency to approve (must be an ERC20 token).
   * @param spender The address authorized to spend the tokens.
   * @param amount The amount to approve.
   * @dev Approving native currency is not allowed and will revert.
   */
  function safeApprove(Currency currency, address spender, uint256 amount) internal {
    if (!isNative(currency)) {
      IERC20Upgradeable(Currency.unwrap(currency)).safeApprove(spender, amount);
    } else {
      // Revert if attempting to approve native currency
      NativeCurrencyApprovalNotAllowed.selector.revertWith();
    }
  }

  /**
   * @notice Safely increases the allowance of a spender for the currency.
   * @param currency The currency to modify allowance for (must be an ERC20 token).
   * @param spender The address authorized to spend the tokens.
   * @param addedValue The amount to increase the allowance by.
   * @dev Increasing allowance for native currency is not allowed and will revert.
   */
  function safeIncreaseAllowance(Currency currency, address spender, uint256 addedValue) internal {
    if (!isNative(currency)) {
      IERC20Upgradeable(Currency.unwrap(currency)).safeIncreaseAllowance(spender, addedValue);
    } else {
      // Revert if attempting to increase allowance for native currency
      NativeCurrencyIncreaseAllowanceNotAllowed.selector.revertWith();
    }
  }

  /**
   * @notice Checks if the given currency is the native currency.
   * @param currency The currency to check.
   * @return True if `currency` is the native currency, false otherwise.
   */
  function isNative(Currency currency) internal pure returns (bool) {
    return Currency.unwrap(currency) == Currency.unwrap(NATIVE);
  }

  /**
   * @notice Checks if the given currency is the zero address.
   * @param currency The currency to check.
   * @return True if `currency` is the zero address, false otherwise.
   */
  function isZero(Currency currency) internal pure returns (bool) {
    return Currency.unwrap(currency) == address(0);
  }

  /**
   * @notice Converts the currency address to a unique identifier.
   * @param currency The currency to convert.
   * @return The uint256 representation of the currency's address.
   */
  function toId(Currency currency) internal pure returns (uint256) {
    return uint160(Currency.unwrap(currency));
  }

  /**
   * @notice Unwraps the `Currency` type to retrieve the underlying address.
   * @param currency The currency to unwrap.
   * @return The underlying address of the currency.
   */
  function toAddress(Currency currency) internal pure returns (address) {
    return Currency.unwrap(currency);
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

// Import the CustomRevert library for standardized error handling
import { CustomRevert } from "../libs/CustomRevert.sol";

/**
 * @title Address
 * @dev Defines a user-defined value type `Address` that wraps the built-in `address` type.
 */
type Address is address;

/**
 * @title AddressLibrary
 * @dev A library for performing various operations on the `Address` type.
 */
library AddressLibrary {
  // Apply the library functions to the `Address` type
  using AddressLibrary for Address;

  // Use the CustomRevert library for standardized error handling via selectors
  using CustomRevert for bytes4;

  // Custom error definitions for more descriptive revert reasons
  error ZeroAddress();
  error FailedCall(string reason);
  error NonContractAddress();
  error UnableToSendValue();

  /**
   * @notice Checks if the given `Address` is the zero address.
   * @param addr The `Address` to check.
   * @return True if `addr` is the zero address, false otherwise.
   */
  function isZero(Address addr) internal pure returns (bool) {
    return Address.unwrap(addr) == address(0);
  }

  /**
   * @notice Determines if the given `Address` is a contract.
   * @param addr The `Address` to check.
   * @return True if `addr` is a contract, false otherwise.
   *
   * @dev This method relies on the fact that contracts have non-zero code size.
   *      It returns false for contracts in construction, since the code is only stored at the end of the constructor execution.
   */
  function isContract(Address addr) internal view returns (bool) {
    return Address.unwrap(addr).code.length > 0;
  }

  /**
   * @notice Compares two `Address` instances for equality.
   * @param a The first `Address`.
   * @param b The second `Address`.
   * @return True if both addresses are equal, false otherwise.
   */
  function equals(Address a, Address b) internal pure returns (bool) {
    address addrA = Address.unwrap(a);
    address addrB = Address.unwrap(b);
    return addrA == addrB;
  }

  /**
   * @notice Converts an `Address` to a `uint160`.
   * @param addr The `Address` to convert.
   * @return The `uint160` representation of the address.
   */
  function toUint160(Address addr) internal pure returns (uint160) {
    return uint160(Address.unwrap(addr));
  }

  /**
   * @notice Creates an `Address` from a `uint160`.
   * @param addr The `uint160` value to convert.
   * @return A new `Address` instance.
   */
  function fromUint160(uint160 addr) internal pure returns (Address) {
    return Address.wrap(address(addr));
  }

  /**
   * @notice Unwraps the `Address` type to retrieve the underlying address.
   * @param addr The `Address` to unwrap.
   * @return The underlying `address`.
   */
  function toAddress(Address addr) internal pure returns (address) {
    return Address.unwrap(addr);
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { WordCodec } from "../libs/WordCodec.sol";
import { Address, AddressLibrary } from "../types/Address.sol";
import { Currency, CurrencyLibrary } from "../types/Currency.sol";
import { GroupState, DefaultFeeParams, FeeParams, FeePermissions, CollateralInfo } from "../types/CommonTypes.sol";
import { GroupStateHelper, GroupSettings } from "../types/GroupStateHelper.sol";
import { GroupFeeLibrary } from "../libs/GroupFeeLibrary.sol";
import { GroupIdLibrary, GroupId } from "../types/GroupId.sol";
import { GroupKey } from "../types/GroupKey.sol";
import { HookLibrary } from "../libs/HookLibrary.sol";
import { CustomRevert } from "../libs/CustomRevert.sol";
import { IHooks } from "../interfaces/IHooks.sol";
import { ITokenRegistry } from "../interfaces/ITokenRegistry.sol";

library TokenRegistryStateLibrary {
  using WordCodec for bytes32;
  using CurrencyLibrary for Currency;
  using GroupIdLibrary for GroupKey;
  using AddressLibrary for Address;
  using HookLibrary for IHooks;
  using CustomRevert for bytes4;
  using GroupStateHelper for GroupSettings;

  // Use GroupFeeLibrary constants
  uint24 private constant MAX_GROUP_FEE = GroupFeeLibrary.MAX_GROUP_FEE; // 5_000 (50% in BPS)

  uint256 private constant MAX_DECIMALS = 18;
  uint256 private constant MAX_STABILITY_RATIO = 100e18;
  uint256 private constant MAX_COLLATERALS = 10;

  struct Storage {
    mapping(GroupId => GroupState) groups;
    mapping(GroupId => mapping(Currency => bool)) groupCollaterals;
  }

  modifier groupExist(Storage storage self, GroupId groupId) {
    if (!_groupExists(self, groupId)) {
      ITokenRegistry.GroupNotFound.selector.revertWith(groupId);
    }
    _;
  }

  /**
   * @dev Checks if a group exists.
   * @param self The storage reference.
   * @param groupId The ID of the group to check.
   * @return True if the group exists, false otherwise.
   */
  function _groupExists(Storage storage self, GroupId groupId) private view returns (bool) {
    return self.groups[groupId].groupSettings != bytes32(0);
  }

  /**
   * @notice Adds a new group to the registry.
   * @dev Validates the group setup and stores it.
   * @param self The storage reference.
   * @param groupId The ID of the group to add.
   * @param setup The setup parameters for the group.
   * @param hookContract The address of the hook contract.
   * @param hookPermissions The permissions for the hook contract.
   */
  function _addGroup(
    Storage storage self,
    GroupId groupId,
    DTokenRegistry.GroupSetup memory setup,
    address hookContract,
    uint256 hookPermissions
  ) internal {
    if (_groupExists(self, groupId)) {
      ITokenRegistry.GroupAlreadyExists.selector.revertWith(groupId);
    }

    _validateGroupSetup(setup, hookContract, hookPermissions);
    _validateFeeParams(setup.fees, setup.defaultFees);

    GroupState storage groupState = self.groups[groupId];

    GroupSettings groupSettings = _createGroupSettings(setup, hookPermissions);
    groupState.groupSettings = GroupSettings.unwrap(groupSettings);

    groupState.core = setup.core;
    groupState.extended = setup.extended;

    bytes32 feesPacked = _packFees(setup.fees, setup.defaultFees);
    groupState.feesPacked = feesPacked;

    for (uint256 i = 0; i < setup.acceptableCollaterals.length; ) {
      Currency collateral = setup.acceptableCollaterals[i].token;
      uint8 decimals = setup.acceptableCollaterals[i].decimals;
      uint256 minAmount = setup.acceptableCollaterals[i].minAmount;
      uint256 maxAmount = setup.acceptableCollaterals[i].maxAmount;

      if (minAmount >= maxAmount || minAmount == 0) {
        ITokenRegistry.InvalidMinMaxCollateralAmount.selector.revertWith();
      }

      _validateDecimals(decimals);
      if (self.groupCollaterals[groupId][collateral]) {
        ITokenRegistry.CollateralAlreadyExists.selector.revertWith();
      }

      self.groupCollaterals[groupId][collateral] = true;
      groupState.acceptableCollaterals.push(setup.acceptableCollaterals[i]);
      unchecked {
        i++;
      }
    }

    groupState.hookContract = Address.wrap(hookContract);
  }

  /**
   * @dev Creates group settings from setup parameters.
   * @param setup The setup parameters.
   * @param hookPermissions The permissions for the hook contract.
   * @return groupSettings The created group settings.
   */
  function _createGroupSettings(
    DTokenRegistry.GroupSetup memory setup,
    uint256 hookPermissions
  ) private pure returns (GroupSettings groupSettings) {
    groupSettings = groupSettings.setATokenDecimals(setup.decimals.aTokenDecimals);
    groupSettings = groupSettings.setXTokenDecimals(setup.decimals.xTokenDecimals);
    groupSettings = groupSettings.setBaseTokenDecimals(setup.decimals.baseTokenDecimals);
    groupSettings = groupSettings.setYieldBearingTokenDecimals(setup.decimals.yieldBearingTokenDecimals);

    groupSettings = groupSettings.setStabilityRatio(setup.meta.stabilityRatio);
    groupSettings = groupSettings.setStabilityTriggeringRatio(setup.meta.stabilityConditionsTriggeringRate);
    groupSettings = groupSettings.setFeeModel(setup.meta.feeModel);
    groupSettings = groupSettings.setWrappingRequired(setup.meta.isWrappingRequired);
    groupSettings = groupSettings.setHookPermissions(uint16(hookPermissions));

    bool isDelegated = setup.feePermissions.allowDelegation;
    setup.feePermissions = FeePermissions({
      isDynamic: isDelegated == true ? isDelegated : setup.feePermissions.isDynamic,
      allowDelegation: setup.feePermissions.allowDelegation
    });

    FeePermissions memory permissions = setup.feePermissions;
    groupSettings = groupSettings.setFeePermissions(permissions);

    return groupSettings;
  }

  /**
   * @dev Packs fee parameters into a single bytes32 value.
   * @param feeParams The fee parameters to pack.
   * @param defaultFees The default fee parameters.
   * @return packed The packed fee parameters.
   */
  function _packFees(FeeParams memory feeParams, DefaultFeeParams memory defaultFees) internal pure returns (bytes32 packed) {
    packed = GroupStateHelper.setMaxFee(packed, uint24(defaultFees.maxFee));
    packed = GroupStateHelper.setMinFee(packed, uint24(defaultFees.minFee));
    packed = GroupStateHelper.setBaseFee(packed, uint24(defaultFees.baseFee));

    packed = GroupStateHelper.setYieldFeeVT(packed, feeParams.yieldFeeVT);
    packed = GroupStateHelper.setYieldFeeYT(packed, feeParams.yieldFeeYT);

    packed = GroupStateHelper.setMintFeeVT(packed, feeParams.mintFeeVT);
    packed = GroupStateHelper.setRedeemFeeVT(packed, feeParams.redeemFeeVT);
    packed = GroupStateHelper.setMintFeeYT(packed, feeParams.mintFeeYT);
    packed = GroupStateHelper.setRedeemFeeYT(packed, feeParams.redeemFeeYT);

    packed = GroupStateHelper.setStabilityMintFeeVT(packed, feeParams.stabilityMintFeeVT);
    packed = GroupStateHelper.setStabilityMintFeeYT(packed, feeParams.stabilityMintFeeYT);
    packed = GroupStateHelper.setStabilityRedeemFeeVT(packed, feeParams.stabilityRedeemFeeVT);
    packed = GroupStateHelper.setStabilityRedeemFeeYT(packed, feeParams.stabilityRedeemFeeYT);

    packed = GroupStateHelper.setProtocolFee(packed, feeParams.protocolFee);

    return packed;
  }

  /**
   * @dev Validates the provided fee parameters against default limits.
   * @param fees The fee parameters to validate.
   * @param defaultFees The default fee parameters.
   */
  function _validateFeeParams(FeeParams memory fees, DefaultFeeParams memory defaultFees) private pure {
    // Validate default fees
    if (defaultFees.maxFee > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidMaxFee.selector.revertWith();
    }
    if (defaultFees.minFee > defaultFees.maxFee) {
      ITokenRegistry.InvalidMinFee.selector.revertWith();
    }
    if (defaultFees.baseFee > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidBaseFee.selector.revertWith();
    }
    if (defaultFees.baseFee < defaultFees.minFee || defaultFees.baseFee > defaultFees.maxFee) {
      ITokenRegistry.InvalidBaseFee.selector.revertWith();
    }

    // Validate 16-bit fees (must be <= MAX_GROUP_FEE, no flags allowed)
    uint24 mask16bit = type(uint16).max;
    if (fees.yieldFeeVT > mask16bit || fees.yieldFeeVT > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidYieldFee.selector.revertWith();
    }
    if (fees.yieldFeeYT > mask16bit || fees.yieldFeeYT > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidYieldFee.selector.revertWith();
    }
    if (fees.stabilityMintFeeVT > mask16bit || fees.stabilityMintFeeVT > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidStabilityFee.selector.revertWith();
    }
    if (fees.stabilityMintFeeYT > mask16bit || fees.stabilityMintFeeYT > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidStabilityFee.selector.revertWith();
    }
    if (fees.stabilityRedeemFeeVT > mask16bit || fees.stabilityRedeemFeeVT > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidStabilityFee.selector.revertWith();
    }
    if (fees.stabilityRedeemFeeYT > mask16bit || fees.stabilityRedeemFeeYT > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidStabilityFee.selector.revertWith();
    }
    if (fees.protocolFee > mask16bit || fees.protocolFee > MAX_GROUP_FEE) {
      ITokenRegistry.InvalidProtocolFee.selector.revertWith();
    }

    // Validate 24-bit fees with min/max checks
    _validate24BitFee(fees.mintFeeVT, defaultFees, "InvalidMintFee");
    _validate24BitFee(fees.redeemFeeVT, defaultFees, "InvalidRedeemFee");
    _validate24BitFee(fees.mintFeeYT, defaultFees, "InvalidMintFee");
    _validate24BitFee(fees.redeemFeeYT, defaultFees, "InvalidRedeemFee");
  }

  /**
   * @dev Validates a 24-bit fee with min/max checks.
   * @param fee The fee to validate.
   * @param defaultFees The default fee parameters.
   * @param /errorString The error string for revert messages.
   */
  function _validate24BitFee(uint24 fee, DefaultFeeParams memory defaultFees, string memory /*errorString*/) private pure {
    // Check both min and max bounds
    if (fee < defaultFees.minFee || fee > defaultFees.maxFee) {
      ITokenRegistry.InvalidFeeFlags.selector.revertWith();
    }
  }

  /**
   * @dev Validates the group setup parameters.
   * @param setup The group setup parameters.
   * @param hookContract The address of the hook contract.
   * @param hookPermissions The permissions for the hook contract.
   */
  function _validateGroupSetup(DTokenRegistry.GroupSetup memory setup, address hookContract, uint256 hookPermissions) private view {
    if (setup.acceptableCollaterals.length == 0) {
      ITokenRegistry.EmptyCollateralList.selector.revertWith();
    }

    if (setup.acceptableCollaterals.length > MAX_COLLATERALS) {
      ITokenRegistry.MaxCollateralsLimitReached.selector.revertWith();
    }

    if (setup.meta.stabilityRatio > MAX_STABILITY_RATIO || setup.meta.stabilityRatio > setup.meta.stabilityConditionsTriggeringRate) {
      ITokenRegistry.StabilityRatioTooLarge.selector.revertWith();
    }

    if (setup.meta.stabilityConditionsTriggeringRate > MAX_STABILITY_RATIO) {
      ITokenRegistry.stabilityConditionsTriggeringRateTooLarge.selector.revertWith();
    }

    uint256 nativeTokenCount = _nativeTokenCount(setup.acceptableCollaterals);
    if (nativeTokenCount > 1) {
      ITokenRegistry.MultipleNativeTokensNotAllowed.selector.revertWith();
    }

    if (
      setup.core.aToken.isZero() || setup.core.xToken.isZero() || setup.core.baseToken.isZero() || setup.core.yieldBearingToken.isZero()
    ) {
      ITokenRegistry.InvalidGroupSetup.selector.revertWith();
    }

    /// @dev cartesian check
    if (
      setup.core.aToken.equals(setup.core.xToken) ||
      setup.core.aToken.equals(setup.core.baseToken) ||
      setup.core.aToken.equals(setup.core.yieldBearingToken) ||
      setup.core.xToken.equals(setup.core.baseToken) ||
      setup.core.xToken.equals(setup.core.yieldBearingToken) ||
      setup.core.baseToken.equals(setup.core.yieldBearingToken)
    ) {
      ITokenRegistry.InvalidGroupSetup.selector.revertWith();
    }

    _validateBatchDecimals(setup.decimals);
    _validateExtendedAddresses(setup.extended);

    if (hookContract == address(0)) {
      hookPermissions = 0;
      setup.feePermissions = FeePermissions({ isDynamic: false, allowDelegation: false });
    } else {
      _validateHookContract(IHooks(hookContract), uint16(hookPermissions));
    }
  }

  /**
   * @dev Validates the decimals for tokens in the group.
   * @param decimals The decimals to validate.
   */
  function _validateBatchDecimals(DTokenRegistry.GroupDecimals memory decimals) private pure {
    if (
      decimals.aTokenDecimals > MAX_DECIMALS ||
      decimals.xTokenDecimals > MAX_DECIMALS ||
      decimals.baseTokenDecimals > MAX_DECIMALS ||
      decimals.yieldBearingTokenDecimals > MAX_DECIMALS
    ) {
      ITokenRegistry.InvalidDecimals.selector.revertWith();
    }
  }

  /**
   * @dev Validates token decimals.
   * @param decimals The decimals to validate.
   */
  function _validateDecimals(uint8 decimals) private pure {
    if (decimals > MAX_DECIMALS || decimals == 0) {
      ITokenRegistry.InvalidDecimals.selector.revertWith();
    }
  }

  /**
   * @dev Validates the extended addresses in the group setup.
   * @param extended The extended addresses to validate.
   */
  function _validateExtendedAddresses(DTokenRegistry.GroupExtended memory extended) private pure {
    if (
      extended.priceOracle.isZero() ||
      extended.rateProvider.isZero() ||
      extended.swapRouter.isZero() ||
      extended.treasury.isZero() ||
      extended.feeCollector.isZero() ||
      extended.strategy.isZero() ||
      extended.rebalancePool.isZero()
    ) {
      ITokenRegistry.ZeroAddress.selector.revertWith();
    }
  }

  /**
   * @dev Counts the number of native tokens in collaterals.
   * @param collaterals The list of collateral tokens.
   * @return count The number of native tokens.
   */
  function _nativeTokenCount(CollateralInfo[] memory collaterals) private pure returns (uint256 count) {
    count = 0;
    for (uint256 i = 0; i < collaterals.length; ) {
      if (collaterals[i].token.isNative()) {
        count++;
      }
      unchecked {
        i++;
      }
    }
  }

  /**
   * @notice Retrieves the default fee parameters for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return defaultFees The default fee parameters.
   */
  function getDefaultFees(
    Storage storage self,
    GroupId groupId
  ) internal view groupExist(self, groupId) returns (DefaultFeeParams memory defaultFees) {
    bytes32 feesPacked = self.groups[groupId].feesPacked;
    defaultFees = GroupStateHelper.getDefaultFeeParams(feesPacked);
  }

  /**
   * @notice Retrieves the fee parameters for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return feeParams The fee parameters.
   */
  function getFeeParams(
    Storage storage self,
    GroupId groupId
  ) internal view groupExist(self, groupId) returns (FeeParams memory feeParams) {
    bytes32 feesPacked = self.groups[groupId].feesPacked;
    feeParams = GroupStateHelper.getFeeParams(feesPacked);
  }

  /**
   * @notice Retrieves the fee permissions for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return feePermissions The fee permissions.
   */
  function getFeePermissions(
    Storage storage self,
    GroupId groupId
  ) internal view groupExist(self, groupId) returns (FeePermissions memory feePermissions) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);
    feePermissions = GroupStateHelper.getFeePermissions(groupSettings);
  }

  /**
   * @notice Retrieves the stability ratio for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return The stability ratio as a uint96 value.
   */
  function getStabilityRatio(Storage storage self, GroupId groupId) internal view groupExist(self, groupId) returns (uint96) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);

    return GroupStateHelper.getStabilityRatio(groupSettings);
  }

  /**
   * @notice Retrieves the stability triggering ratio for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return The stability triggering ratio as a uint96 value.
   */
  function getStabilityTriggeringRatio(Storage storage self, GroupId groupId) internal view groupExist(self, groupId) returns (uint96) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);

    return GroupStateHelper.getStabilityTriggeringRatio(groupSettings);
  }

  /**
   * @notice Retrieves the hook contract address for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return The address of the hook contract.
   */
  function getHookContract(Storage storage self, GroupId groupId) internal view groupExist(self, groupId) returns (address) {
    return self.groups[groupId].hookContract.toAddress();
  }

  /**
   * @notice Retrieves the hook permissions for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return The hook permissions as a uint256 value.
   */
  function getHookPermissions(Storage storage self, GroupId groupId) internal view groupExist(self, groupId) returns (uint256) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);
    return groupSettings.getHookPermissions();
  }

  /**
   * @notice Checks if wrapping is required for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return True if wrapping is required, false otherwise.
   */
  function isWrappingRequired(Storage storage self, GroupId groupId) internal view groupExist(self, groupId) returns (bool) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);
    return groupSettings.isWrappingRequired();
  }

  /**
   * @notice Retrieves the group state for a given group ID.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @return The group state structure.
   */
  function getGroup(Storage storage self, GroupId groupId) internal view groupExist(self, groupId) returns (GroupState memory) {
    return self.groups[groupId];
  }

  /**
   * @notice Sets a new stability ratio for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newStabilityRatio The new stability ratio to set.
   */
  function setStabilityRatio(Storage storage self, GroupId groupId, uint96 newStabilityRatio) internal groupExist(self, groupId) {
    if (newStabilityRatio > MAX_STABILITY_RATIO) {
      ITokenRegistry.StabilityRatioTooLarge.selector.revertWith();
    }
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);
    groupSettings = groupSettings.setStabilityRatio(newStabilityRatio);
    group.groupSettings = GroupSettings.unwrap(groupSettings);
  }

  /**
   * @notice Sets a new stability triggering ratio for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newStabilityTriggeringRatio The new stability triggering ratio to set.
   */

  function setStabilityTriggeringRatio(
    Storage storage self,
    GroupId groupId,
    uint96 newStabilityTriggeringRatio
  ) internal groupExist(self, groupId) {
    if (newStabilityTriggeringRatio > MAX_STABILITY_RATIO) {
      ITokenRegistry.stabilityConditionsTriggeringRateTooLarge.selector.revertWith();
    }
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);

    uint96 stabilityRatio = GroupStateHelper.getStabilityRatio(groupSettings);

    if (stabilityRatio > newStabilityTriggeringRatio) {
      ITokenRegistry.InvalidStabilityTriggeringRatio.selector.revertWith(groupId);
    }

    groupSettings = groupSettings.setStabilityTriggeringRatio(newStabilityTriggeringRatio);

    group.groupSettings = GroupSettings.unwrap(groupSettings);
  }

  /**
   * @notice Sets new fee parameters for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newFees The new fee parameters to set.
   */
  function setFeeParams(Storage storage self, GroupId groupId, FeeParams memory newFees) internal groupExist(self, groupId) {
    GroupState storage group = self.groups[groupId];
    DefaultFeeParams memory defaultFees = getDefaultFees(self, groupId);

    _validateFeeParams(newFees, defaultFees);

    bytes32 feesPacked = _packFees(newFees, defaultFees);
    group.feesPacked = feesPacked;
  }

  /**
   * @notice Sets new default fee parameters for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newDefaultFees The new default fee parameters to set.
   */
  function setDefaultFeeParams(
    Storage storage self,
    GroupId groupId,
    DefaultFeeParams memory newDefaultFees
  ) internal groupExist(self, groupId) {
    GroupState storage group = self.groups[groupId];
    FeeParams memory feeParams = getFeeParams(self, groupId);

    GroupFeeLibrary._validateFeeParams(newDefaultFees);
    _validateFeeParams(feeParams, newDefaultFees);

    bytes32 feesPacked = _packFees(feeParams, newDefaultFees);
    group.feesPacked = feesPacked;
  }

  /**
   * @notice Sets new fee permissions for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newFeePermissions The new fee permissions to set.
   */
  function setFeePermissions(
    Storage storage self,
    GroupId groupId,
    FeePermissions memory newFeePermissions
  ) internal groupExist(self, groupId) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);

    // Update both group settings and fees
    bool isDelegated = newFeePermissions.allowDelegation;
    newFeePermissions = FeePermissions({
      isDynamic: isDelegated == true ? isDelegated : newFeePermissions.isDynamic,
      allowDelegation: newFeePermissions.allowDelegation
    });

    groupSettings = groupSettings.setFeePermissions(newFeePermissions);
    group.groupSettings = GroupSettings.unwrap(groupSettings);
  }

  /**
   * @notice Updates the extended settings for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newExtended The new extended settings to set.
   */
  function updateExtendedSettings(
    Storage storage self,
    GroupId groupId,
    DTokenRegistry.GroupExtended memory newExtended
  ) internal groupExist(self, groupId) {
    GroupState storage group = self.groups[groupId];
    _validateExtendedAddresses(newExtended);
    group.extended = newExtended;
  }

  /**
   * @notice Sets a new hook contract for a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param newHookContract The address of the new hook contract.
   * @param hookPermissions The permissions for the hook contract.
   * @param groupFeePermissions The fee permissions for the group.
   */
  function setHookContract(
    Storage storage self,
    GroupId groupId,
    address newHookContract,
    uint256 hookPermissions,
    FeePermissions calldata groupFeePermissions
  ) internal groupExist(self, groupId) {
    GroupState storage group = self.groups[groupId];
    GroupSettings groupSettings = GroupSettings.wrap(group.groupSettings);

    if (newHookContract == address(0)) {
      // Clear hook contract and permissions
      group.hookContract = Address.wrap(address(0));
      groupSettings = groupSettings.setHookPermissions(0);

      // Reset fee permissions and clear delegation flags
      FeeParams memory feeParams = getFeeParams(self, groupId);
      DefaultFeeParams memory defaultFees = getDefaultFees(self, groupId);
      FeePermissions memory noPermissions = FeePermissions({ allowDelegation: false, isDynamic: false });

      group.feesPacked = _packFees(feeParams, defaultFees);
      groupSettings = groupSettings.setFeePermissions(noPermissions);
    } else {
      // Validate and set new hook
      _validateHookContract(IHooks(newHookContract), uint16(hookPermissions));
      group.hookContract = Address.wrap(newHookContract);
      groupSettings = groupSettings.setHookPermissions(uint16(hookPermissions));

      // Set fee permissions
      bool isDelegated = groupFeePermissions.allowDelegation;
      FeePermissions memory feePermissions = FeePermissions({
        isDynamic: isDelegated == true ? isDelegated : groupFeePermissions.isDynamic,
        allowDelegation: groupFeePermissions.allowDelegation
      });

      FeeParams memory feeParams = getFeeParams(self, groupId);
      DefaultFeeParams memory defaultFees = getDefaultFees(self, groupId);

      group.feesPacked = _packFees(feeParams, defaultFees);
      groupSettings = groupSettings.setFeePermissions(feePermissions);
    }

    group.groupSettings = GroupSettings.unwrap(groupSettings);
  }

  /**
   * @notice Adds a new collateral token to a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param collateral The collateral information to add.
   */
  function _addCollateral(Storage storage self, GroupId groupId, CollateralInfo memory collateral) internal groupExist(self, groupId) {
    Currency token = collateral.token;
    uint8 decimals = collateral.decimals;
    if (self.groupCollaterals[groupId][token]) {
      ITokenRegistry.CollateralAlreadyExists.selector.revertWith();
    }

    _validateDecimals(decimals);

    uint256 minAmount = collateral.minAmount;
    uint256 maxAmount = collateral.maxAmount;

    if (minAmount >= maxAmount || minAmount == 0) {
      ITokenRegistry.InvalidMinMaxCollateralAmount.selector.revertWith();
    }

    CollateralInfo[] storage collaterals = self.groups[groupId].acceptableCollaterals;

    if (collaterals.length == MAX_COLLATERALS) {
      ITokenRegistry.MaxCollateralsLimitReached.selector.revertWith();
    }

    collaterals.push(collateral);
    self.groupCollaterals[groupId][token] = true;

    uint256 nativeCount = _nativeTokenCount(collaterals);
    if (nativeCount > 1) {
      collaterals.pop();
      self.groupCollaterals[groupId][token] = false;
      ITokenRegistry.MultipleNativeTokensNotAllowed.selector.revertWith();
    }

    if (collaterals.length == 0) {
      ITokenRegistry.EmptyCollateralList.selector.revertWith();
    }
  }

  /**
   * @notice Removes a collateral token from a group.
   * @param self The storage reference.
   * @param groupId The ID of the group.
   * @param token The collateral token to remove.
   */
  function _removeCollateral(Storage storage self, GroupId groupId, Currency token) internal groupExist(self, groupId) {
    if (!self.groupCollaterals[groupId][token]) {
      ITokenRegistry.CollateralNotFound.selector.revertWith();
    }

    CollateralInfo[] storage collaterals = self.groups[groupId].acceptableCollaterals;
    uint256 len = collaterals.length;
    bool found = false;

    for (uint256 i = 0; i < len; ) {
      if (collaterals[i].token.equals(token)) {
        found = true;
        collaterals[i] = collaterals[len - 1];
        collaterals.pop();
        break;
      }
      unchecked {
        i++;
      }
    }

    if (!found) {
      ITokenRegistry.CollateralNotFound.selector.revertWith();
    }

    self.groupCollaterals[groupId][token] = false;

    if (collaterals.length == 0) {
      ITokenRegistry.EmptyCollateralList.selector.revertWith();
    }
  }

  /**
   * @dev Validates the hook contract and permissions.
   * @param hookContract The hook contract interface.
   * @param hookPermissions The permissions for the hook contract.
   */
  function _validateHookContract(IHooks hookContract, uint16 hookPermissions) private view {
    hookContract.validateHookPermissions(hookPermissions);
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { Currency } from "../types/Currency.sol";
import { GroupId } from "../types/GroupId.sol";
import { GroupKey } from "../types/GroupKey.sol";
import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { GroupState, FeePermissions, FeeParams, DefaultFeeParams, CollateralInfo } from "../types/CommonTypes.sol";

interface ITokenRegistry {
  // Events
  event GroupAdded(GroupId indexed groupId);
  event GroupUpdated(GroupId indexed groupId);
  event CollateralAdded(GroupId indexed groupId, Currency indexed token, uint8 indexed decimals);
  event CollateralRemoved(GroupId indexed groupId, Currency indexed token);
  event HookContractSet(GroupId indexed groupId, address indexed newHookContract, bool indexed isDynamic, bool isDelegated);
  event HookPermissionsSet(GroupId indexed groupId, uint256 indexed newPermissions);

  event UpdateFeePermissions(GroupId indexed groupId, bool indexed isDynamic, bool indexed allowDelegation);

  // Custom Errors
  error AddressNotContract(address addr);
  error NotPermitted();
  error GroupNotFound(GroupId groupId);
  error GroupAlreadyExists(GroupId groupId);
  error InvalidDecimals();
  error InvalidMinMaxCollateralAmount();
  error CollateralAlreadyExists();
  error MultipleNativeTokensNotAllowed();
  error CollateralNotFound();
  error InvalidGroupSetup();
  error ZeroAddress();
  error EmptyCollateralList();
  error MaxCollateralsLimitReached();
  error StabilityRatioTooLarge();
  error stabilityConditionsTriggeringRateTooLarge();

  error InvalidStabilityTriggeringRatio(GroupId groupId);

  error FeesTooHigh();
  error InvalidMaxFee();
  error InvalidMinFee();
  error InvalidBaseFee();
  error InvalidYieldFee();
  error InvalidStabilityFee();
  error InvalidProtocolFee();
  error InvalidFeeFlags();
  error FeesAreNotCompatibleWithDefaultFees();
  error CannotRecoverToken();

  // Group management functions (Manager Role)
  function addGroup(
    DTokenRegistry.GroupSetup calldata setup, // Full group setup
    address hookContract, // Hook contract for the group
    uint256 hookPermissions // Hook permissions
  ) external;

  // Collateral management functions (Manager Role)
  function addCollateral(GroupKey calldata key, CollateralInfo calldata collateral) external;

  function removeCollateral(GroupKey calldata key, Currency token) external;

  // Getter functions for group state
  function getGroup(GroupId groupId) external view returns (GroupState memory);

  function getStabilityRatio(GroupId groupId) external view returns (uint96);

  function getStabilityTriggeringRatio(GroupId groupId) external view returns (uint96);

  function getProtocolFee(GroupId groupId) external view returns (uint24);

  function getFeePermissions(GroupId groupId) external view returns (FeePermissions memory);

  function getFeeParams(GroupId groupId) external view returns (FeeParams memory);

  function getMintFeeVT(GroupId groupId) external view returns (uint24);

  function getRedeemFeeVT(GroupId groupId) external view returns (uint24);

  function getMintFeeYT(GroupId groupId) external view returns (uint24);

  function getRedeemFeeYT(GroupId groupId) external view returns (uint24);

  function getYieldFeeYT(GroupId groupId) external view returns (uint24);

  function getStabilityMintFeeVT(GroupId groupId) external view returns (uint24);

  function getStabilityMintFeeYT(GroupId groupId) external view returns (uint24);

  function getStabilityRedeemFeeVT(GroupId groupId) external view returns (uint24);

  function getStabilityRedeemFeeYT(GroupId groupId) external view returns (uint24);

  function getHookContract(GroupId groupId) external view returns (address);

  function getHookPermissions(GroupId groupId) external view returns (uint256);

  function validateCollateral(GroupId groupId, Currency currency) external view returns (bool);

  function isWrappingRequired(GroupId groupId) external view returns (bool);

  function getFeeModel(GroupId groupId) external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { GroupId } from "../types/GroupId.sol";

// solhint-disable
/// @title Library for reverting with custom errors efficiently
/// @notice Contains functions for reverting with custom errors with different argument types efficiently
/// @dev To use this library, declare `using CustomRevert for bytes4;` and replace `revert CustomError()` with
/// `CustomError.selector.revertWith()`
/// @dev The functions may tamper with the free memory pointer but it is fine since the call context is exited immediately
library CustomRevert {
  /// @dev Reverts with the selector of a custom error in the scratch space
  function revertWith(bytes4 selector) internal pure {
    assembly("memory-safe") {
      mstore(0, selector)
      revert(0, 0x04)
    }
  }

  /// @dev Reverts with a custom error with an address argument in the scratch space
  function revertWith(bytes4 selector, address addr) internal pure {
    assembly("memory-safe") {
      mstore(0, selector)
      mstore(0x04, and(addr, 0xffffffffffffffffffffffffffffffffffffffff))
      revert(0, 0x24)
    }
  }

  /// @dev Reverts with a custom error with an int24 argument in the scratch space
  function revertWith(bytes4 selector, int24 value) internal pure {
    assembly("memory-safe") {
      mstore(0, selector)
      mstore(0x04, signextend(2, value))
      revert(0, 0x24)
    }
  }

  /// @dev Reverts with a custom error with a uint160 argument in the scratch space
  function revertWith(bytes4 selector, uint160 value) internal pure {
    assembly("memory-safe") {
      mstore(0, selector)
      mstore(0x04, and(value, 0xffffffffffffffffffffffffffffffffffffffff))
      revert(0, 0x24)
    }
  }

  /// @dev Reverts with a custom error with two int24 arguments
  function revertWith(bytes4 selector, int24 value1, int24 value2) internal pure {
    assembly("memory-safe") {
      let fmp := mload(0x40)
      mstore(fmp, selector)
      mstore(add(fmp, 0x04), signextend(2, value1))
      mstore(add(fmp, 0x24), signextend(2, value2))
      revert(fmp, 0x44)
    }
  }

  /// @dev Reverts with a custom error with two uint160 arguments
  function revertWith(bytes4 selector, uint160 value1, uint160 value2) internal pure {
    assembly("memory-safe") {
      let fmp := mload(0x40)
      mstore(fmp, selector)
      mstore(add(fmp, 0x04), and(value1, 0xffffffffffffffffffffffffffffffffffffffff))
      mstore(add(fmp, 0x24), and(value2, 0xffffffffffffffffffffffffffffffffffffffff))
      revert(fmp, 0x44)
    }
  }

  /// @dev Reverts with a custom error with two address arguments
  function revertWith(bytes4 selector, address value1, address value2) internal pure {
    assembly("memory-safe") {
      mstore(0, selector)
      mstore(0x04, and(value1, 0xffffffffffffffffffffffffffffffffffffffff))
      mstore(0x24, and(value2, 0xffffffffffffffffffffffffffffffffffffffff))
      revert(0, 0x44)
    }
  }

  /// @dev Reverts with a custom error with a bytes32 argument in the scratch space
  function revertWith(bytes4 selector, bytes32 value) internal pure {
    assembly("memory-safe") {
      mstore(0, selector)
      mstore(0x04, value)
      revert(0, 0x24)
    }
  }

  /// @dev Reverts with a custom error with a bytes32 argument in the scratch space
  function revertWith(bytes4 selector, GroupId value) internal pure {
    bytes32 valueBytes = GroupId.unwrap(value);
    assembly("memory-safe") {
      mstore(0, selector)
      mstore(0x04, valueBytes)
      revert(0, 0x24)
    }
  }

  /// @dev Reverts with a custom error with a bytes32 and an address argument
  function revertWith(bytes4 selector, GroupId value, address addr) internal pure {
    bytes32 valueBytes = GroupId.unwrap(value);
    assembly("memory-safe") {
      mstore(0x00, selector)
      mstore(0x04, valueBytes)
      mstore(0x24, and(addr, 0xffffffffffffffffffffffffffffffffffffffff))
      revert(0x00, 0x44)
    }
  }

  /// @dev Reverts with a custom error with a bytes32, address, and uint256 arguments
  function revertWith(bytes4 selector, GroupId value, address addr, uint256 amount) internal pure {
    bytes32 valueBytes = GroupId.unwrap(value);
    assembly("memory-safe") {
      mstore(0x00, selector)
      mstore(0x04, valueBytes)
      mstore(0x24, and(addr, 0xffffffffffffffffffffffffffffffffffffffff))
      mstore(0x44, amount)
      revert(0x00, 0x64)
    }
  }

  /// @notice bubble up the revert message returned by a call and revert with the selector provided
  /// @dev this function should only be used with custom errors of the type `CustomError(address target, bytes revertReason)`
  function bubbleUpAndRevertWith(bytes4 selector, address addr) internal pure {
    assembly("memory-safe") {
      let size := returndatasize()
      let fmp := mload(0x40)

      // Encode selector, address, offset, size, data
      mstore(fmp, selector)
      mstore(add(fmp, 0x04), addr)
      mstore(add(fmp, 0x24), 0x40)
      mstore(add(fmp, 0x44), size)
      returndatacopy(add(fmp, 0x64), 0, size)

      // Ensure the size is a multiple of 32 bytes
      let encodedSize := add(0x64, mul(div(add(size, 31), 32), 32))
      revert(fmp, encodedSize)
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { Currency } from "../types/Currency.sol";
import { Address } from "../types/Address.sol";
import { DefaultFeeParams, FeeParams, FeePermissions, CollateralInfo } from "../types/CommonTypes.sol";

library DTokenRegistry {
  // Core tokens of the group (immutable)
  struct GroupCore {
    Currency aToken; // Yield-bearing token
    Currency xToken; // Leverage token
    Currency baseToken; // Base token for the group - wrapped Avax
    Currency yieldBearingToken; // Example: staked AVAX (immutable)
    Currency wethToken; // WETH token address for the router
  }

  // Decimals for each core token
  struct GroupDecimals {
    uint8 aTokenDecimals;
    uint8 xTokenDecimals;
    uint8 baseTokenDecimals;
    uint8 yieldBearingTokenDecimals;
  }

  // Extended group settings (mutable)
  struct GroupExtended {
    Address priceOracle; // Price Oracle address
    Address rateProvider; // Rate provider address
    Address swapRouter; // Swap Router
    Address treasury; // Treasury address
    Address feeCollector; // Fee collector address
    Address strategy; // Strategy contract address
    Currency rebalancePool; // Rebalance pool address
  }

  // Metadata for the group (partially mutable)
  struct GroupMeta {
    uint96 stabilityRatio; // Mutable stability ratio (this is 2^96-1 and we have max 5e18)
    uint96 stabilityConditionsTriggeringRate; // Mutable stability fee trigger (this is 2^96-1 and we have max 5e18)
    uint8 feeModel; // Immutable fee model used for this group
    bool isWrappingRequired; // Immutable wrapping requirement flag
  }

  // Struct representing full group setup during creation
  struct GroupSetup {
    GroupCore core;
    GroupDecimals decimals;
    GroupExtended extended;
    GroupMeta meta;
    FeeParams fees;
    DefaultFeeParams defaultFees;
    FeePermissions feePermissions;
    CollateralInfo[] acceptableCollaterals;
  }

  // Data used for updating mutable parts of the group
  struct GroupUpdate {
    GroupExtended extended;
    GroupMeta meta;
    CollateralInfo[] acceptableCollaterals;
    FeeParams feeParams;
    DefaultFeeParams defaultFees;
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { Currency } from "./Currency.sol";
import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { Address } from "../types/Address.sol";

// Enums representing different fee models that can be applied.
enum OperationTypes {
  OP_TYPE_MINT_VT,
  OP_TYPE_MINT_YT,
  OP_TYPE_REDEEM_VT,
  OP_TYPE_REDEEM_YT
}

enum FeeModel {
  NONE, // No fees.
  MANAGEMENT_FEE, // Management fee model.
  VARIABLE_FUNDING_FEE, // Fee that varies based on funding.
  FIXED_FUNDING_FEE, // Fixed fee for funding.
  CURATED_PAIRS_FEE, // Curated pairs fee model.
  BLANK_FEE // Blank fee model.
}

// Information about acceptable collaterals
struct CollateralInfo {
  Currency token; // Token address for collateral
  uint8 decimals; // Decimals for the collateral token
  uint256 minAmount; // Minimum amount for both usage minting and redeeming (as desired token)
  uint256 maxAmount; // Maximum amount for both usage minting and redeeming (as desired token)
}

// DefaultFeeParams defines the basic fee structure with base, min, and max fees.
struct DefaultFeeParams {
  uint24 baseFee; // The base fee applied when no flags are present.
  uint24 minFee; // The minimum fee allowed for dynamic fee models.
  uint24 maxFee; // The maximum fee allowed.
}

// FeeParams defines specific fees for different token types and operations.
struct FeeParams {
  uint24 mintFeeVT; // Minting fee for volatile tokens (VT).
  uint24 redeemFeeVT; // Redemption fee for volatile tokens (VT).
  uint24 mintFeeYT; // Minting fee for yield tokens (YT).
  uint24 redeemFeeYT; // Redemption fee for yield tokens (YT).
  uint24 stabilityMintFeeVT; // Stability minting fee for volatile tokens (VT).
  uint24 stabilityMintFeeYT; // Stability minting fee for yield tokens (YT).
  uint24 stabilityRedeemFeeVT; // Stability redemption fee for volatile tokens (VT).
  uint24 stabilityRedeemFeeYT; // Stability redemption fee for yield tokens (YT).
  uint24 yieldFeeVT; // Yield fee for volatile tokens (VT).
  uint24 yieldFeeYT; // Yield fee for yield tokens (YT).
  uint24 protocolFee; // Protocol fee.
}

// FeePermissions define the flexibility of the fee model (dynamic fees, delegation).
struct FeePermissions {
  bool isDynamic; // Whether the fee model is dynamic.
  bool allowDelegation; // Whether fee delegation is allowed.
}

struct GroupState {
  DTokenRegistry.GroupCore core;
  DTokenRegistry.GroupExtended extended;
  bytes32 feesPacked;
  CollateralInfo[] acceptableCollaterals;
  Address hookContract;
  bytes32 groupSettings;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { WordCodec } from "../libs/WordCodec.sol";
import { Address, AddressLibrary } from "../types/Address.sol";
import { Currency, CurrencyLibrary } from "../types/Currency.sol";
import { DefaultFeeParams, FeeParams, FeePermissions, CollateralInfo, GroupState } from "../types/CommonTypes.sol";
import { ITokenRegistry } from "../interfaces/ITokenRegistry.sol";

/**
 * @title GroupStateHelper
 * @notice Library for managing group settings and fee parameters in a space-efficient manner using bit packing
 * @dev Uses WordCodec for bit manipulation operations to store and retrieve various parameters
 */
type GroupSettings is bytes32;

library GroupStateHelper {
  using WordCodec for bytes32;
  using CurrencyLibrary for Currency;
  using AddressLibrary for address;

  // Group Settings bit layout (total 256 bits):
  uint256 private constant A_TOKEN_DECIMALS_OFFSET = 0; // [0-7]:    aToken decimals (8 bits)
  uint256 private constant X_TOKEN_DECIMALS_OFFSET = 8; // [8-15]:   xToken decimals (8 bits)
  uint256 private constant BASE_TOKEN_DECIMALS_OFFSET = 16; // [16-23]:  baseToken decimals (8 bits)
  uint256 private constant YIELD_BEARING_TOKEN_DECIMALS_OFFSET = 24; // [24-31]:  yieldBearingToken decimals (8 bits)
  uint256 private constant HOOK_PERMISSIONS_OFFSET = 32; // [32-47]:  hook permissions (16 bits)
  uint256 private constant FEE_PERMISSIONS_OFFSET = 48; // [48-49]:  fee permissions (2 bits)
  uint256 private constant FEE_MODEL_OFFSET = 50; // [50-57]:  fee model (8 bits)
  uint256 private constant WRAPPING_REQUIRED_OFFSET = 58; // [58]:     wrapping required (1 bit)
  uint256 private constant STABILITY_RATIO_OFFSET = 59; // [59-154]: stability ratio (96 bits)
  uint256 private constant STABILITY_TRIGGER_RATIO_OFFSET = 155; // [155-250]: stability triggering ratio (96 bits)

  // Fee Parameters bit layout (total 256 bits):
  uint256 private constant MAX_FEE_OFFSET = 0; // [0-15]:   max fee (16 bits)
  uint256 private constant MIN_FEE_OFFSET = 16; // [16-31]:  min fee (16 bits)
  uint256 private constant BASE_FEE_OFFSET = 32; // [32-47]:  base fee (16 bits)
  uint256 private constant YIELD_FEE_VT_OFFSET = 48; // [48-63]:  yield fee VT (16 bits)
  uint256 private constant YIELD_FEE_YT_OFFSET = 64; // [64-79]:  yield fee YT (16 bits)
  uint256 private constant REDEEM_FEE_YT_OFFSET = 80; // [80-103]: redeem fee YT (24 bits)
  uint256 private constant MINT_FEE_YT_OFFSET = 104; // [104-127]: mint fee YT (24 bits)
  uint256 private constant REDEEM_FEE_VT_OFFSET = 128; // [128-151]: redeem fee VT (24 bits)
  uint256 private constant MINT_FEE_VT_OFFSET = 152; // [152-175]: mint fee VT (24 bits)
  uint256 private constant STABILITY_MINT_FEE_VT_OFFSET = 176; // [176-191]: stability mint fee VT (16 bits)
  uint256 private constant STABILITY_MINT_FEE_YT_OFFSET = 192; // [192-207]: stability mint fee YT (16 bits)
  uint256 private constant STABILITY_REDEEM_FEE_VT_OFFSET = 208; // [208-223]: stability redeem fee VT (16 bits)
  uint256 private constant STABILITY_REDEEM_FEE_YT_OFFSET = 224; // [224-239]: stability redeem fee YT (16 bits)
  uint256 private constant PROTOCOL_FEE_OFFSET = 240; // [240-255]: protocol fee (16 bits)

  // Common bit lengths
  uint256 private constant LENGTH_1BIT = 1;
  uint256 private constant LENGTH_2BITS = 2;
  uint256 private constant LENGTH_8BITS = 8;
  uint256 private constant LENGTH_16BITS = 16;
  uint256 private constant LENGTH_24BITS = 24;
  uint256 private constant LENGTH_96BITS = 96;

  /**
   * @notice Retrieves the aToken decimals from group settings
   * @param groupSettings The packed group settings
   * @return The aToken decimals
   */
  function getATokenDecimals(GroupSettings groupSettings) internal pure returns (uint8) {
    return uint8(GroupSettings.unwrap(groupSettings).decodeUint(A_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS));
  }

  /**
   * @notice Retrieves the xToken decimals from group settings
   * @param groupSettings The packed group settings
   * @return The xToken decimals
   */
  function getXTokenDecimals(GroupSettings groupSettings) internal pure returns (uint8) {
    return uint8(GroupSettings.unwrap(groupSettings).decodeUint(X_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS));
  }

  /**
   * @notice Retrieves the baseToken decimals from group settings
   * @param groupSettings The packed group settings
   * @return The baseToken decimals
   */
  function getBaseTokenDecimals(GroupSettings groupSettings) internal pure returns (uint8) {
    return uint8(GroupSettings.unwrap(groupSettings).decodeUint(BASE_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS));
  }

  /**
   * @notice Retrieves the yieldBearingToken decimals from group settings
   * @param groupSettings The packed group settings
   * @return The yieldBearingToken decimals
   */
  function getYieldBearingTokenDecimals(GroupSettings groupSettings) internal pure returns (uint8) {
    return uint8(GroupSettings.unwrap(groupSettings).decodeUint(YIELD_BEARING_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS));
  }

  /**
   * @notice Retrieves the hook permissions from group settings
   * @param groupSettings The packed group settings
   * @return The hook permissions
   */
  function getHookPermissions(GroupSettings groupSettings) internal pure returns (uint16) {
    return uint16(GroupSettings.unwrap(groupSettings).decodeUint(HOOK_PERMISSIONS_OFFSET, LENGTH_16BITS));
  }

  /**
   * @notice Retrieves the fee permissions from group settings
   * @param groupSettings The packed group settings
   * @return FeePermissions struct containing permission flags
   */
  function getFeePermissions(GroupSettings groupSettings) internal pure returns (FeePermissions memory) {
    bytes32 raw = GroupSettings.unwrap(groupSettings);
    return
      FeePermissions({ isDynamic: raw.decodeBool(FEE_PERMISSIONS_OFFSET + 1), allowDelegation: raw.decodeBool(FEE_PERMISSIONS_OFFSET) });
  }

  /**
   * @notice Retrieves the fee model from group settings
   * @param groupSettings The packed group settings
   * @return The fee model
   */
  function getFeeModel(GroupSettings groupSettings) internal pure returns (uint8) {
    return uint8(GroupSettings.unwrap(groupSettings).decodeUint(FEE_MODEL_OFFSET, LENGTH_8BITS));
  }

  /**
   * @notice Checks if wrapping is required from group settings
   * @param groupSettings The packed group settings
   * @return True if wrapping is required, false otherwise
   */
  function isWrappingRequired(GroupSettings groupSettings) internal pure returns (bool) {
    return GroupSettings.unwrap(groupSettings).decodeBool(WRAPPING_REQUIRED_OFFSET);
  }

  /**
   * @notice Retrieves the stability ratio from group settings
   * @param groupSettings The packed group settings
   * @return The stability ratio (scaled by 1e18)
   */
  function getStabilityRatio(GroupSettings groupSettings) internal pure returns (uint96) {
    return uint96(GroupSettings.unwrap(groupSettings).decodeUint(STABILITY_RATIO_OFFSET, LENGTH_96BITS));
  }

  /**
   * @notice Retrieves the stability triggering ratio from group settings
   * @param groupSettings The packed group settings
   * @return The stability triggering ratio (scaled by 1e18)
   */
  function getStabilityTriggeringRatio(GroupSettings groupSettings) internal pure returns (uint96) {
    return uint96(GroupSettings.unwrap(groupSettings).decodeUint(STABILITY_TRIGGER_RATIO_OFFSET, LENGTH_96BITS));
  }

  /**
   * @notice Sets the aToken decimals in group settings
   * @param groupSettings Current group settings
   * @param decimals The new aToken decimals
   * @return Updated group settings
   */
  function setATokenDecimals(GroupSettings groupSettings, uint8 decimals) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(decimals), A_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the xToken decimals in group settings
   * @param groupSettings Current group settings
   * @param decimals The new xToken decimals
   * @return Updated group settings
   */
  function setXTokenDecimals(GroupSettings groupSettings, uint8 decimals) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(decimals), X_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the baseToken decimals in group settings
   * @param groupSettings Current group settings
   * @param decimals The new baseToken decimals
   * @return Updated group settings
   */
  function setBaseTokenDecimals(GroupSettings groupSettings, uint8 decimals) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(decimals), BASE_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the yieldBearingToken decimals in group settings
   * @param groupSettings Current group settings
   * @param decimals The new yieldBearingToken decimals
   * @return Updated group settings
   */
  function setYieldBearingTokenDecimals(GroupSettings groupSettings, uint8 decimals) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(decimals), YIELD_BEARING_TOKEN_DECIMALS_OFFSET, LENGTH_8BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the hook permissions in group settings
   * @param groupSettings Current group settings
   * @param hookPermissions The new hook permissions
   * @return Updated group settings
   */
  function setHookPermissions(GroupSettings groupSettings, uint16 hookPermissions) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(hookPermissions), HOOK_PERMISSIONS_OFFSET, LENGTH_16BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the fee permissions in group settings
   * @param groupSettings Current group settings
   * @param permissions The new fee permissions
   * @return Updated group settings
   */
  function setFeePermissions(GroupSettings groupSettings, FeePermissions memory permissions) internal pure returns (GroupSettings) {
    bytes32 raw = GroupSettings.unwrap(groupSettings);
    raw = raw.insertBool(permissions.allowDelegation, FEE_PERMISSIONS_OFFSET);
    raw = raw.insertBool(permissions.isDynamic, FEE_PERMISSIONS_OFFSET + 1);
    return GroupSettings.wrap(raw);
  }

  /**
   * @notice Sets the fee model in group settings
   * @param groupSettings Current group settings
   * @param feeModel The new fee model
   * @return Updated group settings
   */
  function setFeeModel(GroupSettings groupSettings, uint8 feeModel) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(feeModel), FEE_MODEL_OFFSET, LENGTH_8BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the wrapping required flag in group settings
   * @param groupSettings Current group settings
   * @param wrappingRequired The new wrapping required flag
   * @return Updated group settings
   */
  function setWrappingRequired(GroupSettings groupSettings, bool wrappingRequired) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertBool(wrappingRequired, WRAPPING_REQUIRED_OFFSET);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the stability ratio in group settings
   * @param groupSettings Current group settings
   * @param stabilityRatio The new stability ratio (scaled by 1e18)
   * @return Updated group settings
   */
  function setStabilityRatio(GroupSettings groupSettings, uint96 stabilityRatio) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(uint256(stabilityRatio), STABILITY_RATIO_OFFSET, LENGTH_96BITS);
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Sets the stability triggering ratio in group settings
   * @param groupSettings Current group settings
   * @param stabilityTriggeringRatio The new stability triggering ratio (scaled by 1e18)
   * @return Updated group settings
   */
  function setStabilityTriggeringRatio(GroupSettings groupSettings, uint96 stabilityTriggeringRatio) internal pure returns (GroupSettings) {
    bytes32 updated = GroupSettings.unwrap(groupSettings).insertUint(
      uint256(stabilityTriggeringRatio),
      STABILITY_TRIGGER_RATIO_OFFSET,
      LENGTH_96BITS
    );
    return GroupSettings.wrap(updated);
  }

  /**
   * @notice Retrieves all fee parameters from packed fees
   * @param feesPacked The packed fees
   * @return FeeParams struct containing all fee parameters
   */
  function getFeeParams(bytes32 feesPacked) internal pure returns (FeeParams memory) {
    return
      FeeParams({
        mintFeeVT: uint24(feesPacked.decodeUint(MINT_FEE_VT_OFFSET, LENGTH_24BITS)),
        redeemFeeVT: uint24(feesPacked.decodeUint(REDEEM_FEE_VT_OFFSET, LENGTH_24BITS)),
        mintFeeYT: uint24(feesPacked.decodeUint(MINT_FEE_YT_OFFSET, LENGTH_24BITS)),
        redeemFeeYT: uint24(feesPacked.decodeUint(REDEEM_FEE_YT_OFFSET, LENGTH_24BITS)),
        // Upcast 16-bit stability fees to 24-bit
        stabilityMintFeeVT: uint24(uint16(feesPacked.decodeUint(STABILITY_MINT_FEE_VT_OFFSET, LENGTH_16BITS))),
        stabilityMintFeeYT: uint24(uint16(feesPacked.decodeUint(STABILITY_MINT_FEE_YT_OFFSET, LENGTH_16BITS))),
        stabilityRedeemFeeVT: uint24(uint16(feesPacked.decodeUint(STABILITY_REDEEM_FEE_VT_OFFSET, LENGTH_16BITS))),
        stabilityRedeemFeeYT: uint24(uint16(feesPacked.decodeUint(STABILITY_REDEEM_FEE_YT_OFFSET, LENGTH_16BITS))),
        // Upcast 16-bit yield fees to 24-bit
        yieldFeeVT: uint24(uint16(feesPacked.decodeUint(YIELD_FEE_VT_OFFSET, LENGTH_16BITS))),
        yieldFeeYT: uint24(uint16(feesPacked.decodeUint(YIELD_FEE_YT_OFFSET, LENGTH_16BITS))),
        protocolFee: uint16(feesPacked.decodeUint(PROTOCOL_FEE_OFFSET, LENGTH_16BITS))
      });
  }

  /**
   * @notice Retrieves the default fee parameters from packed fees
   * @param feesPacked The packed fees
   * @return DefaultFeeParams struct containing min, max and base fees
   */
  function getDefaultFeeParams(bytes32 feesPacked) internal pure returns (DefaultFeeParams memory) {
    return
      DefaultFeeParams({
        baseFee: uint24(feesPacked.decodeUint(BASE_FEE_OFFSET, LENGTH_16BITS)),
        maxFee: uint16(feesPacked.decodeUint(MAX_FEE_OFFSET, LENGTH_16BITS)),
        minFee: uint16(feesPacked.decodeUint(MIN_FEE_OFFSET, LENGTH_16BITS))
      });
  }

  /**
   * @notice Retrieves the max fee from packed fees
   * @param feesPacked The packed fees
   * @return The max fee value (24-bit)
   */
  function getMaxFee(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(MAX_FEE_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the min fee from packed fees
   * @param feesPacked The packed fees
   * @return The min fee value (24-bit)
   */
  function getMinFee(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(MIN_FEE_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the base fee from packed fees
   * @param feesPacked The packed fees
   * @return The base fee value (24-bit)
   */
  function getBaseFee(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(BASE_FEE_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the yield fee VT from packed fees
   * @param feesPacked The packed fees
   * @return The yield fee VT value (24-bit)
   */
  function getYieldFeeVT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(YIELD_FEE_VT_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the yield fee YT from packed fees
   * @param feesPacked The packed fees
   * @return The yield fee YT value (24-bit)
   */
  function getYieldFeeYT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(YIELD_FEE_YT_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the mint fee VT from packed fees
   * @param feesPacked The packed fees
   * @return The mint fee VT value (24-bit)
   */
  function getMintFeeVT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(feesPacked.decodeUint(MINT_FEE_VT_OFFSET, LENGTH_24BITS));
  }

  /**
   * @notice Retrieves the redeem fee VT from packed fees
   * @param feesPacked The packed fees
   * @return The redeem fee VT value (24-bit)
   */
  function getRedeemFeeVT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(feesPacked.decodeUint(REDEEM_FEE_VT_OFFSET, LENGTH_24BITS));
  }

  /**
   * @notice Retrieves the mint fee YT from packed fees
   * @param feesPacked The packed fees
   * @return The mint fee YT value (24-bit)
   */
  function getMintFeeYT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(feesPacked.decodeUint(MINT_FEE_YT_OFFSET, LENGTH_24BITS));
  }

  /**
   * @notice Retrieves the redeem fee YT from packed fees
   * @param feesPacked The packed fees
   * @return The redeem fee YT value (24-bit)
   */
  function getRedeemFeeYT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(feesPacked.decodeUint(REDEEM_FEE_YT_OFFSET, LENGTH_24BITS));
  }

  /**
   * @notice Retrieves the stability mint fee VT from packed fees
   * @param feesPacked The packed fees
   * @return The stability mint fee VT value (24-bit)
   */
  function getStabilityMintFeeVT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(STABILITY_MINT_FEE_VT_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the stability mint fee YT from packed fees
   * @param feesPacked The packed fees
   * @return The stability mint fee YT value (24-bit)
   */
  function getStabilityMintFeeYT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(STABILITY_MINT_FEE_YT_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the stability redeem fee VT from packed fees
   * @param feesPacked The packed fees
   * @return The stability redeem fee VT value (24-bit)
   */
  function getStabilityRedeemFeeVT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(STABILITY_REDEEM_FEE_VT_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the stability redeem fee YT from packed fees
   * @param feesPacked The packed fees
   * @return The stability redeem fee YT value (24-bit)
   */
  function getStabilityRedeemFeeYT(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(STABILITY_REDEEM_FEE_YT_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Retrieves the protocol fee from packed fees
   * @param feesPacked The packed fees
   * @return The protocol fee value (24-bit)
   */
  function getProtocolFee(bytes32 feesPacked) internal pure returns (uint24) {
    return uint24(uint16(feesPacked.decodeUint(PROTOCOL_FEE_OFFSET, LENGTH_16BITS)));
  }

  /**
   * @notice Sets the max fee in packed fees
   * @param feesPacked Current packed fees
   * @param maxFee The new max fee value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setMaxFee(bytes32 feesPacked, uint24 maxFee) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(maxFee)), MAX_FEE_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the min fee in packed fees
   * @param feesPacked Current packed fees
   * @param minFee The new min fee value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setMinFee(bytes32 feesPacked, uint24 minFee) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(minFee)), MIN_FEE_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the base fee in packed fees
   * @param feesPacked Current packed fees
   * @param baseFee The new base fee value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setBaseFee(bytes32 feesPacked, uint24 baseFee) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(baseFee)), BASE_FEE_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the yield fee VT in packed fees
   * @param feesPacked Current packed fees
   * @param yieldFeeVT The new yield fee VT value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setYieldFeeVT(bytes32 feesPacked, uint24 yieldFeeVT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(yieldFeeVT)), YIELD_FEE_VT_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the yield fee YT in packed fees
   * @param feesPacked Current packed fees
   * @param yieldFeeYT The new yield fee YT value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setYieldFeeYT(bytes32 feesPacked, uint24 yieldFeeYT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(yieldFeeYT)), YIELD_FEE_YT_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the mint fee VT in packed fees
   * @param feesPacked Current packed fees
   * @param mintFeeVT The new mint fee VT value
   * @return Updated packed fees
   */
  function setMintFeeVT(bytes32 feesPacked, uint24 mintFeeVT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(mintFeeVT), MINT_FEE_VT_OFFSET, LENGTH_24BITS);
  }

  /**
   * @notice Sets the redeem fee VT in packed fees
   * @param feesPacked Current packed fees
   * @param redeemFeeVT The new redeem fee VT value
   * @return Updated packed fees
   */
  function setRedeemFeeVT(bytes32 feesPacked, uint24 redeemFeeVT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(redeemFeeVT), REDEEM_FEE_VT_OFFSET, LENGTH_24BITS);
  }

  /**
   * @notice Sets the mint fee YT in packed fees
   * @param feesPacked Current packed fees
   * @param mintFeeYT The new mint fee YT value
   * @return Updated packed fees
   */
  function setMintFeeYT(bytes32 feesPacked, uint24 mintFeeYT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(mintFeeYT), MINT_FEE_YT_OFFSET, LENGTH_24BITS);
  }

  /**
   * @notice Sets the redeem fee YT in packed fees
   * @param feesPacked Current packed fees
   * @param redeemFeeYT The new redeem fee YT value
   * @return Updated packed fees
   */
  function setRedeemFeeYT(bytes32 feesPacked, uint24 redeemFeeYT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(redeemFeeYT), REDEEM_FEE_YT_OFFSET, LENGTH_24BITS);
  }

  /**
   * @notice Sets the stability mint fee VT in packed fees
   * @param feesPacked Current packed fees
   * @param stabilityMintFeeVT The new stability mint fee VT value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setStabilityMintFeeVT(bytes32 feesPacked, uint24 stabilityMintFeeVT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(stabilityMintFeeVT)), STABILITY_MINT_FEE_VT_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the stability mint fee YT in packed fees
   * @param feesPacked Current packed fees
   * @param stabilityMintFeeYT The new stability mint fee YT value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setStabilityMintFeeYT(bytes32 feesPacked, uint24 stabilityMintFeeYT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(stabilityMintFeeYT)), STABILITY_MINT_FEE_YT_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the stability redeem fee VT in packed fees
   * @param feesPacked Current packed fees
   * @param stabilityRedeemFeeVT The new stability redeem fee VT value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setStabilityRedeemFeeVT(bytes32 feesPacked, uint24 stabilityRedeemFeeVT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(stabilityRedeemFeeVT)), STABILITY_REDEEM_FEE_VT_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the stability redeem fee YT in packed fees
   * @param feesPacked Current packed fees
   * @param stabilityRedeemFeeYT The new stability redeem fee YT value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setStabilityRedeemFeeYT(bytes32 feesPacked, uint24 stabilityRedeemFeeYT) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(stabilityRedeemFeeYT)), STABILITY_REDEEM_FEE_YT_OFFSET, LENGTH_16BITS);
  }

  /**
   * @notice Sets the protocol fee in packed fees
   * @param feesPacked Current packed fees
   * @param protocolFee The new protocol fee value (truncated to 16-bit)
   * @return Updated packed fees
   */
  function setProtocolFee(bytes32 feesPacked, uint24 protocolFee) internal pure returns (bytes32) {
    return feesPacked.insertUint(uint256(uint16(protocolFee)), PROTOCOL_FEE_OFFSET, LENGTH_16BITS);
  }

  // Group Core Components Getters

  /**
   * @notice Retrieves the hook contract from group state
   * @param groupState The group state
   * @return The hook contract address wrapper
   */
  function getHookContract(GroupState memory groupState) internal pure returns (Address) {
    return groupState.hookContract;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControlUpgradeable {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/MathUpgradeable.sol";
import "./math/SignedMathUpgradeable.sol";

/**
 * @dev String operations.
 */
library StringsUpgradeable {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = MathUpgradeable.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMathUpgradeable.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, MathUpgradeable.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165Upgradeable.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165Upgradeable is Initializable, IERC165Upgradeable {
    function __ERC165_init() internal onlyInitializing {
    }

    function __ERC165_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165Upgradeable).interfaceId;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20PermitUpgradeable {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.28;

// solhint-disable no-inline-assembly

/// @dev A subset copied from the following contracts:
///
/// + `balancer-labs/v2-solidity-utils/contracts/helpers/WordCodec.sol`
/// + `balancer-labs/v2-solidity-utils/contracts/helpers/WordCodecHelpers.sol`
library WordCodec {
  /// @dev Inserts an unsigned integer of bitLength, shifted by an offset, into a 256 bit word,
  /// replacing the old value. Returns the new word.
  function insertUint(bytes32 word, uint256 value, uint256 offset, uint256 bitLength) internal pure returns (bytes32 result) {
    // Equivalent to:
    // uint256 mask = (1 << bitLength) - 1;
    // bytes32 clearedWord = bytes32(uint256(word) & ~(mask << offset));
    // result = clearedWord | bytes32(value << offset);
    assembly("memory-safe") {
      let mask := sub(shl(bitLength, 1), 1)
      let clearedWord := and(word, not(shl(offset, mask)))
      result := or(clearedWord, shl(offset, value))
    }
  }

  /// @dev Decodes and returns an unsigned integer with `bitLength` bits, shifted by an offset, from a 256 bit word.
  function decodeUint(bytes32 word, uint256 offset, uint256 bitLength) internal pure returns (uint256 result) {
    // Equivalent to:
    // result = uint256(word >> offset) & ((1 << bitLength) - 1);
    assembly("memory-safe") {
      result := and(shr(offset, word), sub(shl(bitLength, 1), 1))
    }
  }

  /// @dev Inserts a signed integer shifted by an offset into a 256 bit word, replacing the old value. Returns
  /// the new word.
  ///
  function insertInt(bytes32 word, int256 value, uint256 offset, uint256 bitLength) internal pure returns (bytes32) {
    unchecked {
      uint256 mask = (1 << bitLength) - 1;
      bytes32 clearedWord = bytes32(uint256(word) & ~(mask << offset));
      // Integer values need masking to remove the upper bits of negative values.
      return clearedWord | bytes32((uint256(value) & mask) << offset);
    }
  }

  /// @dev Decodes and returns a signed integer with `bitLength` bits, shifted by an offset, from a 256 bit word.
  function decodeInt(bytes32 word, uint256 offset, uint256 bitLength) internal pure returns (int256 result) {
    unchecked {
      int256 maxInt = int256((1 << (bitLength - 1)) - 1);
      uint256 mask = (1 << bitLength) - 1;

      int256 value = int256(uint256(word >> offset) & mask);
      // In case the decoded value is greater than the max positive integer that can be represented with bitLength
      // bits, we know it was originally a negative integer. Therefore, we mask it to restore the sign in the 256 bit
      // representation.
      //
      // Equivalent to:
      // result = value > maxInt ? (value | int256(~mask)) : value;
      assembly {
        result := or(mul(gt(value, maxInt), not(mask)), value)
      }
    }
  }

  /// @dev Decodes and returns a boolean shifted by an offset from a 256 bit word.
  function decodeBool(bytes32 word, uint256 offset) internal pure returns (bool result) {
    // Equivalent to:
    // result = (uint256(word >> offset) & 1) == 1;
    assembly {
      result := and(shr(offset, word), 1)
    }
  }

  /// @dev Inserts a boolean value shifted by an offset into a 256 bit word, replacing the old value. Returns the new
  /// word.
  function insertBool(bytes32 word, bool value, uint256 offset) internal pure returns (bytes32 result) {
    // Equivalent to:
    // bytes32 clearedWord = bytes32(uint256(word) & ~(1 << offset));
    // bytes32 referenceInsertBool = clearedWord | bytes32(uint256(value ? 1 : 0) << offset);
    assembly("memory-safe") {
      let clearedWord := and(word, not(shl(offset, 1)))
      result := or(clearedWord, shl(offset, value))
    }
  }

  function clearWordAtPosition(bytes32 word, uint256 offset, uint256 bitLength) internal pure returns (bytes32 clearedWord) {
    unchecked {
      uint256 mask = (1 << bitLength) - 1;
      clearedWord = bytes32(uint256(word) & ~(mask << offset));
    }
  }

  /// @dev Encodes an address into a 256 bit word at a given offset.
  function insertAddress(bytes32 word, address value, uint256 offset) internal pure returns (bytes32 result) {
    assembly("memory-safe") {
      let clearedWord := and(word, not(shl(offset, 0xffffffffffffffffffffffffffffffffffffffff)))
      result := or(clearedWord, shl(offset, value))
    }
  }

  /// @dev Decodes an address from a 256 bit word at a given offset.
  function decodeAddress(bytes32 word, uint256 offset) internal pure returns (address result) {
    assembly("memory-safe") {
      result := and(shr(offset, word), 0xffffffffffffffffffffffffffffffffffffffff)
    }
  }

  /// @dev Encodes an enum value into a 256 bit word at a given offset.
  function insertEnum(bytes32 word, uint8 value, uint256 offset) internal pure returns (bytes32 result) {
    assembly("memory-safe") {
      let clearedWord := and(word, not(shl(offset, 0xff)))
      result := or(clearedWord, shl(offset, value))
    }
  }

  /// @dev Decodes an enum value from a 256 bit word at a given offset.
  function decodeEnum(bytes32 word, uint256 offset) internal pure returns (uint8 result) {
    assembly("memory-safe") {
      result := and(shr(offset, word), 0xff)
    }
  }
}

// SPDX-License-Identifier: MI
pragma solidity 0.8.28;

import { CustomRevert } from "./CustomRevert.sol";
import { FeePermissions, DefaultFeeParams } from "../types/CommonTypes.sol";

/**
 * @title GroupFeeLibrary
 * @dev Provides utilities to manage fees for groups with their own fee structures and permissions.
 *      This library handles fee validation, processing, and manipulation based on defined flags and permissions.
 */
library GroupFeeLibrary {
  // Utilize the CustomRevert library for standardized error handling via selectors.
  using CustomRevert for bytes4;

  /**
   * @dev Thrown when a fee exceeds the allowed maximum.
   * @param fee The fee value that is too large.
   */
  error InvalidGroupFee(uint24 fee);

  /**
   * @dev Thrown when fee delegation is attempted without permission.
   */
  error FeeDelegationNotAllowed();

  error BaseFeeExceedslimit();
  error MinFeeExceedsBaseFee();
  error MaxFeeIsLessThanBaseFee();
  error MaxFeeExceedsLimit();

  /**
   * @dev Thrown when a dynamic fee operation is called but not allowed.
   */
  error NotDynamicFeeGroup();

  // ====================
  // ==== Constants ====
  // ====================

  /**
   * @dev Flag indicating dynamic fees. Embedded in the fee's uint24 value.
   *      Example: fee | 0x800000
   */
  uint24 public constant DYNAMIC_FEE_FLAG = 0x800000;

  /**
   * @dev Flag for overriding fees. Embedded in the fee's uint24 value.
   *      Example: fee |0x400000
   */
  uint24 public constant OVERRIDE_FEE_FLAG = 0x400000;

  /**
   * @dev Flag allowing fee delegation. Embedded in the fee's uint24 value.
   *      Example: fee | 0x200000
   */
  uint24 public constant DELEGATE_FEE_FLAG = 0x200000;

  /**
   * @dev Flag for explicit zero fee. Embedded in the fee's uint24 value.
   *      Example: fee |0x100000
   * @notice Group min Fee settings has the priority over this flag, so it's impossible where minFee not equal to zero
   */
  uint24 public constant ZERO_FEE_FLAG = 0x100000;

  /**
   * @dev Mask to remove all flags from the fee's uint24 value.
   *      Example: fee |0x1FFFFF
   *  All flags (0x800000, 0x400000, 0x200000, 0x100000) are in the upper 4 bits
   *  limiting the mask to 0x0FFFFF, all these flags are cleared.
   */
  uint24 public constant REMOVE_ALL_FLAGS_MASK = 0x0FFFFF;

  /**
   * @dev Maximum allowed group fee (10,000 BPS). 50% expressed in basis points.
   */
  uint24 public constant MAX_GROUP_FEE = 5_000;

  // ====================
  // ==== Internal Functions ====
  // ====================

  /**
   * @notice Validates whether the given fee is within acceptable boundaries.
   * @param self The DefaultFeeParams struct containing fee parameters.
   * @param fee The fee value to validate.
   * @return True if the fee is valid, false otherwise.
   *
   * @dev The cleaned fee (without flags) must be within the min/max fee limits and not exceed MAX_GROUP_FEE.
   */
  function isValid(DefaultFeeParams memory self, uint24 fee) internal pure returns (bool) {
    // Clean the fee by removing any flags (since flags do not affect fee validation).
    uint24 cleanFee = fee & REMOVE_ALL_FLAGS_MASK;

    // The cleaned fee must be within the min/max fee limits and not exceed MAX_GROUP_FEE.
    /// @dev The cleaned fee must be within the min/max fee limits and not exceed MAX_GROUP_FEE, eventhough hook sent with ZERO_FEE_FLAG
    return cleanFee >= self.minFee && cleanFee <= self.maxFee && cleanFee <= MAX_GROUP_FEE;
  }

  /**
   * @notice Checks if the fee has the dynamic fee flag set.
   * @param fee The fee value to check.
   * @return True if the dynamic fee flag is set, false otherwise.
   */
  function isDynamicFee(uint24 fee) internal pure returns (bool) {
    return fee & DYNAMIC_FEE_FLAG != 0;
  }

  /**
   * @notice Checks if the fee has an override flag.
   * @param fee The fee value to check.
   * @return True if the override flag is set, false otherwise.
   */
  function isOverride(uint24 fee) internal pure returns (bool) {
    return fee & OVERRIDE_FEE_FLAG != 0;
  }

  /**
   * @notice Checks if the fee has the delegation flag set.
   * @param fee The fee value to check.
   * @return True if the delegation flag is set, false otherwise.
   */
  function isDelegate(uint24 fee) internal pure returns (bool) {
    return fee & DELEGATE_FEE_FLAG != 0;
  }

  /**
   * @notice Removes all flags from the fee (i.e., cleans it to its base value).
   * @param fee The fee value to clean.
   * @return cleanedFee The fee value without any flags.
   */
  function _removeAllFlags(uint24 fee) internal pure returns (uint24 cleanedFee) {
    return fee & REMOVE_ALL_FLAGS_MASK;
  }

  /**
   * @notice Validates the group fee based on default fee parameters and permissions.
   * @param self The DefaultFeeParams struct containing fee parameters.
   * @param permissions The FeePermissions struct containing permission flags.
   * @param checkingFee The fee value to validate.
   * @return The validated fee.
   *
   * @dev Ensures the fee is within allowed bounds and adheres to permissions.
   */
  function _validateGroupFee(
    DefaultFeeParams memory self,
    FeePermissions memory permissions,
    uint24 checkingFee
  ) internal pure returns (uint24) {
    // Ensure fee delegation is allowed.
    if (!permissions.allowDelegation && isDelegate(checkingFee)) {
      FeeDelegationNotAllowed.selector.revertWith();
    }

    if (!permissions.isDynamic && isDynamicFee(checkingFee)) {
      NotDynamicFeeGroup.selector.revertWith();
    }

    // Validate fee bounds
    bool validated = isValid(self, checkingFee);
    if (!validated) {
      InvalidGroupFee.selector.revertWith(checkingFee);
    }
    return checkingFee;
  }

  /**
   * @notice Processes the group fee, applying validations and possible overrides.
   * @param self The DefaultFeeParams struct containing fee parameters.
   * @param permissions The FeePermissions struct containing permission flags.
   * @param overrideFee The fee value that may override the default base fee.
   * @return cleanFee The processed and validated fee.
   */
  function processGroupFee(
    DefaultFeeParams memory self,
    FeePermissions memory permissions,
    uint24 overrideFee
  ) internal pure returns (uint24 cleanFee) {
    cleanFee = _validateGroupFee(self, permissions, overrideFee);
  }

  /**
   * @notice Validates the fee parameters to ensure they are logically correct.
   * @param params The DefaultFeeParams struct containing fee parameters.
   *
   * @dev Ensures that:
   *      - Base fee does not exceed MAX_GROUP_FEE.
   *      - Minimum fee is not greater than the base fee.
   *      - Maximum fee is not less than the base fee.
   *      - Maximum fee does not exceed MAX_GROUP_FEE.
   */
  function _validateFeeParams(DefaultFeeParams memory params) internal pure {
    // Base fee should not exceed the maximum group fee.
    if (params.baseFee > MAX_GROUP_FEE) {
      BaseFeeExceedslimit.selector.revertWith();
    }
    // Min fee must be less than or equal to base fee.
    if (params.minFee > params.baseFee) {
      MinFeeExceedsBaseFee.selector.revertWith();
    }
    // Max fee must be greater than or equal to base fee.
    if (params.maxFee < params.baseFee) {
      MaxFeeIsLessThanBaseFee.selector.revertWith();
    }
    // Max fee should not exceed the maximum allowed group fee.
    if (params.maxFee > MAX_GROUP_FEE) {
      MaxFeeExceedsLimit.selector.revertWith();
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { CustomRevert } from "./CustomRevert.sol";
import { GroupId } from "../types/GroupId.sol";
import { IHooks } from "../interfaces/IHooks.sol";
import { DOperationContext } from "../declarations/DOperationContext.sol";
import { OperationContextLibrary } from "./OperationContextLibrary.sol";
import { GroupFeeLibrary } from "./GroupFeeLibrary.sol";

/**
 * @title HookLibrary
 * @notice Provides utilities to manage hooks related to minting, redeeming.
 *         It handles the invocation of hook functions and manages `hookData` only when necessary.
 * @dev Hooks are for internal purpose so its generally safer
 */
library HookLibrary {
  using GroupFeeLibrary for uint24;
  using OperationContextLibrary for DOperationContext.OperationContext;
  using CustomRevert for bytes4;

  uint256 internal constant MAX_HOOK_DATA_LENGTH = 1024; // 1 KB limit for hookData
  uint256 internal constant EMPTY_BYTES_LENGTH = 32; // bytes length when empty
  uint256 internal constant MIN_HOOK_RESPONSE_LENGTH = 32 + 32; // bytes4 selector + empty bytes updatedHookData
  uint256 internal constant MAX_HOOK_RESPONSE_LENGTH = MIN_HOOK_RESPONSE_LENGTH + MAX_HOOK_DATA_LENGTH; // bytes4 selector + bytes hookData + uint24 lpFeeOverride

  /// @dev Thrown when the hook response is invalid.
  error InvalidHookResponse(GroupId groupId);

  /// @dev Thrown when the provided hook contract address is invalid.
  /// @param hookContract The address of the invalid hook contract.
  error InvalidHookContract(address hookContract);

  /// @dev Thrown when a hook call fails, providing the hook address and revert reason.
  /// @param hookContract The address of the hook contract that failed.
  /// @param revertReason The raw revert reason returned by the hook contract.
  error Wrap__FailedHookCall(address hookContract, bytes revertReason);

  /// @dev Emitted when a hook call fails.
  /// @param hookContract The address of the hook contract.
  /// @param hookType The type of hook attempted.
  /// @param sender The address initiating the hook.
  /// @param groupId The identifier of the group.
  /// @param reason The reason for the hook failure.
  event HookFailed(GroupId indexed groupId, address indexed hookContract, address indexed sender, string hookType, string reason);

  /**
   * @dev Defines the structure of permissions for various hook operations.
   */
  struct Permissions {
    bool beforeMint;
    bool afterMint;
    bool beforeRedeem;
    bool afterRedeem;
  }

  // Permission Flags
  uint16 internal constant BEFORE_MINT_FLAG = 1 << 0;
  uint16 internal constant AFTER_MINT_FLAG = 1 << 1;
  uint16 internal constant BEFORE_REDEEM_FLAG = 1 << 2;
  uint16 internal constant AFTER_REDEEM_FLAG = 1 << 3;

  // Mask of all possible flags
  uint16 internal constant ALL_HOOK_MASK = BEFORE_MINT_FLAG | AFTER_MINT_FLAG | BEFORE_REDEEM_FLAG | AFTER_REDEEM_FLAG;

  // =========================
  // ==== Permission Functions =====
  // =========================

  /**
   * @dev Packs the permissions into a uint16.
   * @param flags The Permissions struct containing individual permission flags.
   * @return permissions The packed permissions as a uint16.
   */
  function packPermissions(Permissions memory flags) internal pure returns (uint16 permissions) {
    if (flags.beforeMint) permissions |= BEFORE_MINT_FLAG;
    if (flags.afterMint) permissions |= AFTER_MINT_FLAG;
    if (flags.beforeRedeem) permissions |= BEFORE_REDEEM_FLAG;
    if (flags.afterRedeem) permissions |= AFTER_REDEEM_FLAG;
  }

  // =========================
  // ==== Hook Contract Validation =====
  // =========================

  /**
   * @dev Validates the permissions of a hook contract during initialization.
   * @param self The IHooks contract.
   * @param expectedPermissions The expected uint16 packed permissions
   */
  function validateHookPermissions(IHooks self, uint16 expectedPermissions) internal view {
    uint16 actualPermissions = getHookContractPermissions(self);
    if (actualPermissions != expectedPermissions) {
      InvalidHookContract.selector.revertWith(address(self));
    }
  }

  /**
   * @dev Checks if a hook contract is valid during initialization.
   * @param self The IHooks contract.
   * @param fee The fee associated with the hook.
   * @return True if the hook contract is valid.
   */
  function isValidHookContract(IHooks self, uint24 fee) internal view returns (bool) {
    if (address(self) == address(0)) {
      // If there is no hook contract set, then fee cannot be dynamic
      return !fee.isDynamicFee();
    } else {
      // If a hook contract is set, it must have at least 1 flag set, or have a dynamic fee
      uint16 permissions = getHookContractPermissions(self);
      return (permissions & ALL_HOOK_MASK != 0) || fee.isDynamicFee();
    }
  }

  /**
   * @dev Retrieves the permissions from the hook contract.
   * @param self The IHooks contract.
   * @return The permissions as a uint16.
   */
  function getHookContractPermissions(IHooks self) internal view returns (uint16) {
    (bool success, bytes memory data) = address(self).staticcall(abi.encodeWithSelector(IHooks.getHookPermissions.selector));
    if (!success || data.length == 0) {
      InvalidHookContract.selector.bubbleUpAndRevertWith(address(self));
    }
    uint16 permissions = abi.decode(data, (uint16));
    return permissions;
  }

  /**
   * @dev Checks if the given permissions include the specified flag.
   * @param actualPermissions The actual permissions represented as a uint256.
   * @param flag The permission flag to check.
   * @return True if the flag is set in the actualPermissions.
   */
  function hasPermission(uint256 actualPermissions, uint16 flag) internal pure returns (bool) {
    return uint16(actualPermissions) & flag != 0;
  }

  // =========================
  // ==== Hook Invocation =====
  // =========================

  /**
   * @dev Calls the hook contract with the provided data.
   * @param self The IHooks contract.
   * @param data The calldata to be sent to the hook contract.
   * @return result The result returned by the hook contract.
   */
  function callHook(IHooks self, bytes memory data) internal returns (bytes memory result) {
    bool success;
    assembly ("memory-safe") {
      success := call(gas(), self, 0, add(data, 32), mload(data), 0, 0)
      let size := returndatasize()
      result := mload(0x40) // Load the free memory pointer
      mstore(0x40, add(result, and(add(size, 63), not(31)))) // Update free memory pointer
      mstore(result, size) // Set the length of result
      returndatacopy(add(result, 32), 0, size) // Copy return data
    }
    if (!success) {
      if (!success) Wrap__FailedHookCall.selector.bubbleUpAndRevertWith(address(self));
    }
  }

  // =========================
  // ==== Hook Operations =====
  // =========================

  /**
   * @dev Modifier to prevent self-calls to the hook contract.
   * @param self The IHooks contract.
   */
  modifier noSelfCall(IHooks self) {
    if (msg.sender != address(self)) {
      _;
    }
  }

  /**
   * @dev Invokes the beforeMint hook if the permission is set.
   * @param self The IHooks contract.
   * @param groupId The GroupId for the operation.
   * @param context The operation context.
   */
  function beforeMint(IHooks self, GroupId groupId, DOperationContext.OperationContext memory context) internal noSelfCall(self) {
    if (!hasPermission(context.getHookPermissions(), BEFORE_MINT_FLAG)) {
      return;
    }

    bytes memory hookData = context.getHookData();
    uint24 contextFee = context.getContextFee();
    bool isDynamic = contextFee & GroupFeeLibrary.DYNAMIC_FEE_FLAG != 0;
    bool isDelegate = contextFee & GroupFeeLibrary.DELEGATE_FEE_FLAG != 0;

    bytes memory data = abi.encodeWithSelector(IHooks.beforeMint.selector, msg.sender, groupId, context, hookData);

    bytes memory result = callHook(self, data);

    if (result.length == 0) {
      // Hook call failed or returned empty result, proceed without changing context
      return;
    }

    // Expected result is (bytes4 selector, bytes updatedHookData, 24 lpFeeOverride)
    /// @notice Each primitive type gets padded to 32 bytes + bytes
    if (result.length < MIN_HOOK_RESPONSE_LENGTH + MIN_HOOK_RESPONSE_LENGTH || result.length > MAX_HOOK_RESPONSE_LENGTH) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    (bytes4 returnedSelector, bytes memory updatedHookData, uint24 lpFeeOverrideUint) = abi.decode(result, (bytes4, bytes, uint24));

    if (returnedSelector != IHooks.beforeMint.selector) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    (bool isValid, uint24 lpFeeOverride) = _sanitizeAndProcessFeeOverride(lpFeeOverrideUint);

    if (isValid && lpFeeOverride > 0 && (isDynamic || isDelegate)) {
      // Update the fee in the context
      context.setOverriddenFee(lpFeeOverride);
    }

    // Update hookData in context
    setHookData(context, updatedHookData);
  }

  /**
   * @dev Sanitizes and processes the fee override value.
   * @param _lpFeeOverrideUint The fee override value to sanitize.
   * @return isValid True if the fee override is valid, false otherwise.
   * @return fee The sanitized fee override value.
   */
  function _sanitizeAndProcessFeeOverride(uint24 _lpFeeOverrideUint) internal pure returns (bool, uint24) {
    uint24 sanitizedFee = _lpFeeOverrideUint & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK;

    // If ZERO_FEE_FLAG is set, REQUIRE fee amount to be 0
    if (_lpFeeOverrideUint & GroupFeeLibrary.ZERO_FEE_FLAG != 0) {
      // If hook claims zero fee but sends non-zero amount, reject it
      if (sanitizedFee != 0) {
        return (false, 0);
      }
      return (true, GroupFeeLibrary.ZERO_FEE_FLAG);
    }

    // For non-zero fee cases
    return (sanitizedFee > 0, sanitizedFee);
  }

  /**
   * @dev Invokes the afterMint hook if the permission is set.
   * @param self The IHooks contract.
   * @param groupId The GroupId for the operation.
   * @param context The operation context.
   */
  function afterMint(IHooks self, GroupId groupId, DOperationContext.OperationContext memory context) internal noSelfCall(self) {
    if (!hasPermission(context.getHookPermissions(), AFTER_MINT_FLAG)) {
      return;
    }

    bytes memory hookData = context.getHookData();
    bytes memory data = abi.encodeWithSelector(IHooks.afterMint.selector, msg.sender, groupId, context, hookData);

    bytes memory result = callHook(self, data);

    if (result.length == 0) {
      // Hook call failed or returned empty result, proceed without changing context
      return;
    }

    // Expected result is (bytes4 selector, bytes updatedHookData)
    /// @notice Each primitive type gets padded to 32 bytes + bytes
    if (result.length < MIN_HOOK_RESPONSE_LENGTH || result.length > MAX_HOOK_RESPONSE_LENGTH) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    (bytes4 returnedSelector, bytes memory updatedHookData) = abi.decode(result, (bytes4, bytes));

    if (returnedSelector != IHooks.afterMint.selector) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    // Update hookData in context
    setHookData(context, updatedHookData);
  }

  /**
   * @dev Invokes the beforeRedeem hook if the permission is set.
   * @param self The IHooks contract.
   * @param groupId The GroupId for the operation.
   * @param context The operation context.
   */
  function beforeRedeem(IHooks self, GroupId groupId, DOperationContext.OperationContext memory context) internal noSelfCall(self) {
    if (!hasPermission(context.getHookPermissions(), BEFORE_REDEEM_FLAG)) {
      return;
    }

    bytes memory hookData = context.getHookData();
    uint24 contextFee = context.getContextFee();
    bool isDynamic = contextFee & GroupFeeLibrary.DYNAMIC_FEE_FLAG != 0;
    bool isDelegate = contextFee & GroupFeeLibrary.DELEGATE_FEE_FLAG != 0;

    bytes memory data = abi.encodeWithSelector(IHooks.beforeRedeem.selector, msg.sender, groupId, context, hookData);

    bytes memory result = callHook(self, data);

    if (result.length == 0) {
      // Hook call failed or returned empty result, proceed without changing context
      return;
    }

    // Expected result is (bytes4 selector, bytes updatedHookData, uint24 lpFeeOverride)
    /// @notice Each primitive type gets padded to 32 bytes
    if (result.length < MIN_HOOK_RESPONSE_LENGTH + MIN_HOOK_RESPONSE_LENGTH || result.length > MAX_HOOK_RESPONSE_LENGTH) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    (bytes4 returnedSelector, bytes memory updatedHookData, uint24 lpFeeOverrideUint) = abi.decode(result, (bytes4, bytes, uint24));

    if (returnedSelector != IHooks.beforeRedeem.selector) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    (bool isValid, uint24 lpFeeOverride) = _sanitizeAndProcessFeeOverride(lpFeeOverrideUint);

    if (isValid && lpFeeOverride > 0 && lpFeeOverride != context.getContextFee() && (isDynamic || isDelegate)) {
      // Update the fee in the context
      context.setOverriddenFee(lpFeeOverride);
    }

    // Update hookData in context
    setHookData(context, updatedHookData);
  }

  /**
   * @dev Invokes the afterRedeem hook if the permission is set.
   * @param self The IHooks contract.
   * @param groupId The GroupId for the operation.
   * @param context The operation context.
   */
  function afterRedeem(IHooks self, GroupId groupId, DOperationContext.OperationContext memory context) internal noSelfCall(self) {
    if (!hasPermission(context.getHookPermissions(), AFTER_REDEEM_FLAG)) {
      return;
    }

    bytes memory hookData = context.getHookData();
    bytes memory data = abi.encodeWithSelector(IHooks.afterRedeem.selector, msg.sender, groupId, context, hookData);

    bytes memory result = callHook(self, data);

    if (result.length == 0) {
      // Hook call failed or returned empty result, proceed without changing context
      return;
    }

    // Expected result is (bytes4 selector, bytes updatedHookData)
    /// @notice Each primitive type gets padded to 32 bytes + bytes
    if (result.length < MIN_HOOK_RESPONSE_LENGTH || result.length > MAX_HOOK_RESPONSE_LENGTH) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    (bytes4 returnedSelector, bytes memory updatedHookData) = abi.decode(result, (bytes4, bytes));

    if (returnedSelector != IHooks.afterRedeem.selector) {
      InvalidHookResponse.selector.revertWith(context.groupId);
    }

    // Update hookData in context
    setHookData(context, updatedHookData);
  }

  // =========================
  // ==== Helper Functions =====
  // =========================

  /**
   * @dev Sets the hookData in the operation context.
   * @param context The operation context.
   * @param hookData The hook data to set.
   */
  function setHookData(DOperationContext.OperationContext memory context, bytes memory hookData) internal pure {
    context.setHookData(hookData);
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { GroupId } from "../types/GroupId.sol";
import { DOperationContext } from "../declarations/DOperationContext.sol";

/**
 * @title IHooks
 * @notice Interface defining hooks that can be called during protocol operations
 * @dev This interface must be implemented by any contract that wants to act as a hook
 */
interface IHooks {
  /**
   * @notice Returns the permissions of the hook contract
   * @return A uint16 representing the permission flags
   */
  function getHookPermissions() external view returns (uint16);

  /**
   * @notice Hook called before a mint operation
   * @param sender The address initiating the operation
   * @param groupId The group identifier
   * @param context The operation context
   * @param hookData The current hook data
   * @return selector The function selector (should be `beforeMint.selector`)
   * @return updatedHookData The updated hook data
   * @return lpFeeOverride An optional LP fee override
   */
  function beforeMint(
    address sender,
    GroupId groupId,
    DOperationContext.OperationContext calldata context,
    bytes calldata hookData
  ) external returns (bytes4 selector, bytes memory updatedHookData, uint24 lpFeeOverride);

  /**
   * @notice Hook called after a mint operation
   * @param sender The address initiating the operation
   * @param groupId The group identifier
   * @param context The operation context
   * @param hookData The current hook data
   * @return selector The function selector (should be `afterMint.selector`)
   * @return updatedHookData The updated hook data
   */
  function afterMint(
    address sender,
    GroupId groupId,
    DOperationContext.OperationContext calldata context,
    bytes calldata hookData
  ) external returns (bytes4 selector, bytes memory updatedHookData);

  /**
   * @notice Hook called before a redeem operation
   * @param sender The address initiating the operation
   * @param groupId The group identifier
   * @param context The operation context
   * @param hookData The current hook data
   * @return selector The function selector (should be `beforeRedeem.selector`)
   * @return updatedHookData The updated hook data
   * @return lpFeeOverride An optional LP fee override
   */
  function beforeRedeem(
    address sender,
    GroupId groupId,
    DOperationContext.OperationContext calldata context,
    bytes calldata hookData
  ) external returns (bytes4 selector, bytes memory updatedHookData, uint24 lpFeeOverride);

  /**
   * @notice Hook called after a redeem operation
   * @param sender The address initiating the operation
   * @param groupId The group identifier
   * @param context The operation context
   * @param hookData The current hook data
   * @return selector The function selector (should be `afterRedeem.selector`)
   * @return updatedHookData The updated hook data
   */
  function afterRedeem(
    address sender,
    GroupId groupId,
    DOperationContext.OperationContext calldata context,
    bytes calldata hookData
  ) external returns (bytes4 selector, bytes memory updatedHookData);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library MathUpgradeable {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMathUpgradeable {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165Upgradeable {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { Currency } from "../types/Currency.sol";
import { GroupId } from "../types/GroupId.sol";
import { Slot0 } from "../types/Slot0.sol";
import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { Address } from "../types/Address.sol";
import { GroupState, CollateralInfo } from "../types/CommonTypes.sol";

/**
 * @title DOperationContext
 * @notice Library containing the data structures used for operation contexts.
 */
library DOperationContext {
  /**
   * @notice Struct representing amounts used in the context.
   */
  struct ContextAmounts {
    uint256 amount0;
    uint256 amount1;
  }

  /**
   * @notice Struct representing a tight group state.
   */
  struct TightGroupState {
    DTokenRegistry.GroupCore core;
    DTokenRegistry.GroupExtended extended;
    bytes32 groupSettings;
    bytes32 feesPacked;
    Address hookContract;
  }

  /**
   * @notice Struct containing parameters needed to create an operation context.
   */
  struct Context {
    uint8 operationType;
    ContextAmounts amounts;
    uint24 slippage;
    address recipient;
    CollateralInfo paymentToken;
    GroupId groupId;
    GroupState groupState;
    bytes hookData;
  }

  /**
   * @notice Struct representing parameters packed into Slot0 and Slot1 (memory bytes).
   */
  struct Params {
    Slot0 slot0;
    bytes slot1;
  }

  /**
   * @notice Struct representing the full operation context.
   */
  struct OperationContext {
    GroupId groupId;
    Params params;
    TightGroupState groupState;
    uint256 amount0;
    uint256 amount1;
    uint24 slippage;
    address recipient;
    CollateralInfo paymentToken;
    uint256 collateralRatio;
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { DOperationContext } from "../declarations/DOperationContext.sol";
import { Slot0, Slot0Library } from "../types/Slot0.sol";
import { Currency, CurrencyLibrary } from "../types/Currency.sol";
import { GroupId } from "../types/GroupId.sol";
import { CustomRevert } from "./CustomRevert.sol";
// import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { Address, AddressLibrary } from "../types/Address.sol";
import { GroupState, FeePermissions, DefaultFeeParams, OperationTypes } from "../types/CommonTypes.sol";
import { GroupStateHelper, GroupSettings } from "../types/GroupStateHelper.sol";
import { GroupFeeLibrary } from "../libs/GroupFeeLibrary.sol";
import { IRateProvider } from "../interfaces/IRateProvider.sol";
import { ITreasury } from "../interfaces/ITreasury.sol";

/**
 * @title OperationContextLibrary
 * @notice Library for creating and managing operation contexts within the protocol.
 */
library OperationContextLibrary {
  using Slot0Library for Slot0;
  using GroupStateHelper for GroupState;
  using GroupStateHelper for GroupSettings;
  using AddressLibrary for Address;
  using CurrencyLibrary for Currency;
  using CustomRevert for bytes4;

  // Custom Errors
  error ZeroAddress(GroupId groupId);
  error ZeroAmount(GroupId groupId);
  error CycleOperationsAreNotPermitted(GroupId groupId);
  error InvalidCollateralRatio(GroupId groupId);
  error ErrorMintingPausedInStabilityMode(GroupId groupId);
  error InvalidOperationType(GroupId groupId);
  error ErrorGettingRate(GroupId groupId, uint256 rate);
  error InvalidSlippageTolerance(GroupId groupId, uint256 minAmount1, uint256 amount0);
  error ArbitraryCallsNotAllowed(GroupId groupId, address recipient, address sender);

  // Constants
  uint256 private constant PRECISION = 1e18;
  uint24 private constant MAX_SLIPPAGE_TOLERANCE = 1_000; // 10% bps
  uint24 private constant BASIS_POINTS = 10_000;

  /**
   * @notice Creates an operation context.
   * @param params Struct containing parameters needed to create the context.
   * @return context The created operation context.
   */
  function createContext(
    DOperationContext.Context memory params
  ) internal view returns (DOperationContext.OperationContext memory context) {
    // Validate recipient and amounts
    _validateParams(params);

    // Initialize context without applying slippage checks
    context = _initializeContext(params);

    // Retrieve operation type
    uint8 operationType = params.operationType;

    // Get stability ratios
    uint96 stabilityRatio = _getStabilityRatio(params);
    uint96 stabilityConditionsTriggeringRate = _getstabilityConditionsTriggeringRate(params);

    // Retrieve collateral ratio and validate
    context.collateralRatio = _getCollateralRatio(params, stabilityRatio);

    // Calculate context fee & override fee depending on the group's permissions
    uint24 contextFee = _calculateContextFee(params, operationType, context.collateralRatio, stabilityConditionsTriggeringRate);

    // Get initial protocol fee
    uint24 initialProtocolFee = GroupStateHelper.getProtocolFee(params.groupState.feesPacked);

    // Pack Slot0 and Slot1
    context.params = _createParams(params, operationType, initialProtocolFee, contextFee, stabilityConditionsTriggeringRate);
  }

  // ------ Helper Functions ------ //

  /**
   * @notice Validates the parameters for creating an operation context.
   * @param params Struct containing parameters needed to create the context.
   */
  function _validateParams(DOperationContext.Context memory params) internal pure {
    if (params.recipient == address(0)) {
      ZeroAddress.selector.revertWith(params.groupId);
    }

    if (params.amounts.amount0 == 0 && params.amounts.amount1 == 0) {
      ZeroAmount.selector.revertWith(params.groupId);
    }

    if (params.slippage > MAX_SLIPPAGE_TOLERANCE) {
      revert InvalidSlippageTolerance(params.groupId, params.slippage, MAX_SLIPPAGE_TOLERANCE);
    }
  }

  /**
   * @notice Initializes the operation context without applying slippage checks.
   * @param params Struct containing parameters needed to create the context.
   * @return context The initialized operation context.
   */
  function _initializeContext(
    DOperationContext.Context memory params
  ) internal pure returns (DOperationContext.OperationContext memory context) {
    context.groupId = params.groupId;
    context.amount0 = params.amounts.amount0;
    context.amount1 = params.amounts.amount1;
    context.recipient = params.recipient;
    context.paymentToken = params.paymentToken;
    context.slippage = _validateSlippage(params.groupId, params.slippage);
    context.groupState = DOperationContext.TightGroupState({
      core: params.groupState.core,
      extended: params.groupState.extended,
      groupSettings: params.groupState.groupSettings,
      feesPacked: params.groupState.feesPacked,
      hookContract: params.groupState.hookContract
    });
  }

  /**
   * @notice Validates the slippage value.
   * @param groupId The group ID.
   * @param slippage The slippage value to validate.
   * @return The validated slippage value.
   */
  function _validateSlippage(GroupId groupId, uint24 slippage) internal pure returns (uint24) {
    if (slippage > MAX_SLIPPAGE_TOLERANCE) {
      revert InvalidSlippageTolerance(groupId, slippage, MAX_SLIPPAGE_TOLERANCE);
    }

    return slippage;
  }

  /**
   * @notice Retrieves the collateral ratio and validates it.
   * @param params Struct containing parameters needed to create the context.
   * @param stabilityRatio The stability ratio.
   * @return collateralRatio The validated collateral ratio.
   */
  function _getCollateralRatio(
    DOperationContext.Context memory params,
    uint96 stabilityRatio
  ) internal view returns (uint256 collateralRatio) {
    ITreasury treasury = ITreasury(params.groupState.extended.treasury.toAddress());

    try treasury.collateralRatio(params.groupId) returns (uint256 _collateralRatio) {
      collateralRatio = _collateralRatio;

      if (collateralRatio <= uint256(stabilityRatio)) {
        ErrorMintingPausedInStabilityMode.selector.revertWith(params.groupId);
      }
    } catch {
      InvalidCollateralRatio.selector.revertWith(params.groupId);
    }
  }

  /**
   * @notice Calculates the context fee.
   * @param params Struct containing parameters needed to create the context.
   * @param operationType The operation type.
   * @param collateralRatio The collateral ratio.
   * @param stabilityConditionsTriggeringRate The stability conditions triggering rate.
   * @return contextFee The calculated context fee.
   */
  function _calculateContextFee(
    DOperationContext.Context memory params,
    uint8 operationType,
    uint256 collateralRatio,
    uint96 stabilityConditionsTriggeringRate
  ) internal pure returns (uint24 contextFee) {
    bool isStabilityMode = collateralRatio < uint256(stabilityConditionsTriggeringRate);

    if (isStabilityMode) {
      contextFee = _getStabilityFee(params.groupId, params.groupState.feesPacked, operationType);
    } else {
      contextFee = _getRegularFee(params.groupId, params.groupState.feesPacked, operationType);
    }

    contextFee = _applyFeePermissions(contextFee, params.groupState.groupSettings);

    return contextFee;
  }

  /**
   * @notice Retrieves the stability fee.
   * @param groupId The group ID.
   * @param feesPacked The packed fees.
   * @param operationType The operation type.
   * @return The stability fee.
   */
  function _getStabilityFee(GroupId groupId, bytes32 feesPacked, uint8 operationType) internal pure returns (uint24) {
    if (operationType == uint8(OperationTypes.OP_TYPE_MINT_VT)) {
      return GroupStateHelper.getStabilityMintFeeVT(feesPacked);
    } else if (operationType == uint8(OperationTypes.OP_TYPE_MINT_YT)) {
      return GroupStateHelper.getStabilityMintFeeYT(feesPacked);
    } else if (operationType == uint8(OperationTypes.OP_TYPE_REDEEM_VT)) {
      return GroupStateHelper.getStabilityRedeemFeeVT(feesPacked);
    } else if (operationType == uint8(OperationTypes.OP_TYPE_REDEEM_YT)) {
      return GroupStateHelper.getStabilityRedeemFeeYT(feesPacked);
    } else {
      InvalidOperationType.selector.revertWith(groupId);
    }
  }

  /**
   * @notice Retrieves the regular fee.
   * @param groupId The group ID.
   * @param feesPacked The packed fees.
   * @param operationType The operation type.
   * @return The regular fee.
   */
  function _getRegularFee(GroupId groupId, bytes32 feesPacked, uint8 operationType) internal pure returns (uint24) {
    if (operationType == uint8(OperationTypes.OP_TYPE_MINT_VT)) {
      return GroupStateHelper.getMintFeeVT(feesPacked);
    } else if (operationType == uint8(OperationTypes.OP_TYPE_MINT_YT)) {
      return GroupStateHelper.getMintFeeYT(feesPacked);
    } else if (operationType == uint8(OperationTypes.OP_TYPE_REDEEM_VT)) {
      return GroupStateHelper.getRedeemFeeVT(feesPacked);
    } else if (operationType == uint8(OperationTypes.OP_TYPE_REDEEM_YT)) {
      return GroupStateHelper.getRedeemFeeYT(feesPacked);
    } else {
      InvalidOperationType.selector.revertWith(groupId);
    }
  }

  /**
   * @notice Applies fee permissions to the context fee.
   * @param fee The context fee.
   * @param groupSettings The group settings.
   * @return The context fee with applied permissions.
   */
  function _applyFeePermissions(uint24 fee, bytes32 groupSettings) internal pure returns (uint24) {
    FeePermissions memory feePermissions = GroupStateHelper.getFeePermissions(GroupSettings.wrap(groupSettings));

    if (feePermissions.isDynamic && !feePermissions.allowDelegation) {
      fee |= GroupFeeLibrary.DYNAMIC_FEE_FLAG;
    }

    if (feePermissions.allowDelegation) {
      fee |= GroupFeeLibrary.DELEGATE_FEE_FLAG;
    }

    return fee;
  }

  /**
   * @notice Creates the parameters for the operation context.
   * @param params Struct containing parameters needed to create the context.
   * @param operationType The operation type.
   * @param initialProtocolFee The initial protocol fee.
   * @param contextFee The context fee.
   * @param stabilityConditionsTriggeringRate The stability conditions triggering rate.
   * @return operationParams The created parameters.
   */
  function _createParams(
    DOperationContext.Context memory params,
    uint8 operationType,
    uint24 initialProtocolFee,
    uint24 contextFee,
    uint96 stabilityConditionsTriggeringRate
  ) internal pure returns (DOperationContext.Params memory operationParams) {
    Slot0 slot0 = Slot0Library.pack(
      operationType,
      initialProtocolFee,
      contextFee,
      0, // overriddenFee
      stabilityConditionsTriggeringRate
    );

    operationParams = DOperationContext.Params({ slot0: slot0, slot1: params.hookData });
  }

  /**
   * @notice Retrieves the stability ratio.
   * @param params Struct containing parameters needed to create the context.
   * @return The stability ratio.
   */
  function _getStabilityRatio(DOperationContext.Context memory params) internal pure returns (uint96) {
    return GroupStateHelper.getStabilityRatio(GroupSettings.wrap(params.groupState.groupSettings));
  }

  /**
   * @notice Retrieves the stability conditions triggering rate.
   * @param params Struct containing parameters needed to create the context.
   * @return The stability conditions triggering rate.
   */
  function _getstabilityConditionsTriggeringRate(DOperationContext.Context memory params) internal pure returns (uint96) {
    return GroupStateHelper.getStabilityTriggeringRatio(GroupSettings.wrap(params.groupState.groupSettings));
  }

  // ------ Getter Functions ------ //

  /**
   * @notice Retrieves the operation type from the operation context.
   * @param self The operation context.
   * @return The operation type.
   */
  function getOperationType(DOperationContext.OperationContext memory self) internal pure returns (uint8) {
    return self.params.slot0.operationType();
  }

  /**
   * @notice Retrieves the first amount from the operation context.
   * @param self The operation context.
   * @return The first amount.
   */
  function getAmount0(DOperationContext.OperationContext memory self) internal pure returns (uint256) {
    return self.amount0;
  }

  /**
   * @notice Retrieves the slippage rate from the operation context.
   * @param self The operation context.
   * @return The slippage rate.
   */
  function getSlippageRate(DOperationContext.OperationContext memory self) internal pure returns (uint24) {
    return self.slippage;
  }

  /**
   * @notice Retrieves the context fee from the operation context.
   * @param self The operation context.
   * @return The context fee.
   */
  function getContextFee(DOperationContext.OperationContext memory self) internal pure returns (uint24) {
    return self.params.slot0.contextFee();
  }

  /**
   * @notice Retrieves the protocol fee from the operation context.
   * @param self The operation context.
   * @return The protocol fee.
   */
  function getProtocolFee(DOperationContext.OperationContext memory self) internal pure returns (uint24) {
    return self.params.slot0.contextProtocolFee();
  }

  /**
   * @notice Retrieves the overridden fee from the operation context.
   * @param self The operation context.
   * @return The overridden fee.
   */
  function getOverriddenFee(DOperationContext.OperationContext memory self) internal pure returns (uint24) {
    return self.params.slot0.overriddenFee();
  }

  /**
   * @notice Retrieves the hook data from the operation context.
   * @param self The operation context.
   * @return The hook data.
   */
  function getHookData(DOperationContext.OperationContext memory self) internal pure returns (bytes memory) {
    return self.params.slot1;
  }

  /**
   * @notice Retrieves the recipient from the operation context.
   * @param self The operation context.
   * @return The recipient.
   */
  function getRecipient(DOperationContext.OperationContext memory self) internal view returns (address) {
    address recipient = self.recipient;
    if (recipient != msg.sender) revert ArbitraryCallsNotAllowed(self.groupId, recipient, msg.sender);
    return self.recipient;
  }

  /**
   * @notice Retrieves the payment token from the operation context.
   * @param self The operation context.
   * @return The payment token.
   */
  function getPaymentToken(DOperationContext.OperationContext memory self) internal pure returns (Currency) {
    return self.paymentToken.token;
  }

  /**
   * @notice Retrieves the payment token decimals from the operation context.
   * @param self The operation context.
   * @return The payment token decimals.
   */
  function getPaymentTokenDecimals(DOperationContext.OperationContext memory self) internal pure returns (uint8) {
    return self.paymentToken.decimals;
  }

  /**
   * @notice Retrieves the base token decimals from the operation context.
   * @param self The operation context.
   * @return The base token decimals.
   */
  function getBaseTokenDecimals(DOperationContext.OperationContext memory self) internal pure returns (uint8) {
    return GroupStateHelper.getBaseTokenDecimals(GroupSettings.wrap(self.groupState.groupSettings));
  }

  /**
   * @notice Retrieves the hook contract from the operation context.
   * @param self The operation context.
   * @return The hook contract.
   */
  function getHookContract(DOperationContext.OperationContext memory self) internal pure returns (address) {
    return self.groupState.hookContract.toAddress();
  }

  function getGroupWethAddress(DOperationContext.OperationContext memory self) internal pure returns (address) {
    return self.groupState.core.wethToken.toAddress();
  }

  /**
   * @notice Retrieves the stability ratio from the operation context.
   * @param self The operation context.
   * @return The stability ratio.
   */
  function getStabilityRatio(DOperationContext.OperationContext memory self) internal pure returns (uint96) {
    return GroupStateHelper.getStabilityRatio(GroupSettings.wrap(self.groupState.groupSettings));
  }

  // ------ Setter Functions ------ //

  /**
   * @notice Sets the overridden fee in the operation context.
   * @param self The operation context.
   * @param overriddenFee The overridden fee.
   */
  function setOverriddenFee(DOperationContext.OperationContext memory self, uint24 overriddenFee) internal pure {
    FeePermissions memory feePermissions = GroupStateHelper.getFeePermissions(GroupSettings.wrap(self.groupState.groupSettings));
    DefaultFeeParams memory defaultFees = GroupStateHelper.getDefaultFeeParams(self.groupState.feesPacked);

    uint24 validatedFee = GroupFeeLibrary.processGroupFee(defaultFees, feePermissions, overriddenFee);

    self.params.slot0 = self.params.slot0.setOverriddenFee(validatedFee);
  }

  /**
   * @notice Sets the hook data in the operation context.
   * @param self The operation context.
   * @param hookData The hook data.
   */
  function setHookData(DOperationContext.OperationContext memory self, bytes memory hookData) internal pure {
    /// @dev Only set hookData if hookContract exists
    if (!self.groupState.hookContract.isZero()) {
      self.params.slot1 = hookData;
    }
  }

  /**
   * @notice Sets the context fee in the operation context.
   * @param self The operation context.
   * @param contextFee The context fee.
   */
  function setContextFee(DOperationContext.OperationContext memory self, uint24 contextFee) internal pure {
    self.params.slot0 = self.params.slot0.setContextFee(contextFee);
  }

  // ------ Utility Functions ------ //

  /**
   * @notice Validates the recipient in the operation context.
   * @param self The operation context.
   */
  function validateRecipient(DOperationContext.OperationContext memory self) internal pure {
    if (self.recipient == address(0)) {
      ZeroAddress.selector.revertWith(self.groupId);
    }

    /// @dev guarding for hooks to cycle minting/redeeming
    if (self.recipient == self.groupState.hookContract.toAddress()) {
      CycleOperationsAreNotPermitted.selector.revertWith(self.groupId);
    }
  }

  /**
   * @notice Retrieves the fee model from the operation context.
   * @param self The operation context.
   * @return The fee model.
   */
  function getFeeModel(DOperationContext.OperationContext memory self) internal pure returns (uint8) {
    return GroupStateHelper.getFeeModel(GroupSettings.wrap(self.groupState.groupSettings));
  }

  /**
   * @notice Retrieves the context collateral ratio from the operation context.
   * @param self The operation context.
   * @return The context collateral ratio.
   */
  function getContextCollateralRatio(DOperationContext.OperationContext memory self) internal pure returns (uint256) {
    return self.collateralRatio;
  }

  /**
   * @notice Checks if wrapping is required in the operation context.
   * @param self The operation context.
   * @return True if wrapping is required, false otherwise.
   */
  function isWrappingRequired(DOperationContext.OperationContext memory self) internal pure returns (bool) {
    return GroupStateHelper.isWrappingRequired(GroupSettings.wrap(self.groupState.groupSettings));
  }

  /**
   * @notice Retrieves the hook permissions from the operation context.
   * @param self The operation context.
   * @return The hook permissions.
   */
  function getHookPermissions(DOperationContext.OperationContext memory self) internal pure returns (uint256) {
    return GroupStateHelper.getHookPermissions(GroupSettings.wrap(self.groupState.groupSettings));
  }

  // ------ Interaction with Slot0 and Slot1 ------ //

  /**
   * @notice Sets the second amount in the operation context.
   * @param self The operation context.
   * @param amount1 The second amount.
   */
  function setAmount1(DOperationContext.OperationContext memory self, uint256 amount1) internal pure {
    self.amount1 = amount1;
  }

  /**
   * @notice Retrieves the AToken from the operation context.
   * @param self The operation context.
   * @return The AToken.
   */
  function getAToken(DOperationContext.OperationContext memory self) internal pure returns (Currency) {
    return self.groupState.core.aToken;
  }

  /**
   * @notice Retrieves the XToken from the operation context.
   * @param self The operation context.
   * @return The XToken.
   */
  function getXToken(DOperationContext.OperationContext memory self) internal pure returns (Currency) {
    return self.groupState.core.xToken;
  }

  /**
   * @notice Retrieves the base token from the operation context.
   * @param self The operation context.
   * @return The base token.
   */
  function getBaseToken(DOperationContext.OperationContext memory self) internal pure returns (Currency) {
    return self.groupState.core.baseToken;
  }

  /**
   * @notice Retrieves the yield bearing token from the operation context.
   * @param self The operation context.
   * @return The yield bearing token.
   */
  function getYieldBearingToken(DOperationContext.OperationContext memory self) internal pure returns (Currency) {
    return self.groupState.core.yieldBearingToken;
  }

  /**
   * @notice Retrieves the swap router from the operation context.
   * @param self The operation context.
   * @return The swap router.
   */
  function getSwapRouter(DOperationContext.OperationContext memory self) internal pure returns (Address) {
    return self.groupState.extended.swapRouter;
  }

  /**
   * @notice Retrieves the price oracle from the operation context.
   * @param self The operation context.
   * @return The price oracle.
   */
  function getPriceOracle(DOperationContext.OperationContext memory self) internal pure returns (Address) {
    return self.groupState.extended.priceOracle;
  }

  /**
   * @notice Retrieves the treasury from the operation context.
   * @param self The operation context.
   * @return The treasury.
   */
  function getTreasury(DOperationContext.OperationContext memory self) internal pure returns (Address) {
    return self.groupState.extended.treasury;
  }

  /**
   * @notice Retrieves the fee collector from the operation context.
   * @param self The operation context.
   * @return The fee collector.
   */
  function getFeeCollector(DOperationContext.OperationContext memory self) internal pure returns (Address) {
    return self.groupState.extended.feeCollector;
  }

  /**
   * @notice Retrieves the rebalance pool from the operation context.
   * @param self The operation context.
   * @return The rebalance pool.
   */
  function getRebalancePool(DOperationContext.OperationContext memory self) internal pure returns (Currency) {
    return self.groupState.extended.rebalancePool;
  }

  function isMintOperation(DOperationContext.OperationContext memory self) internal pure returns (bool) {
    uint8 operationType = self.params.slot0.operationType();
    return operationType == uint8(OperationTypes.OP_TYPE_MINT_VT) || operationType == uint8(OperationTypes.OP_TYPE_MINT_YT);
  }

  function isRedeemOperation(DOperationContext.OperationContext memory self) internal pure returns (bool) {
    uint8 operationType = self.params.slot0.operationType();
    return operationType == uint8(OperationTypes.OP_TYPE_REDEEM_VT) || operationType == uint8(OperationTypes.OP_TYPE_REDEEM_YT);
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { WordCodec } from "../libs/WordCodec.sol";
import { CustomRevert } from "../libs/CustomRevert.sol";
import { GroupFeeLibrary } from "../libs/GroupFeeLibrary.sol";

import { OperationTypes } from "./CommonTypes.sol";

type Slot0 is bytes32;

/**
 * @title Slot0Library
 * @notice Library for managing operation types, fees, and rates in a space-efficient manner
 * @dev Uses bit packing to store multiple values in a single bytes32 slot
 */
library Slot0Library {
  using WordCodec for bytes32;
  using CustomRevert for bytes4;

  // Operation Type Constants
  uint8 internal constant MAX_OPERATION_TYPE = 3;

  // Fee Range Constants
  /// @dev Same as GroupFeeLibrary
  uint24 internal constant MAX_FEE = 10_000; /// 100% in basis points (1e4)
  uint24 internal constant MAX_OVERRIDING_FEE = 5_000; /// 50% in basis points (5e3)

  uint64 internal constant MAX_RATE = type(uint64).max; // ~18.44e18
  uint96 internal constant MAX_STABILITY_TRIGGER = type(uint96).max;

  // Offsets
  uint256 internal constant OPERATION_TYPE_OFFSET = 0; // 8 bits
  uint256 internal constant CONTEXT_PROTOCOL_FEE_OFFSET = 8; // 24 bits
  uint256 internal constant CONTEXT_FEE_OFFSET = 32; // 24 bits
  uint256 internal constant OVERRIDDEN_FEE_OFFSET = 56; // 24 bits

  uint256 internal constant STABILITY_FEE_TRIGGER_OFFSET = 80; // 96 bits for stability fee trigger

  // Bit lengths for the values
  uint256 internal constant OPERATION_TYPE_LENGTH = 8;
  uint256 internal constant CONTEXT_PROTOCOL_FEE_LENGTH = 24;
  uint256 internal constant CONTEXT_FEE_LENGTH = 24;
  uint256 internal constant OVERRIDDEN_FEE_LENGTH = 24;
  uint256 internal constant RATE_LENGTH = 64; /// @dev ~18.44e18 is sufficient for rate
  uint256 internal constant STABILITY_FEE_TRIGGER_LENGTH = 96;

  // Custom errors
  error InvalidOperationType(uint8 operationType);
  error InvalidFee(uint24 fee);
  error InvalidOverridenFee(uint24 fee);
  error InvalidRate(uint64 rate);
  error InvalidStabilityTrigger(uint96 trigger);
  error InvalidPackedData();
  error OperationTypeMismatch();

  // Validation modifiers
  /**
   * @dev Validates that a protocol fees is within acceptable bounds
   */
  modifier validateProtocolFee(uint24 fee) {
    if (fee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK > MAX_FEE) revert InvalidFee(fee);
    _;
  }

  /**
   * @dev Validates that hook fee is within acceptable bounds
   */
  modifier validateOverridenFee(uint24 fee) {
    if ((fee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) > MAX_OVERRIDING_FEE) revert InvalidFee(fee);
    _;
  }

  /**
   * @dev Validates that an operation type is valid
   */
  modifier validateOperationType(uint8 opType) {
    if (opType > MAX_OPERATION_TYPE) revert InvalidOperationType(opType);
    _;
  }

  // Getter Functions

  /// @notice Retrieves the operation type from Slot0.
  /// @param _packed The packed Slot0 data
  /// @return The operation type
  function operationType(Slot0 _packed) internal pure returns (uint8) {
    return uint8(Slot0.unwrap(_packed).decodeUint(OPERATION_TYPE_OFFSET, OPERATION_TYPE_LENGTH));
  }

  /// @notice Retrieves the context protocol fee from Slot0.
  /// @param _packed The packed Slot0 data
  /// @return The context protocol fee
  function contextProtocolFee(Slot0 _packed) internal pure returns (uint24) {
    uint24 fee = uint24(Slot0.unwrap(_packed).decodeUint(CONTEXT_PROTOCOL_FEE_OFFSET, CONTEXT_PROTOCOL_FEE_LENGTH));
    if ((fee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) > MAX_FEE) revert InvalidFee(fee);
    return fee;
  }

  /// @notice Retrieves the context LP fee from Slot0.
  /// @param _packed The packed Slot0 data
  /// @return The context LP fee
  function contextFee(Slot0 _packed) internal pure returns (uint24) {
    uint24 fee = uint24(Slot0.unwrap(_packed).decodeUint(CONTEXT_FEE_OFFSET, CONTEXT_FEE_LENGTH));
    if ((fee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) > MAX_FEE) revert InvalidFee(fee);
    return fee;
  }

  /// @notice Retrieves the overridden fee from Slot0.
  /// @param _packed The packed Slot0 data
  /// @return The overridden fee
  function overriddenFee(Slot0 _packed) internal pure returns (uint24) {
    uint24 fee = uint24(Slot0.unwrap(_packed).decodeUint(OVERRIDDEN_FEE_OFFSET, OVERRIDDEN_FEE_LENGTH));
    if ((fee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) > MAX_OVERRIDING_FEE) revert InvalidFee(fee);
    return fee;
  }

  /// @notice Retrieves the stability fee trigger ratio from Slot0.
  /// @param _packed The packed Slot0 data
  /// @return The stability fee trigger ratio
  function stabilityConditionsTriggeringRate(Slot0 _packed) internal pure returns (uint256) {
    return uint256(Slot0.unwrap(_packed).decodeUint(STABILITY_FEE_TRIGGER_OFFSET, STABILITY_FEE_TRIGGER_LENGTH));
  }

  // Pack Function

  /// @notice Packs all Slot0 data into a single bytes32.
  /// @param _operationType The operation type to pack
  /// @param _contextProtocolFee The context protocol fee to pack
  /// @param _contextFee The context fee to pack
  /// @param _overriddenFee The overridden fee to pack
  /// @param _stabilityFeeTrigger The stability fee trigger to pack
  /// @return _packed The packed Slot0 data
  function pack(
    uint8 _operationType,
    uint24 _contextProtocolFee,
    uint24 _contextFee,
    uint24 _overriddenFee,
    uint96 _stabilityFeeTrigger
  )
    internal
    pure
    validateOperationType(_operationType)
    validateProtocolFee(_contextProtocolFee)
    validateProtocolFee(_contextFee)
    validateOverridenFee(_overriddenFee)
    returns (Slot0 _packed)
  {
    bytes32 packed = 0;
    packed = packed.insertUint(_operationType, OPERATION_TYPE_OFFSET, OPERATION_TYPE_LENGTH);
    packed = packed.insertUint(_contextProtocolFee, CONTEXT_PROTOCOL_FEE_OFFSET, CONTEXT_PROTOCOL_FEE_LENGTH);
    packed = packed.insertUint(_contextFee, CONTEXT_FEE_OFFSET, CONTEXT_FEE_LENGTH);
    packed = packed.insertUint(_overriddenFee, OVERRIDDEN_FEE_OFFSET, OVERRIDDEN_FEE_LENGTH);
    packed = packed.insertUint(_stabilityFeeTrigger, STABILITY_FEE_TRIGGER_OFFSET, STABILITY_FEE_TRIGGER_LENGTH);

    if (!isValidPacked(packed)) revert InvalidPackedData();
    return Slot0.wrap(packed);
  }

  // Setter Functions

  /// @notice Sets the overridden fee in Slot0.
  /// @param _packed Current Slot0 data
  /// @param _overriddenFee New overridden fee value
  /// @return Updated Slot0 data
  function setOverriddenFee(Slot0 _packed, uint24 _overriddenFee) internal pure validateOverridenFee(_overriddenFee) returns (Slot0) {
    bytes32 packed = Slot0.unwrap(_packed).insertUint(_overriddenFee, OVERRIDDEN_FEE_OFFSET, OVERRIDDEN_FEE_LENGTH);
    if (!isValidPacked(packed)) revert InvalidPackedData();
    return Slot0.wrap(packed);
  }

  /// @notice Sets the context fee in Slot0.
  /// @param _packed Current Slot0 data
  /// @param _contextFee New context fee value
  /// @return Updated Slot0 data
  function setContextFee(Slot0 _packed, uint24 _contextFee) internal pure validateProtocolFee(_contextFee) returns (Slot0) {
    bytes32 packed = Slot0.unwrap(_packed).insertUint(_contextFee, CONTEXT_FEE_OFFSET, CONTEXT_FEE_LENGTH);
    if (!isValidPacked(packed)) revert InvalidPackedData();
    return Slot0.wrap(packed);
  }

  /// @notice Sets the context protocol fee in Slot0.
  /// @param _packed Current Slot0 data
  /// @param _contextProtocolFee New context protocol fee value
  /// @return Updated Slot0 data
  function setContextProtocolFee(
    Slot0 _packed,
    uint24 _contextProtocolFee
  ) internal pure validateProtocolFee(_contextProtocolFee) returns (Slot0) {
    bytes32 packed = Slot0.unwrap(_packed).insertUint(_contextProtocolFee, CONTEXT_PROTOCOL_FEE_OFFSET, CONTEXT_PROTOCOL_FEE_LENGTH);
    if (!isValidPacked(packed)) revert InvalidPackedData();
    return Slot0.wrap(packed);
  }

  // Internal Helper Functions

  /// @dev Validates that packed data contains valid values
  /// @param packed The packed data to validate
  /// @return True if the packed data is valid
  function isValidPacked(bytes32 packed) internal pure returns (bool) {
    uint8 _opType = uint8(packed.decodeUint(OPERATION_TYPE_OFFSET, OPERATION_TYPE_LENGTH));
    uint24 _protocolFee = uint24(packed.decodeUint(CONTEXT_PROTOCOL_FEE_OFFSET, CONTEXT_PROTOCOL_FEE_LENGTH));
    uint24 _contextFee = uint24(packed.decodeUint(CONTEXT_FEE_OFFSET, CONTEXT_FEE_LENGTH));
    uint24 _overriddenFee = uint24(packed.decodeUint(OVERRIDDEN_FEE_OFFSET, OVERRIDDEN_FEE_LENGTH));

    return
      _opType <= MAX_OPERATION_TYPE &&
      (_protocolFee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) <= MAX_FEE &&
      (_contextFee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) <= MAX_FEE &&
      (_overriddenFee & GroupFeeLibrary.REMOVE_ALL_FLAGS_MASK) <= MAX_OVERRIDING_FEE;
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

interface IRateProvider {
  function getRate() external view returns (uint256);

  function rateDecimals() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { GroupId } from "../types/GroupId.sol";
import { DTokenRegistry } from "../declarations/DTokenRegistry.sol";
import { DTreasury } from "../declarations/DTreasury.sol";
import { TreasuryHarvestLibrary } from "../libs/TreasuryHarvestLibrary.sol";

interface ITreasury {
  // Events
  event HarvestYield(GroupId indexed groupId, uint256 indexed yieldBaseTokens);
  event HarvestFees(GroupId indexed groupId, uint256 indexed xTokenAmount, uint256 indexed aTokenAmount);
  event FeesDistributed(GroupId indexed groupId, uint256 indexed xTokenAmount, uint256 indexed baseTokenAmount);
  event UpdateBaseTokenCap(GroupId indexed groupId, uint256 indexed oldBaseTokenCap, uint256 indexed newBaseTokenCap);
  event Settle(GroupId indexed groupId, uint256 indexed oldPrice, uint256 indexed newPrice);
  event UpdateFeeCollector(address indexed oldFeeCollector, address indexed newFeeCollector);
  event GroupInitialized(GroupId indexed groupId, uint256 indexed baseTokenPrice);

  event RebalanceUpPerformed(GroupId indexed groupId, uint256 indexed newCollateralRatio);
  event RebalanceDownPerformed(GroupId indexed groupId, uint256 indexed newCollateralRatio);
  event TransferToStrategy(GroupId indexed groupId, uint256 indexed amount);

  // Custom Errors
  error ZeroAddress();
  error ZeroAmount();
  error OnlyStrategy();
  error GroupAlreadyInitialized(GroupId groupId);
  error ErrorUnderCollateral(GroupId groupId);
  error ErrorExceedTotalCap(GroupId groupId);
  error ErrorInvalidTwapPrice(GroupId groupId);
  error NotPermitted();
  error InvalidGroupConfiguration(GroupId groupId);
  error InvalidRate(GroupId groupId, address rateProvider);
  error InvalidRatio(GroupId groupId);
  error InvalidPrice(GroupId groupId);
  error InvalidBaseTokenCap(GroupId groupId);
  error ErrorInsufficientBalance(GroupId groupId, address token);
  error ErrorSwapFailed();
  error ErrorDistributingYield(GroupId groupId);
  error ErrorWithdrawFromStrategy();
  error ErrorCollateralRatioTooSmall(GroupId groupId);
  error MaximumAmountExceeded(GroupId groupId, uint256 maxAmount);
  error StrategyUnderflow(GroupId groupId);
  error InvalidTokenType();
  error RenounceRoleProhibited();

  // View Functions
  function collateralRatio(GroupId groupId) external view returns (uint256);

  function isUnderCollateral(GroupId groupId) external view returns (bool);

  function leverageRatio(GroupId groupId) external view returns (uint256);

  function currentBaseTokenPrice(GroupId groupId) external view returns (uint256);

  // function isBaseTokenPriceValid(GroupId groupId) external view returns (bool _isValid);
  function totalBaseToken(GroupId groupId) external view returns (uint256);

  function maxMintableAToken(
    GroupId groupId,
    uint256 _newCollateralRatio
  ) external view returns (uint256 _maxBaseIn, uint256 _maxATokenMintable);

  function maxRedeemableAToken(
    GroupId groupId,
    uint256 _newCollateralRatio
  ) external view returns (uint256 _maxBaseOut, uint256 _maxATokenRedeemable);

  // State-Changing Functions
  function mintAToken(GroupId groupId, uint256 _baseIn, address _recipient) external returns (uint256 _aTokenOut);

  function mintXToken(GroupId groupId, uint256 _baseIn, address _recipient) external returns (uint256 _xTokenOut);

  function redeem(GroupId groupId, uint256 _aTokenIn, uint256 _xTokenIn, address _owner) external returns (uint256 _baseOut);

  function transferToStrategy(GroupId groupId, uint256 _amount) external;

  // Harvest Functions
  function harvestYield(GroupId groupId, TreasuryHarvestLibrary.HarvestParams memory params) external;

  function harvestFees(GroupId groupId, TreasuryHarvestLibrary.HarvestParams memory params) external;

  // Management Functions  
  function updateBaseTokenCap(GroupId groupId, uint256 _baseTokenCap) external;

  function updateFeeCollector(address _newFeeCollector) external;

  function forceUpdateGroupCache(address tokenRegistry, GroupId groupId) external;

  function getTreasuryState(GroupId groupId) external view returns (DTreasury.TreasuryState memory);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { ExponentialMovingAverageV8 } from "../libs/math/ExponentialMovingAverageV8.sol";

library DTreasury {
  using ExponentialMovingAverageV8 for ExponentialMovingAverageV8.EMAStorage;

  struct GroupUpdateParams {
    uint256 baseTokenCaps;
    uint256 baseIn;
  }

  struct TreasuryState {
    ExponentialMovingAverageV8.EMAStorage emaLeverageRatio;
    uint256 totalBaseTokens;
    uint256 baseTokenCaps;

    uint256 lastSettlementTimestamp;
    uint256 baseTokenPrice;
    bool inited;
    uint256 strategyUnderlying;
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { Currency, CurrencyLibrary } from "../types/Currency.sol";
import { GroupStateHelper, GroupSettings } from "../types/GroupStateHelper.sol";
import { GroupState, FeeModel } from "../types/CommonTypes.sol";
import { GroupId } from "../types/GroupId.sol";
import { DTreasury } from "../declarations/DTreasury.sol";
import { TreasuryStateLibrary } from "./TreasuryStateLibrary.sol";
import { IDXToken } from "../interfaces/IDXToken.sol";
import { IAToken } from "../interfaces/IAToken.sol";
import { IWToken } from "../interfaces/IWToken.sol";
import { IRebalancePool } from "../interfaces/IRebalancePool.sol";
import { CustomRevert } from "../libs/CustomRevert.sol";
import { FullMath } from "../libs/math/FullMath.sol";
import { IProtocolMinimum as IProtocol } from "../interfaces/IProtocolMinimum.sol";

/**
 * @title TreasuryHarvestLibrary
 * @notice This library orchestrates fee and yield harvesting for a specific group.
 * @dev It handles collecting fees, distributing base tokens, minting aTokens, and managing 
 *      yield fees. The library relies on external calls to tokens and Rebalance Pools, and 
 *      carefully handles potential revert scenarios via `try/catch` and bubble-up reverts.
 */
library TreasuryHarvestLibrary {
    using CurrencyLibrary for Currency;
    using GroupStateHelper for GroupSettings;
    using TreasuryStateLibrary for *;
    using CustomRevert for bytes4;

    // =========================
    // ======== Errors =========
    // =========================
    error ZeroAmount();
    error WrongFeeModel(GroupId groupId);
    error ErrorDistributingYield();
    error ErrorFeeCollectionFailed(GroupId groupId);
    error ErrorDistributingTokens(GroupId groupId);

    // =========================
    // ======== Events =========
    // =========================

    event FeesCollected(GroupId indexed groupId, uint256 amount);
    event FeesHarvested(GroupId indexed groupId, uint256 dxTokenBalance, address feeCollector);
    event YieldHarvested(GroupId indexed groupId, uint256 yieldAmount, address feeCollector);
    event ATokensMintedToPool(GroupId indexed groupId, uint256 aTokenAmount, address recipient);
    event TokensSwappedToPool(GroupId indexed groupId, address fromToken, address toToken, uint256 amountIn, uint256 amountOut);

    // =========================
    // ======== Structs ========
    // =========================

    /**
     * @notice Parameters used to harvest yield or fees.
     * @param sendTokens If true, will swap base tokens into stablecoins 
     *        instead of attempting to mint aTokens (when mint capacity is exceeded).
     * @param swapRouter Address of the DEX/router used to swap base tokens for stablecoins.
     * @param stablecoin The address of the stablecoin into which base tokens may be swapped.
     * @param minAmountOut The minimum amount of stablecoins that must be received from the swap 
     *        for the transaction not to revert.
     */
    struct HarvestParams {
        bool sendTokens;
        address swapRouter;
        address stablecoin;
        uint256 minAmountOut;
    }

    /**
     * @notice Collects any accrued fees from dxToken. 
     * @dev Calls `collectFees` on the dxToken. Reverts if no fees were collected.
     * @param groupState The current group state, which includes the dxToken address.
     * @return The amount of dxToken fees collected.
     */
    function collectFees(GroupState memory groupState, GroupId groupId) internal returns (uint256) {
        IDXToken dxToken = IDXToken(groupState.core.xToken.toAddress());
        uint256 dxTokenBalanceBefore = dxToken.balanceOf(address(this));
        
        // Attempt to collect fees from dxToken
        try dxToken.collectFees() {
            // Get the balance of dxToken after fees have been collected
            uint256 dxTokenBalanceAfter = dxToken.balanceOf(address(this));
            uint256 collectedAmount = dxTokenBalanceAfter - dxTokenBalanceBefore;

            // Revert if no fees were actually collected
            if (collectedAmount == 0) ZeroAmount.selector.revertWith();

            // Emit an event to log the fees collected
            emit FeesCollected(groupId, collectedAmount);

            return collectedAmount;
        } catch {
           CustomRevert.bubbleUpAndRevertWith(dxToken.collectFees.selector, address(dxToken));
        }
    }

    /**
     * @notice Harvests fees (not yield) based on the group's fee model.
     * @dev For management fees, the dxTokens are simply transferred to the feeCollector.
     *      For funding fees, dxTokens are burned and then aTokens are minted (or stablecoins are swapped).
     * @param groupId The ID of the group for which fees are harvested.
     * @param groupState The current group state data.
     * @param treasuryState The TreasuryState storage reference for updating internal state.
     * @param harvestParams Parameters controlling how the harvested tokens might be swapped or minted.
     * @param dxTokenBalance The amount of dxTokens available for fee harvesting.
     * @param feeCollector The address to which management fees should be sent.
     * @param protocol The Protocol contract address (for calculating stability ratio, etc).
     */
    function harvestFees(
        GroupId groupId,
        GroupState memory groupState,
        DTreasury.TreasuryState storage treasuryState,
        HarvestParams memory harvestParams,
        uint256 dxTokenBalance, 
        address feeCollector, 
        address protocol
    ) internal {
        IDXToken dxToken = IDXToken(groupState.core.xToken.toAddress());
        
        // Determine the fee model for this group
        FeeModel feeModel = dxToken.getFeeModel();

        if (feeModel == FeeModel.MANAGEMENT_FEE) {
            // Simply transfer dxTokens to fee collector
            groupState.core.xToken.safeTransfer(feeCollector, dxTokenBalance);
            return;
        }
        
        if (feeModel == FeeModel.VARIABLE_FUNDING_FEE || feeModel == FeeModel.FIXED_FUNDING_FEE) {
            // For funding fees, burn dxTokens
            try dxToken.burn(address(this), dxTokenBalance) {} catch {
                CustomRevert.bubbleUpAndRevertWith(dxToken.burn.selector, address(dxToken));
            }

            // Calculate baseTokenAmount from dxTokens
            uint256 baseTokenAmount = dxToken.dxTokenToBaseToken(dxTokenBalance);
            uint8 baseTokenDecimals = GroupSettings.wrap(groupState.groupSettings).getBaseTokenDecimals();

            // apply yield and get net harvestable amount
            (baseTokenAmount, ) = _applyYield(groupState, baseTokenAmount, feeCollector);
            
            // Normalize baseTokenAmount to an 18-decimal scale (for internal accounting)
            uint256 baseTokenAmountNormalized = TreasuryStateLibrary.normalizeDecimals(
                baseTokenAmount, 
                baseTokenDecimals
            );

            // Distribute base tokens either as aToken or stablecoin, depending on mint capacity
            _distributeBaseTokens(
                groupState,
                groupId,
                treasuryState,
                baseTokenAmount,
                baseTokenAmountNormalized,
                harvestParams,
                protocol
            );

            emit FeesHarvested(groupId, dxTokenBalance, feeCollector);
            return;
        }

        // If none of the recognized fee models applies, revert.
        WrongFeeModel.selector.revertWith(groupId);
    }

    /**
     * @notice Harvests yield for a group, applies any yield fees, and distributes the net amount.
     * @dev A portion of the yield is sent to the feeCollector as a yield fee (if applicable).
     * @param groupId The ID of the group for which yield is being harvested.
     * @param groupState The current group state data.
     * @param treasuryState The TreasuryState storage reference for updating internal state.
     * @param harvestParams Parameters controlling how the base tokens might be swapped or minted.
     * @param harvestableAmount The total base token amount of yield harvested.
     * @param feeCollector The address to which the yield fee is sent.
     * @param protocol The Protocol contract address (for calculating stability ratio, etc).
     */
    function harvestYield(
        GroupId groupId,
        GroupState memory groupState,
        DTreasury.TreasuryState storage treasuryState,
        HarvestParams memory harvestParams,
        uint256 harvestableAmount, 
        address feeCollector, 
        address protocol
    ) internal {
        // Apply yield fees and get net harvestable amount
        (harvestableAmount, ) = _applyYield(groupState, harvestableAmount, feeCollector);

        // Normalize the base token amount for internal accounting
        uint8 baseTokenDecimals = GroupSettings.wrap(groupState.groupSettings).getBaseTokenDecimals();
        uint256 baseTokenAmountNormalized = TreasuryStateLibrary.normalizeDecimals(
            harvestableAmount, 
            baseTokenDecimals
        );

        // Distribute the net base tokens (either as stablecoin or aTokens)
        _distributeBaseTokens(
            groupState,
            groupId,
            treasuryState,
            harvestableAmount,
            baseTokenAmountNormalized,
            harvestParams,
            protocol
        );

        emit YieldHarvested(groupId, harvestableAmount, feeCollector);
    }

    /**
     * @notice Calculates how many aTokens should be minted given a certain amount of base tokens,
     *         and also how many aTokens can be minted at maximum without breaching collateral targets.
     * @param groupState The current group state data.
     * @param groupId The ID of the group for which aTokens will be minted.
     * @param baseTokenAmountNormalized The normalized amount of base tokens to convert into aTokens.
     * @param aToken The IAToken contract reference (whose NAV is used to compute minted supply).
     * @param protocol The Protocol contract address (for stability ratio checks).
     * @return aTokenToMint How many aTokens should be minted given the current NAV.
     * @return aTokenMintableMax The maximum number of aTokens that can be minted without breaching collateral.
     */
    function calculateMintingParams(
        DTreasury.TreasuryState storage treasuryState,
        GroupState memory groupState,
        GroupId groupId,
        uint256 baseTokenAmountNormalized,
        IAToken aToken,
        address protocol
    ) internal view returns (uint256 aTokenToMint, uint256 aTokenMintableMax) {
        // Fetch the current base token price from an oracle or similar feed
        (, uint256 newPrice) = TreasuryStateLibrary.fetchBaseTokenPrice(treasuryState, groupState);
        
        // NAV of the aToken is used to determine how many aTokens 1 base token is worth
        uint256 aTokenNav = aToken.nav();
        
        // aTokenToMint = (baseTokenAmountNormalized * newPrice) / aTokenNav
        aTokenToMint = FullMath.mulDiv(baseTokenAmountNormalized, newPrice, aTokenNav);

        // Check how many aTokens we can mint before breaching collateral/stability constraints
        (, aTokenMintableMax) = TreasuryStateLibrary.maxMintableAToken(
            treasuryState,
            groupState, 
            uint256(IProtocol(protocol).stabilityRatio(groupId))
        );
    }

    /**
     * @notice Distributes base tokens to the Rebalance Pool either by minting aTokens or swapping 
     *         them into stablecoins, depending on the mint capacity and user preference.
     * @dev If the aToken mint capacity is insufficient and `sendTokens == true`, base tokens 
     *      are swapped into stablecoins. Otherwise, the function reverts.
     * @param groupState The current group state data.
     * @param groupId The ID of the group for which distribution is happening.
     * @param treasuryState The TreasuryState storage reference for updating internal state.
     * @param baseTokenAmount The actual (denormalized) amount of base tokens.
     * @param baseTokenAmountNormalized The normalized base token amount (scaled to 18 decimals internally).
     * @param harvestParams Struct containing swap and stablecoin parameters.
     * @param protocol The Protocol contract address (for stability ratio checks).
     */
    function _distributeBaseTokens(
        GroupState memory groupState,
        GroupId groupId,
        DTreasury.TreasuryState storage treasuryState,
        uint256 baseTokenAmount,
        uint256 baseTokenAmountNormalized,
        HarvestParams memory harvestParams,
        address protocol
    ) private {
        IAToken aToken = IAToken(groupState.core.aToken.toAddress());
        Currency stableCoinCurrency = Currency.wrap(harvestParams.stablecoin);

        // Compute how many aTokens we *need* to mint and how many are *allowed* to mint
        (uint256 aTokenToMint, uint256 aTokenMintableMax) = calculateMintingParams(
            treasuryState,
            groupState, 
            groupId, 
            baseTokenAmountNormalized, 
            aToken, 
            protocol
        );

        // If we cannot mint the entire required amount of aTokens
        if (aTokenMintableMax < aTokenToMint) {
            // If we are NOT allowed to send stablecoins, revert
            if (!harvestParams.sendTokens) ErrorDistributingTokens.selector.revertWith(groupId);

            // Decrease the treasury's totalBaseTokens because we'll unwrap and swap them
            treasuryState.totalBaseTokens -= baseTokenAmountNormalized;

            // 1. Unwrap the wrapped base tokens into their underlying (e.g., WETH -> ETH or WMATIC -> MATIC).
            uint256 unwrappedBaseTokens = IWToken(groupState.core.baseToken.toAddress()).unwrap(baseTokenAmount);

            // 2. Swap from base tokens -> stablecoins
            uint256 stablecoinAmount = TreasuryStateLibrary.swapTokens(
                address(this),
                harvestParams.swapRouter,
                // We should swap from the *yield-bearing token* (not the base token)
                groupState.core.yieldBearingToken.toAddress(),
                stableCoinCurrency.toAddress(),
                unwrappedBaseTokens,
                harvestParams.minAmountOut
            );

            // 3. Transfer the stablecoins to the Rebalance Pool
            stableCoinCurrency.safeTransfer(
                groupState.extended.rebalancePool.toAddress(), 
                stablecoinAmount
            );

            emit TokensSwappedToPool(groupId, groupState.core.baseToken.toAddress(), harvestParams.stablecoin, unwrappedBaseTokens, stablecoinAmount);

        } else {
            // We can mint the full aToken amount from the base tokens
            // Increase the treasury's totalBaseTokens accordingly
            treasuryState.totalBaseTokens += baseTokenAmountNormalized;

            // Convert aTokenToMint from normalized (18 decimals) to the actual aToken decimals
            uint8 aTokenDecimals = GroupSettings.wrap(groupState.groupSettings).getATokenDecimals();
            uint256 aTokenToMintDenorm = TreasuryStateLibrary.denormalizeDecimals(aTokenToMint, aTokenDecimals);

            // Mint aTokens directly to the Rebalance Pool
            aToken.mint(groupState.extended.rebalancePool.toAddress(), aTokenToMintDenorm);

            // Update the Rebalance Pool’s NAV to reflect the newly minted aTokens
            IRebalancePool(groupState.extended.rebalancePool.toAddress()).updateNAV();

            emit ATokensMintedToPool(groupId, aTokenToMintDenorm, groupState.extended.rebalancePool.toAddress());
        }
    }

    /**
     * @notice Applies a yield fee to the harvestable amount (if any) and transfers that fee 
     *         portion to the feeCollector. Returns the net amount after fee.
     * @param groupState The current group state data (for accessing baseToken).
     * @param harvestableAmount The total yield (in base tokens) to be distributed.
     * @param feeCollector The address to which yield fees should be sent.
     * @return _harvestableAmount The net (post-fee) amount of base tokens.
     * @return _feeAmount The fee amount that was deducted and sent to the feeCollector.
     */
    function _applyYield(
        GroupState memory groupState, 
        uint256 harvestableAmount, 
        address feeCollector
    ) 
        private 
        returns (uint256 _harvestableAmount, uint256 _feeAmount) 
    {
        IRebalancePool rebalancePool = IRebalancePool(groupState.extended.rebalancePool.toAddress());
        uint256 yieldFeePercentage = rebalancePool.yieldFeePercentage();
        uint256 BASE_POINTS = 10_000;

        // If there's a yield fee, calculate and transfer it
        if (yieldFeePercentage > 0) {
            _feeAmount = (harvestableAmount * yieldFeePercentage) / BASE_POINTS;
            _harvestableAmount = harvestableAmount - _feeAmount;

            if (_feeAmount > 0) {
                groupState.core.baseToken.safeTransfer(feeCollector, _feeAmount);
            }
        } else {
            // If no yield fee, the entire amount is harvestable
            _harvestableAmount = harvestableAmount;
        }

        return (_harvestableAmount, _feeAmount);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.28;

import { LogExpMathV8 } from "./LogExpMathV8.sol";

// solhint-disable not-rely-on-time

/// @dev See https://en.wikipedia.org/wiki/Exponential_smoothing
/// It is the same as `ExponentialMovingAverageV7` with `unchecked` scope.
library ExponentialMovingAverageV8 {
  /*************
   * Constants *
   *************/

  /// @dev The precision used to compute EMA.
  uint256 private constant PRECISION = 1e18;

  /***********
   * Structs *
   ***********/

  /// @dev Compiler will pack this into single `uint256`.
  /// @param lastTime The last timestamp when the storage is updated.
  /// @param sampleInterval The sampling time interval used in the EMA.
  /// @param lastValue The last value in the data sequence, with precision 1e18.
  /// @param lastEmaValue The last EMA value computed, with precision 1e18.
  struct EMAStorage {
    uint40 lastTime;
    uint24 sampleInterval;
    uint96 lastValue;
    uint96 lastEmaValue;
  }

  /// @dev Save value of EMA storage.
  /// @param s The EMA storage.
  /// @param value The new value, with precision 1e18.
  function saveValue(EMAStorage storage s, uint96 value) internal {
    s.lastEmaValue = uint96(emaValue(s));
    s.lastValue = value;
    s.lastTime = uint40(block.timestamp);
  }

  /// @dev Return the current ema value.
  /// @param s The EMA storage.
  function emaValue(EMAStorage storage s) internal view returns (uint256) {
    unchecked {
      if (uint256(s.lastTime) < block.timestamp) {
        uint256 dt = block.timestamp - uint256(s.lastTime);
        uint256 e = (dt * PRECISION) / s.sampleInterval;
        if (e > 41e18) {
          return s.lastValue;
        } else {
          uint256 alpha = uint256(LogExpMathV8.exp(-int256(e)));
          return (s.lastValue * (PRECISION - alpha) + s.lastEmaValue * alpha) / PRECISION;
        }
      } else {
        return s.lastEmaValue;
      }
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { Currency, CurrencyLibrary } from "../types/Currency.sol";
import { Address, AddressLibrary } from "../types/Address.sol";
import { FxStableMath } from "../libs/math/FxStableMath.sol";
import { ExponentialMovingAverageV8 } from "../libs/math/ExponentialMovingAverageV8.sol";
import { IERC20Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import { IPriceOracle } from "../interfaces/IPriceOracle.sol";
import { DTreasury } from "../declarations/DTreasury.sol";
import { GroupStateHelper, GroupSettings } from "../types/GroupStateHelper.sol";
import { IAToken } from "../interfaces/IAToken.sol";
import { CustomRevert } from "../libs/CustomRevert.sol";
import { IDEXRouter } from "../interfaces/IDEXRouter.sol";
import { IStrategy } from "../interfaces/IStrategy.sol";
import { GroupState } from "../types/CommonTypes.sol";
import { FullMath } from "../libs/math/FullMath.sol";

/**
 * @title TreasuryStateLibrary
 * @notice Library for managing treasury state and calculations.
 */
library TreasuryStateLibrary {
  using CurrencyLibrary for Currency;
  using AddressLibrary for Address;
  using FxStableMath for FxStableMath.SwapState;
  using ExponentialMovingAverageV8 for ExponentialMovingAverageV8.EMAStorage;
  using GroupStateHelper for GroupSettings;
  using CustomRevert for bytes4;

  error ErrorInvalidTwapPrice();
  error ErrorSwapFailed();
  error ErrorWithdrawFromStrategy();
  error StrategyUnderflow();

  event BaseTokenCapsUpdated(uint256 newCaps);
  event BaseTokenPriceUpdated(uint256 newPrice);
  event SwapExecuted(address indexed fromToken, address indexed toToken, uint256 amountIn, uint256 amountOut);
  event BaseTokenTransferred(address indexed recipient, uint256 amount);
  event StrategyWithdrawal(address indexed strategy, uint256 amount);
  event EMALeverageRatioUpdated(uint256 newEMAValue);
  event GroupEMALeverageRatioInitialized(uint256 initialValue);

  uint256 private constant PRECISION = 1e18;

  /**
   * @notice Updates the base token caps in the treasury state.
   * @param self The treasury state storage.
   * @param newCaps The new base token caps.
   */
  function updateBaseTokenCaps(DTreasury.TreasuryState storage self, uint256 newCaps) internal {
    self.baseTokenCaps = newCaps;
    emit BaseTokenCapsUpdated(newCaps);
  }

  /**
   * @notice Updates the base token price in the treasury state.
   * @param self The treasury state storage.
   * @param newPrice The new base token price.
   */
  function updateBaseTokenPrice(DTreasury.TreasuryState storage self, uint256 newPrice) internal {
    self.baseTokenPrice = newPrice;
    emit BaseTokenPriceUpdated(newPrice);
  }

  /**
   * @notice Loads the swap state with proper precision handling.
   * @param self The treasury state storage.
   * @param group The group state.
   * @return _state The loaded swap state.
   */
  function loadSwapState(
    DTreasury.TreasuryState storage self,
    GroupState memory group
  ) internal view returns (FxStableMath.SwapState memory _state) {
    // Fetch decimals
    uint8 baseTokenDecimals = GroupSettings.wrap(group.groupSettings).getBaseTokenDecimals();
    uint8 aTokenDecimals = GroupSettings.wrap(group.groupSettings).getATokenDecimals();
    uint8 xTokenDecimals = GroupSettings.wrap(group.groupSettings).getXTokenDecimals();

    // Normalize baseSupply to 18 decimals
    _state.baseSupply = normalizeDecimals(self.totalBaseTokens, baseTokenDecimals);

    // Fetch base token price (already in 18 decimals)
    (_state.baseTwapNav, _state.baseNav) = fetchBaseTokenPrice(self, group);

    if (_state.baseSupply == 0) {
      _state.aNav = PRECISION;
      _state.xNav = PRECISION;
    } else {
      // Fetch token supplies and normalize to 18 decimals
      uint256 aSupplyRaw = IERC20Upgradeable(group.core.aToken.toAddress()).totalSupply();
      uint256 xSupplyRaw = IERC20Upgradeable(group.core.xToken.toAddress()).totalSupply();

      _state.aSupply = normalizeDecimals(aSupplyRaw, aTokenDecimals);
      _state.xSupply = normalizeDecimals(xSupplyRaw, xTokenDecimals);

      // Fetch aNav (assuming it's already in 18 decimals)
      _state.beta = IAToken(group.core.aToken.toAddress()).beta();

      if (_state.beta) {
        _state.aNav = IAToken(group.core.aToken.toAddress()).nav();
      } else {
        _state.aNav = PRECISION;
      }
          
      if (_state.xSupply == 0) {
        // No xToken, treat the nav of xToken as 1.0
        _state.xNav = PRECISION;
      } else {
        uint256 _baseVal = _state.baseSupply * _state.baseNav;
        uint256 _aVal = _state.aSupply * _state.aNav;
        if (_baseVal >= _aVal) {
          _state.xNav = (_baseVal - _aVal) / _state.xSupply;
        } else {
          // Under-collateralized
          _state.xNav = 0;
        }
      }
    }
  }

  /**
   * @notice Fetches the base token price from the price oracle.
   * @param group The group state.
   * @return _twap The time-weighted average price.
   * @return _price The selected price
   */
  function fetchBaseTokenPrice(
    DTreasury.TreasuryState storage /*self*/,
    GroupState memory group
  ) internal view returns (uint256 _twap, uint256 _price) {
    bool isValid;
    address priceOracle = group.extended.priceOracle.toAddress();
    (isValid, _price) = IPriceOracle(priceOracle).getPrice(group.core.baseToken.toAddress());

    if (!isValid || _price == 0) ErrorInvalidTwapPrice.selector.revertWith();

    // Prices are already in 18 decimals
    return (_price, _price);
  }

  /**
   * @notice Checks if the treasury is under-collateralized.
   * @param self The treasury state storage.
   * @param group The group state.
   * @return True if under-collateralized, false otherwise.
   */
  function isUnderCollateral(DTreasury.TreasuryState storage self, GroupState memory group) internal view returns (bool) {
    FxStableMath.SwapState memory _state = loadSwapState(self, group);
    return _state.xNav == 0;
  }

  /**
   * @notice Gets the collateral ratio of the treasury.
   * @param self The treasury state storage.
   * @param group The group state.
   * @return The collateral ratio.
   */
  function getCollateralRatio(DTreasury.TreasuryState storage self, GroupState memory group) internal view returns (uint256) {
    FxStableMath.SwapState memory _state = loadSwapState(self, group);

    if (_state.baseSupply == 0) return PRECISION;
    if (_state.aSupply == 0 || _state.aNav == 0) return PRECISION * PRECISION;

    return FullMath.mulDiv(_state.baseSupply * _state.baseNav, PRECISION, _state.aSupply * _state.aNav);
  }

  /**
   * @notice Calculates the maximum mintable AToken based on the new collateral ratio.
   * @param self The treasury state storage.
   * @param group The group state.
   * @param _newCollateralRatio The new desired collateral ratio.
   * @return _maxBaseIn The maximum base tokens that can be input.
   * @return _maxATokenMintable The maximum AToken that can be minted.
   */
  function maxMintableAToken(
    DTreasury.TreasuryState storage self,
    GroupState memory group,
    uint256 _newCollateralRatio
  ) internal view returns (uint256 _maxBaseIn, uint256 _maxATokenMintable) {
    FxStableMath.SwapState memory _state = loadSwapState(self, group);
    (_maxBaseIn, _maxATokenMintable) = _state.maxMintableAToken(_newCollateralRatio);
  }

  /**
   * @notice Calculates the maximum redeemable AToken based on the new collateral ratio.
   * @param self The treasury state storage.
   * @param group The group state.
   * @param _newCollateralRatio The new desired collateral ratio.
   * @return _maxBaseOut The maximum base tokens that can be output.
   * @return _maxATokenRedeemable The maximum AToken that can be redeemed.
   */
  function maxRedeemableAToken(
    DTreasury.TreasuryState storage self,
    GroupState memory group,
    uint256 _newCollateralRatio
  ) internal view returns (uint256 _maxBaseOut, uint256 _maxATokenRedeemable) {
    FxStableMath.SwapState memory _state = loadSwapState(self, group);
    (_maxBaseOut, _maxATokenRedeemable) = _state.maxRedeemableAToken(_newCollateralRatio);
  }
  /**
   * @notice Updates the Exponential Moving Average (EMA) of the leverage ratio.
   * @param self The treasury state storage.
   * @param _state The current swap state.
   */
  function updateEMALeverageRatio(DTreasury.TreasuryState storage self, FxStableMath.SwapState memory _state) internal {
    uint256 _ratio = _state.leverageRatio();
    self.emaLeverageRatio.saveValue(uint96(_ratio));
    emit EMALeverageRatioUpdated(_ratio);
  }

  function getEMAValue(DTreasury.TreasuryState storage self) internal view returns (uint256) {
    return self.emaLeverageRatio.emaValue();
  }

  function initializeGroupEMALeverageRatio(DTreasury.TreasuryState storage self) internal {
    self.emaLeverageRatio.lastTime = uint40(block.timestamp);
    self.emaLeverageRatio.lastValue = uint96(PRECISION * 2);
    self.emaLeverageRatio.lastEmaValue = uint96(PRECISION * 2);
    self.emaLeverageRatio.sampleInterval = 1 days;

    emit GroupEMALeverageRatioInitialized(PRECISION * 2);
  }

  /**
   * @dev Normalizes a token amount to 18 decimals.
   * @param amount The amount to normalize.
   * @param tokenDecimals The decimals of the token.
   * @return The normalized amount.
   */
  function normalizeDecimals(uint256 amount, uint8 tokenDecimals) internal pure returns (uint256) {
    if (tokenDecimals == 18) {
      return amount;
    }

    uint256 factor;
    if (tokenDecimals < 18) {
      factor = 10 ** (18 - tokenDecimals);
      return amount * factor;
    } else {
      factor = 10 ** (tokenDecimals - 18);
      return amount / factor;
    }
  }

  /**
   * @dev Denormalizes a token amount from 18 decimals to the token's decimals.
   * @param amount The amount to denormalize.
   * @param tokenDecimals The decimals of the token.
   * @return The denormalized amount.
   */
  function denormalizeDecimals(uint256 amount, uint8 tokenDecimals) internal pure returns (uint256) {
    if (tokenDecimals == 18) {
      return amount;
    }

    uint256 factor;
    if (tokenDecimals < 18) {
      factor = 10 ** (18 - tokenDecimals);
      return amount / factor;
    } else {
      factor = 10 ** (tokenDecimals - 18);
      return amount * factor;
    }
  }

  /**
   * @notice Transfers base tokens to the recipient, withdrawing from strategy if necessary.
   * @param baseToken The base token.
   * @param strategyAddress The strategy address.
   * @param treasuryState The treasury state.
   * @param amount The amount of base tokens to transfer.
   * @param recipient The recipient address.
   */
  function transferBaseToken(
    address self,
    uint8 baseTokenDecimals,
    Currency baseToken,
    address strategyAddress,
    DTreasury.TreasuryState storage treasuryState,
    uint256 amount,
    address recipient
  ) internal {
    uint256 amountNormalized = normalizeDecimals(amount, baseTokenDecimals);

    uint256 balance = baseToken.balanceOf(self);
    uint256 balanceNormalized = normalizeDecimals(balance, baseTokenDecimals);

    if (balanceNormalized < amountNormalized) {
      uint256 diff = amountNormalized - balanceNormalized;

      if (diff == 0) return;

      IStrategy strategy = IStrategy(strategyAddress);

      bool success = strategy.withdrawToTreasury(diff);

      if (!success) ErrorWithdrawFromStrategy.selector.revertWith();

      if (treasuryState.strategyUnderlying < diff) StrategyUnderflow.selector.revertWith();
      treasuryState.strategyUnderlying -= diff;

      balance = baseToken.balanceOf(self);
      balanceNormalized = normalizeDecimals(balance, baseTokenDecimals);

      if (amountNormalized > balanceNormalized) {
        amountNormalized = balanceNormalized;
        amount = denormalizeDecimals(amountNormalized, baseTokenDecimals);
      }
    }

    treasuryState.totalBaseTokens -= amountNormalized;
    baseToken.safeTransfer(recipient, amount);
    emit BaseTokenTransferred(recipient, amount);
  }

  /**
   * @notice Swaps tokens using the specified router.
   * @param self The address of the contract using this library
   * @param swapRouter The address of the swap router.
   * @param from The address of the token to swap from.
   * @param to The address of the token to swap to.
   * @param amount The amount of tokens to swap.
   * @param minOutAmount The minimum acceptable amount of tokens to receive.
   * @return swappedAmount The amount of tokens received after the swap.
   */
  function swapTokens(
    address self,
    address swapRouter,
    address from,
    address to,
    uint256 amount,
    uint256 minOutAmount
  ) internal returns (uint256 swappedAmount) {
    IDEXRouter router = IDEXRouter(swapRouter);

    uint256 deadline = block.timestamp + 30;

    address[] memory path = new address[](2);
    path[0] = from;
    path[1] = to;

    Currency fromToken = Currency.wrap(from);

    uint256 currentAllowance = fromToken.allowance(self, swapRouter);
    if (currentAllowance < amount) {
      fromToken.safeIncreaseAllowance(swapRouter, amount - currentAllowance);
    }

    swappedAmount = _executeSwap(router, amount, minOutAmount, path, self, deadline);

    if (swappedAmount < minOutAmount) {
      ErrorSwapFailed.selector.revertWith();
    }

    emit SwapExecuted(from, to, amount, swappedAmount);

    return swappedAmount;
  }

  function _executeSwap(
    IDEXRouter router,
    uint256 amount,
    uint256 minOutAmount,
    address[] memory path,
    address to,
    uint256 deadline
  ) private returns (uint256) {
    try router.swapExactTokensForTokens(amount, minOutAmount, path, to, deadline) returns (uint256[] memory amounts) {
      return amounts[amounts.length - 1];
    } catch {
      ErrorSwapFailed.selector.revertWith();
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { IERC20Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";
import { FeeModel } from "../types/CommonTypes.sol";

interface IDXToken is IERC20Upgradeable {
  /**********
   * Events *
   **********/

  /// @notice Emitted when the cooling-off period is updated.
  /// @param oldValue The value of the previous cooling-off period.
  /// @param newValue The value of the current cooling-off period.
  event UpdateCoolingOffPeriod(uint256 indexed oldValue, uint256 indexed newValue);

  /// @notice Emitted when the management fee rate is updated.
  /// @param oldRate The previous management fee rate.
  /// @param newRate The new management fee rate.
  event UpdateManagementFeeRate(uint256 indexed oldRate, uint256 indexed newRate);

  /// @notice Emitted when the funding fee rate is updated.
  /// @param oldRate The previous funding fee rate.
  /// @param newRate The new funding fee rate.
  event UpdateFundingFeeRate(uint256 indexed oldRate, uint256 indexed newRate);

  /// @notice Emitted when the fixed yield amount is updated.
  /// @param oldRate The previous fixed yield amount.
  /// @param newRate The new fixed yield amount.
  event UpdateVariableFundingFeeRate(uint256 indexed oldRate, uint256 indexed newRate);

  /// @notice Emitted when fees are collected.
  /// @param amount The amount of fees collected.
  event FeesCollected(uint256 indexed amount);

  /// @notice Emitted when tokens are minted.
  /// @param to The address receiving the minted tokens.
  /// @param amount The amount of tokens minted.
  event Minted(address indexed to, uint256 indexed amount);

  /// @notice Emitted when tokens are burned.
  /// @param from The address whose tokens are burned.
  /// @param amount The amount of tokens burned.
  event Burned(address indexed from, uint256 indexed amount);

  /// @notice Emitted when the cooling-off period is triggered.
  /// @param account The account triggering the cooling-off period.
  /// @param timestamp The timestamp when triggered.
  event CoolingOffPeriodTriggered(address indexed account, uint256 indexed timestamp);

  /// @notice Emitted when the associated group is updated.
  /// @param groupId The new associated group ID.
  event UpdateGroup(bytes32 indexed groupId);

  /// @notice Emitted when the treasury address is updated.
  /// @param oldTreasury The old treasury address.
  /// @param newTreasury The new treasury address.
  event UpdateTreasuryAddress(address indexed oldTreasury, address indexed newTreasury);

  /// @notice Emitted when the max supply is updated.
  /// @param oldMaxSupply The old max supply.
  /// @param newMaxSupply The new max supply.
  event UpdateMaxSupply(uint256 indexed oldMaxSupply, uint256 indexed newMaxSupply);

  /**********
   * Errors *
   **********/

  /// @dev Thrown when an address is zero.
  error ZeroAddress();

  /// @dev Thrown when decimals are invalid.
  error InvalidDecimals();

  /// @dev Thrown when the cooling-off period is too large.
  error CoolingOffPeriodTooLarge();

  /// @dev Thrown when trying to mint or burn an amount below the minimum.
  error ErrorMinimumMintingAmount();

  /// @dev Thrown when trying to burn an amount below the minimum.
  error ErrorMinimumBurningAmount();

  /// @dev Thrown when minting exceeds the max supply.
  error ExceedsMaxSupply();

  /// @dev Thrown when cooling-off period is active.
  error CoolingOffPeriodActive();

  /// @dev Thrown when parameter is unchanged.
  error ParameterUnchanged();

  /// @dev Thrown when management fee is invalid.
  error InvalidManagementFee();

  /// @dev Thrown when funding fee rate is invalid.
  error InvalidFundingFeeRate();

  /// @dev Thrown when fixed yield amount is invalid.
  error InvalidFixedYieldAmount();

  /// @dev Thrown when fee model is invalid.
  error InvalidFeeModel();

  /// @dev Thrown when base supply is zero.
  error BaseSupplyZero();

  /// @dev Thrown when transfer amount exceeds balance.
  error TransferAmountExceedsBalance();

  /// @dev Thrown when burn amount exceeds balance.
  error BurnAmountExceedsBalance();

  /// @dev Thrown cannot recover token.
  error CannotRecoverToken();

  /// @dev Thrown when invalid base token price.
  error InvalidBaseTokenPrice();

  /// @dev Thrown when an operation is not permitted.
  error NotPermitted();

  /*************************
   * Public View Functions *
   *************************/

  /// @notice Returns the NAV of the token.
  function nav() external view returns (uint256);

  /// @notice Converts DXToken amount to base token amount.
  function dxTokenToBaseToken(uint256 dxTokenAmount) external view returns (uint256 baseTokenAmount);

  /// @notice Returns the fee model.
  function getFeeModel() external view returns (FeeModel);

  /****************************
   * Public Mutated Functions *
   ****************************/

  /// @notice Mints tokens to a specified address.
  function mint(address _to, uint256 _amount) external;

  /// @notice Burns tokens from a specified address.
  function burn(address _from, uint256 _amount) external;

  /// @notice Collects accumulated fees.
  function collectFees() external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { IERC20Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";
import { GroupId } from "../types/GroupId.sol";

/**
 * @title IAToken
 * @notice Interface for AToken, an ERC20-compatible token with minting, burning, and
 *         additional functionality for treasury and rebalance management.
 */
interface IAToken is IERC20Upgradeable {
  /**
   * @dev Emitted when the treasury address is updated.
   * @param oldTreasury The previous treasury address.
   * @param newTreasury The new treasury address.
   */
  event UpdateTreasuryAddress(address indexed oldTreasury, address indexed newTreasury);

  /**
   * @dev Emitted when the rebalance pool address is updated.
   * @param oldRebalancePool The previous rebalance pool address.
   * @param newRebalancePool The new rebalance pool address.
   */
  event UpdateRebalancePool(address indexed oldRebalancePool, address indexed newRebalancePool);

  /**
   * @dev Emitted when tokens are minted to an address.
   * @param to The address receiving the minted tokens.
   * @param amount The amount of tokens minted.
   */
  event Minted(address indexed to, uint256 indexed amount);

  /**
   * @dev Emitted when tokens are burned from an address.
   * @param from The address from which tokens are burned.
   * @param amount The amount of tokens burned.
   */
  event Burned(address indexed from, uint256 indexed amount);

  /**
   * @dev Emitted when a group is updated.
   * @param groupId The identifier of the updated group.
   */
  event UpdateGroup(GroupId indexed groupId);

  /**
   * @dev Emitted when the max supply is updated.
   * @param oldMaxSupply The previous max supply.
   * @param newMaxSupply The new max supply.
   */
  event UpdateMaxSupply(uint256 indexed oldMaxSupply, uint256 indexed newMaxSupply);

  // Custom Errors
  error InvalidDecimals();
  error ErrorNotPermitted();
  error ErrorZeroAddress();
  error ErrorZeroAmount();
  error ErrorExceedsMaxSupply();
  error ErrorCannotRecoverToken();
  error ErrorParameterUnchanged();

  /**
   * @notice Returns the beta status of the token.
   */
  function beta() external view returns (bool);
  
  /**
   * @notice Returns the Net Asset Value (NAV) of the token.
   * @return The current NAV as an unsigned integer.
   */
  function nav() external view returns (uint256);

  /**
   * @notice Returns the number of decimals used by the token.
   * @return The number of decimals.
   */
  function decimals() external view returns (uint8);

  /**
   * @notice Mints tokens to a specified address.
   * @dev Emits a {Minted} event.
   * @param _to The address to receive the minted tokens.
   * @param _amount The amount of tokens to mint.
   */
  function mint(address _to, uint256 _amount) external;

  /**
   * @notice Burns tokens from a specified address.
   * @dev Emits a {Burned} event.
   * @param _from The address from which tokens are burned.
   * @param _amount The amount of tokens to burn.
   */
  function burn(address _from, uint256 _amount) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { IERC20Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/utils/SafeERC20Upgradeable.sol";
import { GroupId } from "../types/GroupId.sol";

/**
 * @title IWToken
 * @notice Interface for the WToken contract, enabling wrapping and unwrapping of an underlying token.
 */
interface IWToken is IERC20Upgradeable {
  /**
   * @dev Emitted when tokens are wrapped into WTokens.
   * @param user The address of the user wrapping tokens.
   * @param underlyingAmount The amount of underlying tokens wrapped.
   * @param amount The amount of tokens wrapped.
   */
  event TokenWrapped(address indexed user, uint256 indexed underlyingAmount, uint256 indexed amount);

  /**
   * @dev Emitted when WTokens are unwrapped into underlying tokens.
   * @param user The address of the user unwrapping tokens.
   * @param underlyingAmount The amount of underlying tokens unwrapped.
   * @param amount The amount of WTokens unwrapped.
   */
  event TokenUnwrapped(address indexed user, uint256 indexed underlyingAmount, uint256 indexed amount);

  /**
   * @dev Emitted when the treasury address is updated.
   * @param oldTreasury The address of the previous treasury contract.
   * @param newTreasury The address of the new treasury contract.
   */
  event UpdateTreasuryAddress(address indexed oldTreasury, address indexed newTreasury);

  /**
   * @dev Emitted when the associated group ID is updated.
   * @param groupId New group identifier.
   */
  event UpdateGroup(GroupId indexed groupId);

  event Rebase(uint256 indexed epoch, uint256 indexed newScalar);
  event RateProviderUpdated(address indexed rateProvider);

  // Custom Errors
  error ErrorZeroAddress();
  error InvalidDecimals();
  error ErrorZeroAmount();
  error ErrorNotPermitted();
  error ErrorCannotRecoverToken();
  error ErrorMaxUnderlyingExceeded();

  /**
   * @notice Wraps underlying tokens into WTokens.
   * @param underlyingAmount The amount of underlying tokens to wrap.
   * @return wrappedAmount amount of WTokens minted.
   */
  function wrap(uint256 underlyingAmount) external returns (uint256 wrappedAmount);

  /**
   * @notice Unwraps WTokens back into underlying tokens.
   * @param burnAmount The amount of WTokens to burn.
   * @return amount of underlying tokens returned.
   */
  function unwrap(uint256 burnAmount) external returns (uint256 amount);

  /**
   * @notice rebase the WToken
   */
  function rebase() external;

  function updateRateProvider(address _rateProvider) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { IERC4626Upgradeable } from "@openzeppelin/contracts-upgradeable/token/ERC20/extensions/ERC4626Upgradeable.sol";

/**
 * @title IRebalancePool
 * @notice Interface for the RebalancePool contract implementing ERC4626
 */
interface IRebalancePool is IERC4626Upgradeable {
  /// @notice Errors
  error ZeroAddress();
  error ZeroDeposit();
  error InvalidDepositAmount();
  error ZeroRedeem();
  error TokenAlreadyAdded(address token);
  error ZeroShares();
  error InvalidPriceFromOracle();
  error NotPermitted();
  error InvalidYieldFee();
  error RedeemingNotAvailableYet();
  error CannotRecoverToken();
  error UpdatingNotAvailableYet();
  error InvalidCoolingPeriod();
  error CoolingPeriodTriggered();

  /// @notice Events
  event YieldDistributed(uint256 indexed assets, uint256 indexed shares);
  event NAVUpdated(address indexed caller, uint256 indexed totalAssets, uint256 indexed totalSupply);
  event CoolingOffPeriodUpdated(uint256 indexed oldPeriod, uint256 indexed newPeriod);
  event FeeCollectorUpdated(address indexed oldCollector, address indexed newCollector);
  event PriceOracleUpdated(address indexed oldOracle, address indexed newOracle);
  event OtherERC20Withdrawn(address indexed receiver, address indexed token, uint256 indexed amount);
  event DepositMade(address indexed depositor, address indexed receiver, uint256 indexed amount);
  event YieldFeeUpdated(uint256 indexed newFee);

  /// @notice Function to update NAV externally
  function updateNAV() external;

  /// @notice Get NAV per share
  function getNavPerShare() external view returns (uint256);

  /// @notice Override decimals
  function decimals() external view override returns (uint8);

  /// @notice Get cooling off period
  function coolingOffPeriod() external view returns (uint256);

  /// @notice Transfer tokens to treasury
  function transferTokenToTreasury(address token, uint256 amount) external;

  /// @notice Get yieldFeePercentage
  function yieldFeePercentage() external view returns (uint256);

  /// @notice Get base points
  function BASE_POINTS() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

// solhint-disable
/// @title Contains 512-bit math functions
/// @notice Facilitates multiplication and division that can have overflow of an intermediate value without any loss of precision
/// @dev Handles "phantom overflow" i.e., allows multiplication and division where an intermediate value overflows 256 bits
library FullMath {
  /// @notice Calculates floor(a×b÷denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
  /// @param a The multiplicand
  /// @param b The multiplier
  /// @param denominator The divisor
  /// @return result The 256-bit result
  /// @dev Credit to Remco Bloemen under MIT license https://xn--2-umb.com/21/muldiv
  function mulDiv(uint256 a, uint256 b, uint256 denominator) internal pure returns (uint256 result) {
    unchecked {
      // 512-bit multiply [prod1 prod0] = a * b
      // Compute the product mod 2**256 and mod 2**256 - 1
      // then use the Chinese Remainder Theorem to reconstruct
      // the 512 bit result. The result is stored in two 256
      // variables such that product = prod1 * 2**256 + prod0
      uint256 prod0 = a * b; // Least significant 256 bits of the product
      uint256 prod1; // Most significant 256 bits of the product
      assembly ("memory-safe") {
        let mm := mulmod(a, b, not(0))
        prod1 := sub(sub(mm, prod0), lt(mm, prod0))
      }

      // Make sure the result is less than 2**256.
      // Also prevents denominator == 0
      require(denominator > prod1, "FullMath: denominator too small");

      // Handle non-overflow cases, 256 by 256 division
      if (prod1 == 0) {
        assembly ("memory-safe") {
          result := div(prod0, denominator)
        }
        return result;
      }

      ///////////////////////////////////////////////
      // 512 by 256 division.
      ///////////////////////////////////////////////

      // Make division exact by subtracting the remainder from [prod1 prod0]
      // Compute remainder using mulmod
      uint256 remainder;
      assembly ("memory-safe") {
        remainder := mulmod(a, b, denominator)
      }
      // Subtract 256 bit number from 512 bit number
      assembly ("memory-safe") {
        prod1 := sub(prod1, gt(remainder, prod0))
        prod0 := sub(prod0, remainder)
      }

      // Factor powers of two out of denominator
      // Compute largest power of two divisor of denominator.
      // Always >= 1.
      uint256 twos = (0 - denominator) & denominator;
      // Divide denominator by power of two
      assembly ("memory-safe") {
        denominator := div(denominator, twos)
      }

      // Divide [prod1 prod0] by the factors of two
      assembly ("memory-safe") {
        prod0 := div(prod0, twos)
      }
      // Shift in bits from prod1 into prod0. For this we need
      // to flip `twos` such that it is 2**256 / twos.
      // If twos is zero, then it becomes one
      assembly ("memory-safe") {
        twos := add(div(sub(0, twos), twos), 1)
      }
      prod0 |= prod1 * twos;

      // Invert denominator mod 2**256
      // Now that denominator is an odd number, it has an inverse
      // modulo 2**256 such that denominator * inv = 1 mod 2**256.
      // Compute the inverse by starting with a seed that is correct
      // correct for four bits. That is, denominator * inv = 1 mod 2**4
      uint256 inv = (3 * denominator) ^ 2;
      // Now use Newton-Raphson iteration to improve the precision.
      // Thanks to Hensel's lifting lemma, this also works in modular
      // arithmetic, doubling the correct bits in each step.
      inv *= 2 - denominator * inv; // inverse mod 2**8
      inv *= 2 - denominator * inv; // inverse mod 2**16
      inv *= 2 - denominator * inv; // inverse mod 2**32
      inv *= 2 - denominator * inv; // inverse mod 2**64
      inv *= 2 - denominator * inv; // inverse mod 2**128
      inv *= 2 - denominator * inv; // inverse mod 2**256

      // Because the division is now exact we can divide by multiplying
      // with the modular inverse of denominator. This will give us the
      // correct result modulo 2**256. Since the preconditions guarantee
      // that the outcome is less than 2**256, this is the final result.
      // We don't need to compute the high bits of the result and prod1
      // is no longer required.
      result = prod0 * inv;
      return result;
    }
  }

  /// @notice Calculates ceil(a×b÷denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
  /// @param a The multiplicand
  /// @param b The multiplier
  /// @param denominator The divisor
  /// @return result The 256-bit result
  function mulDivRoundingUp(uint256 a, uint256 b, uint256 denominator) internal pure returns (uint256 result) {
    unchecked {
      result = mulDiv(a, b, denominator);
      if (mulmod(a, b, denominator) != 0) {
        require(++result > 0, "FullMath: addition overflow");
      }
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import { GroupId } from "../types/GroupId.sol";

interface IProtocolMinimum {
    function stabilityRatio(GroupId groupId) external view returns (uint96);
}

// SPDX-License-Identifier: MIT

// THE SOFTWARE IS PROVIDED “AS IS”, WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE
// WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR
// COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR
// OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

pragma solidity 0.8.28;

/* solhint-disable */

/**
 * @dev Copied from https://github.com/balancer/balancer-v2-monorepo/blob/master/pkg/solidity-utils/contracts/math/LogExpMath.sol
 *
 * Some modifications are made due to compile error.
 *
 * It is the same as `LogExpMathV8` with `unchecked` scope.
 *
 * @dev Exponentiation and logarithm functions for 18 decimal fixed point numbers (both base and exponent/argument).
 *
 * Exponentiation and logarithm with arbitrary bases (x^y and log_x(y)) are implemented by conversion to natural
 * exponentiation and logarithm (where the base is Euler's number).
 *
 * @author Fernando Martinelli - @fernandomartinelli
 * @author Sergio Yuhjtman - @sergioyuhjtman
 * @author Daniel Fernandez - @dmf7z
 */
library LogExpMathV8 {
  // All fixed point multiplications and divisions are inlined. This means we need to divide by ONE when multiplying
  // two numbers, and multiply by ONE when dividing them.

  // All arguments and return values are 18 decimal fixed point numbers.
  int256 constant ONE_18 = 1e18;

  // Internally, intermediate values are computed with higher precision as 20 decimal fixed point numbers, and in the
  // case of ln36, 36 decimals.
  int256 constant ONE_20 = 1e20;
  int256 constant ONE_36 = 1e36;

  // The domain of natural exponentiation is bound by the word size and number of decimals used.
  //
  // Because internally the result will be stored using 20 decimals, the largest possible result is
  // (2^255 - 1) / 10^20, which makes the largest exponent ln((2^255 - 1) / 10^20) = 130.700829182905140221.
  // The smallest possible result is 10^(-18), which makes largest negative argument
  // ln(10^(-18)) = -41.446531673892822312.
  // We use 130.0 and -41.0 to have some safety margin.
  int256 constant MAX_NATURAL_EXPONENT = 130e18;
  int256 constant MIN_NATURAL_EXPONENT = -41e18;

  // Bounds for ln_36's argument. Both ln(0.9) and ln(1.1) can be represented with 36 decimal places in a fixed point
  // 256 bit integer.
  int256 constant LN_36_LOWER_BOUND = ONE_18 - 1e17;
  int256 constant LN_36_UPPER_BOUND = ONE_18 + 1e17;

  uint256 constant MILD_EXPONENT_BOUND = 2 ** 254 / uint256(ONE_20);

  // 18 decimal constants
  int256 constant x0 = 128000000000000000000; // 2ˆ7
  int256 constant a0 = 38877084059945950922200000000000000000000000000000000000; // eˆ(x0) (no decimals)
  int256 constant x1 = 64000000000000000000; // 2ˆ6
  int256 constant a1 = 6235149080811616882910000000; // eˆ(x1) (no decimals)

  // 20 decimal constants
  int256 constant x2 = 3200000000000000000000; // 2ˆ5
  int256 constant a2 = 7896296018268069516100000000000000; // eˆ(x2)
  int256 constant x3 = 1600000000000000000000; // 2ˆ4
  int256 constant a3 = 888611052050787263676000000; // eˆ(x3)
  int256 constant x4 = 800000000000000000000; // 2ˆ3
  int256 constant a4 = 298095798704172827474000; // eˆ(x4)
  int256 constant x5 = 400000000000000000000; // 2ˆ2
  int256 constant a5 = 5459815003314423907810; // eˆ(x5)
  int256 constant x6 = 200000000000000000000; // 2ˆ1
  int256 constant a6 = 738905609893065022723; // eˆ(x6)
  int256 constant x7 = 100000000000000000000; // 2ˆ0
  int256 constant a7 = 271828182845904523536; // eˆ(x7)
  int256 constant x8 = 50000000000000000000; // 2ˆ-1
  int256 constant a8 = 164872127070012814685; // eˆ(x8)
  int256 constant x9 = 25000000000000000000; // 2ˆ-2
  int256 constant a9 = 128402541668774148407; // eˆ(x9)
  int256 constant x10 = 12500000000000000000; // 2ˆ-3
  int256 constant a10 = 113314845306682631683; // eˆ(x10)
  int256 constant x11 = 6250000000000000000; // 2ˆ-4
  int256 constant a11 = 106449445891785942956; // eˆ(x11)

  /**
   * @dev Exponentiation (x^y) with unsigned 18 decimal fixed point base and exponent.
   *
   * Reverts if ln(x) * y is smaller than `MIN_NATURAL_EXPONENT`, or larger than `MAX_NATURAL_EXPONENT`.
   */
  function pow(uint256 x, uint256 y) internal pure returns (uint256) {
    unchecked {
      if (y == 0) {
        // We solve the 0^0 indetermination by making it equal one.
        return uint256(ONE_18);
      }

      if (x == 0) {
        return 0;
      }

      // Instead of computing x^y directly, we instead rely on the properties of logarithms and exponentiation to
      // arrive at that result. In particular, exp(ln(x)) = x, and ln(x^y) = y * ln(x). This means
      // x^y = exp(y * ln(x)).

      // The ln function takes a signed value, so we need to make sure x fits in the signed 256 bit range.
      require(x >> 255 == 0, "X_OUT_OF_BOUNDS");
      int256 x_int256 = int256(x);

      // We will compute y * ln(x) in a single step. Depending on the value of x, we can either use ln or ln_36. In
      // both cases, we leave the division by ONE_18 (due to fixed point multiplication) to the end.

      // This prevents y * ln(x) from overflowing, and at the same time guarantees y fits in the signed 256 bit range.
      require(y < MILD_EXPONENT_BOUND, "Y_OUT_OF_BOUNDS");
      int256 y_int256 = int256(y);

      int256 logx_times_y;
      if (LN_36_LOWER_BOUND < x_int256 && x_int256 < LN_36_UPPER_BOUND) {
        int256 ln_36_x = _ln_36(x_int256);

        // ln_36_x has 36 decimal places, so multiplying by y_int256 isn't as straightforward, since we can't just
        // bring y_int256 to 36 decimal places, as it might overflow. Instead, we perform two 18 decimal
        // multiplications and add the results: one with the first 18 decimals of ln_36_x, and one with the
        // (downscaled) last 18 decimals.
        logx_times_y = ((ln_36_x / ONE_18) * y_int256 + ((ln_36_x % ONE_18) * y_int256) / ONE_18);
      } else {
        logx_times_y = _ln(x_int256) * y_int256;
      }
      logx_times_y /= ONE_18;

      // Finally, we compute exp(y * ln(x)) to arrive at x^y
      require(MIN_NATURAL_EXPONENT <= logx_times_y && logx_times_y <= MAX_NATURAL_EXPONENT, "PRODUCT_OUT_OF_BOUNDS");

      return uint256(exp(logx_times_y));
    }
  }

  /**
   * @dev Natural exponentiation (e^x) with signed 18 decimal fixed point exponent.
   *
   * Reverts if `x` is smaller than MIN_NATURAL_EXPONENT, or larger than `MAX_NATURAL_EXPONENT`.
   */
  function exp(int256 x) internal pure returns (int256) {
    unchecked {
      require(x >= MIN_NATURAL_EXPONENT && x <= MAX_NATURAL_EXPONENT, "INVALID_EXPONENT");

      if (x < 0) {
        // We only handle positive exponents: e^(-x) is computed as 1 / e^x. We can safely make x positive since it
        // fits in the signed 256 bit range (as it is larger than MIN_NATURAL_EXPONENT).
        // Fixed point division requires multiplying by ONE_18.
        return ((ONE_18 * ONE_18) / exp(-x));
      }

      // First, we use the fact that e^(x+y) = e^x * e^y to decompose x into a sum of powers of two, which we call x_n,
      // where x_n == 2^(7 - n), and e^x_n = a_n has been precomputed. We choose the first x_n, x0, to equal 2^7
      // because all larger powers are larger than MAX_NATURAL_EXPONENT, and therefore not present in the
      // decomposition.
      // At the end of this process we will have the product of all e^x_n = a_n that apply, and the remainder of this
      // decomposition, which will be lower than the smallest x_n.
      // exp(x) = k_0 * a_0 * k_1 * a_1 * ... + k_n * a_n * exp(remainder), where each k_n equals either 0 or 1.
      // We mutate x by subtracting x_n, making it the remainder of the decomposition.

      // The first two a_n (e^(2^7) and e^(2^6)) are too large if stored as 18 decimal numbers, and could cause
      // intermediate overflows. Instead we store them as plain integers, with 0 decimals.
      // Additionally, x0 + x1 is larger than MAX_NATURAL_EXPONENT, which means they will not both be present in the
      // decomposition.

      // For each x_n, we test if that term is present in the decomposition (if x is larger than it), and if so deduct
      // it and compute the accumulated product.

      int256 firstAN;
      if (x >= x0) {
        x -= x0;
        firstAN = a0;
      } else if (x >= x1) {
        x -= x1;
        firstAN = a1;
      } else {
        firstAN = 1; // One with no decimal places
      }

      // We now transform x into a 20 decimal fixed point number, to have enhanced precision when computing the
      // smaller terms.
      x *= 100;

      // `product` is the accumulated product of all a_n (except a0 and a1), which starts at 20 decimal fixed point
      // one. Recall that fixed point multiplication requires dividing by ONE_20.
      int256 product = ONE_20;

      if (x >= x2) {
        x -= x2;
        product = (product * a2) / ONE_20;
      }
      if (x >= x3) {
        x -= x3;
        product = (product * a3) / ONE_20;
      }
      if (x >= x4) {
        x -= x4;
        product = (product * a4) / ONE_20;
      }
      if (x >= x5) {
        x -= x5;
        product = (product * a5) / ONE_20;
      }
      if (x >= x6) {
        x -= x6;
        product = (product * a6) / ONE_20;
      }
      if (x >= x7) {
        x -= x7;
        product = (product * a7) / ONE_20;
      }
      if (x >= x8) {
        x -= x8;
        product = (product * a8) / ONE_20;
      }
      if (x >= x9) {
        x -= x9;
        product = (product * a9) / ONE_20;
      }

      // x10 and x11 are unnecessary here since we have high enough precision already.

      // Now we need to compute e^x, where x is small (in particular, it is smaller than x9). We use the Taylor series
      // expansion for e^x: 1 + x + (x^2 / 2!) + (x^3 / 3!) + ... + (x^n / n!).

      int256 seriesSum = ONE_20; // The initial one in the sum, with 20 decimal places.
      int256 term; // Each term in the sum, where the nth term is (x^n / n!).

      // The first term is simply x.
      term = x;
      seriesSum += term;

      // Each term (x^n / n!) equals the previous one times x, divided by n. Since x is a fixed point number,
      // multiplying by it requires dividing by ONE_20, but dividing by the non-fixed point n values does not.

      term = ((term * x) / ONE_20) / 2;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 3;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 4;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 5;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 6;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 7;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 8;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 9;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 10;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 11;
      seriesSum += term;

      term = ((term * x) / ONE_20) / 12;
      seriesSum += term;

      // 12 Taylor terms are sufficient for 18 decimal precision.

      // We now have the first a_n (with no decimals), and the product of all other a_n present, and the Taylor
      // approximation of the exponentiation of the remainder (both with 20 decimals). All that remains is to multiply
      // all three (one 20 decimal fixed point multiplication, dividing by ONE_20, and one integer multiplication),
      // and then drop two digits to return an 18 decimal value.

      return (((product * seriesSum) / ONE_20) * firstAN) / 100;
    }
  }

  /**
   * @dev Logarithm (log(arg, base), with signed 18 decimal fixed point base and argument.
   */
  function log(int256 arg, int256 base) internal pure returns (int256) {
    unchecked {
      // This performs a simple base change: log(arg, base) = ln(arg) / ln(base).

      // Both logBase and logArg are computed as 36 decimal fixed point numbers, either by using ln_36, or by
      // upscaling.

      int256 logBase;
      if (LN_36_LOWER_BOUND < base && base < LN_36_UPPER_BOUND) {
        logBase = _ln_36(base);
      } else {
        logBase = _ln(base) * ONE_18;
      }

      int256 logArg;
      if (LN_36_LOWER_BOUND < arg && arg < LN_36_UPPER_BOUND) {
        logArg = _ln_36(arg);
      } else {
        logArg = _ln(arg) * ONE_18;
      }

      // When dividing, we multiply by ONE_18 to arrive at a result with 18 decimal places
      return (logArg * ONE_18) / logBase;
    }
  }

  /**
   * @dev Natural logarithm (ln(a)) with signed 18 decimal fixed point argument.
   */
  function ln(int256 a) internal pure returns (int256) {
    unchecked {
      // The real natural logarithm is not defined for negative numbers or zero.
      require(a > 0, "OUT_OF_BOUNDS");
      if (LN_36_LOWER_BOUND < a && a < LN_36_UPPER_BOUND) {
        return _ln_36(a) / ONE_18;
      } else {
        return _ln(a);
      }
    }
  }

  /**
   * @dev Internal natural logarithm (ln(a)) with signed 18 decimal fixed point argument.
   */
  function _ln(int256 a) private pure returns (int256) {
    unchecked {
      if (a < ONE_18) {
        // Since ln(a^k) = k * ln(a), we can compute ln(a) as ln(a) = ln((1/a)^(-1)) = - ln((1/a)). If a is less
        // than one, 1/a will be greater than one, and this if statement will not be entered in the recursive call.
        // Fixed point division requires multiplying by ONE_18.
        return (-_ln((ONE_18 * ONE_18) / a));
      }

      // First, we use the fact that ln^(a * b) = ln(a) + ln(b) to decompose ln(a) into a sum of powers of two, which
      // we call x_n, where x_n == 2^(7 - n), which are the natural logarithm of precomputed quantities a_n (that is,
      // ln(a_n) = x_n). We choose the first x_n, x0, to equal 2^7 because the exponential of all larger powers cannot
      // be represented as 18 fixed point decimal numbers in 256 bits, and are therefore larger than a.
      // At the end of this process we will have the sum of all x_n = ln(a_n) that apply, and the remainder of this
      // decomposition, which will be lower than the smallest a_n.
      // ln(a) = k_0 * x_0 + k_1 * x_1 + ... + k_n * x_n + ln(remainder), where each k_n equals either 0 or 1.
      // We mutate a by subtracting a_n, making it the remainder of the decomposition.

      // For reasons related to how `exp` works, the first two a_n (e^(2^7) and e^(2^6)) are not stored as fixed point
      // numbers with 18 decimals, but instead as plain integers with 0 decimals, so we need to multiply them by
      // ONE_18 to convert them to fixed point.
      // For each a_n, we test if that term is present in the decomposition (if a is larger than it), and if so divide
      // by it and compute the accumulated sum.

      int256 sum = 0;
      if (a >= a0 * ONE_18) {
        a /= a0; // Integer, not fixed point division
        sum += x0;
      }

      if (a >= a1 * ONE_18) {
        a /= a1; // Integer, not fixed point division
        sum += x1;
      }

      // All other a_n and x_n are stored as 20 digit fixed point numbers, so we convert the sum and a to this format.
      sum *= 100;
      a *= 100;

      // Because further a_n are  20 digit fixed point numbers, we multiply by ONE_20 when dividing by them.

      if (a >= a2) {
        a = (a * ONE_20) / a2;
        sum += x2;
      }

      if (a >= a3) {
        a = (a * ONE_20) / a3;
        sum += x3;
      }

      if (a >= a4) {
        a = (a * ONE_20) / a4;
        sum += x4;
      }

      if (a >= a5) {
        a = (a * ONE_20) / a5;
        sum += x5;
      }

      if (a >= a6) {
        a = (a * ONE_20) / a6;
        sum += x6;
      }

      if (a >= a7) {
        a = (a * ONE_20) / a7;
        sum += x7;
      }

      if (a >= a8) {
        a = (a * ONE_20) / a8;
        sum += x8;
      }

      if (a >= a9) {
        a = (a * ONE_20) / a9;
        sum += x9;
      }

      if (a >= a10) {
        a = (a * ONE_20) / a10;
        sum += x10;
      }

      if (a >= a11) {
        a = (a * ONE_20) / a11;
        sum += x11;
      }

      // a is now a small number (smaller than a_11, which roughly equals 1.06). This means we can use a Taylor series
      // that converges rapidly for values of `a` close to one - the same one used in ln_36.
      // Let z = (a - 1) / (a + 1).
      // ln(a) = 2 * (z + z^3 / 3 + z^5 / 5 + z^7 / 7 + ... + z^(2 * n + 1) / (2 * n + 1))

      // Recall that 20 digit fixed point division requires multiplying by ONE_20, and multiplication requires
      // division by ONE_20.
      int256 z = ((a - ONE_20) * ONE_20) / (a + ONE_20);
      int256 z_squared = (z * z) / ONE_20;

      // num is the numerator of the series: the z^(2 * n + 1) term
      int256 num = z;

      // seriesSum holds the accumulated sum of each term in the series, starting with the initial z
      int256 seriesSum = num;

      // In each step, the numerator is multiplied by z^2
      num = (num * z_squared) / ONE_20;
      seriesSum += num / 3;

      num = (num * z_squared) / ONE_20;
      seriesSum += num / 5;

      num = (num * z_squared) / ONE_20;
      seriesSum += num / 7;

      num = (num * z_squared) / ONE_20;
      seriesSum += num / 9;

      num = (num * z_squared) / ONE_20;
      seriesSum += num / 11;

      // 6 Taylor terms are sufficient for 36 decimal precision.

      // Finally, we multiply by 2 (non fixed point) to compute ln(remainder)
      seriesSum *= 2;

      // We now have the sum of all x_n present, and the Taylor approximation of the logarithm of the remainder (both
      // with 20 decimals). All that remains is to sum these two, and then drop two digits to return a 18 decimal
      // value.

      return (sum + seriesSum) / 100;
    }
  }

  /**
   * @dev Intrnal high precision (36 decimal places) natural logarithm (ln(x)) with signed 18 decimal fixed point argument,
   * for x close to one.
   *
   * Should only be used if x is between LN_36_LOWER_BOUND and LN_36_UPPER_BOUND.
   */
  function _ln_36(int256 x) private pure returns (int256) {
    unchecked {
      // Since ln(1) = 0, a value of x close to one will yield a very small result, which makes using 36 digits
      // worthwhile.

      // First, we transform x to a 36 digit fixed point value.
      x *= ONE_18;

      // We will use the following Taylor expansion, which converges very rapidly. Let z = (x - 1) / (x + 1).
      // ln(x) = 2 * (z + z^3 / 3 + z^5 / 5 + z^7 / 7 + ... + z^(2 * n + 1) / (2 * n + 1))

      // Recall that 36 digit fixed point division requires multiplying by ONE_36, and multiplication requires
      // division by ONE_36.
      int256 z = ((x - ONE_36) * ONE_36) / (x + ONE_36);
      int256 z_squared = (z * z) / ONE_36;

      // num is the numerator of the series: the z^(2 * n + 1) term
      int256 num = z;

      // seriesSum holds the accumulated sum of each term in the series, starting with the initial z
      int256 seriesSum = num;

      // In each step, the numerator is multiplied by z^2
      num = (num * z_squared) / ONE_36;
      seriesSum += num / 3;

      num = (num * z_squared) / ONE_36;
      seriesSum += num / 5;

      num = (num * z_squared) / ONE_36;
      seriesSum += num / 7;

      num = (num * z_squared) / ONE_36;
      seriesSum += num / 9;

      num = (num * z_squared) / ONE_36;
      seriesSum += num / 11;

      num = (num * z_squared) / ONE_36;
      seriesSum += num / 13;

      num = (num * z_squared) / ONE_36;
      seriesSum += num / 15;

      // 8 Taylor terms are sufficient for 36 decimal precision.

      // All that remains is multiplying by 2 (non fixed point).
      return seriesSum * 2;
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

/// @dev This library implements formulas for minting and redeeming stable coin token (aToken) and leveraged (xToken)
///      tokens in a system where:
///        - There is a base token with a certain Net Asset Value (NAV).
///        - A stable coin token (aToken) with its own NAV.
///        - A leveraged token (xToken) with its own NAV.
///      All values are scaled by 1e18 before being passed to these functions.
///
/// The core equation governing the system is:
///     n * v = nf * vf + nx * vx
///
/// Where:
///   n   = current total base supply
///   v   = baseNav (NAV of base token)
///   nf  = aSupply (supply of stable coin token)
///   vf  = aNav (NAV of stable coin token)
///   nx  = xSupply (supply of leveraged token)
///   vx  = xNav (NAV of leveraged token)
///
/// The "collateral ratio" (cr) or "target collateral ratio" (ncr) is defined as:
///   cr = (total base value) / (stable coin token value) = (n * v) / (nf * vf)
///
/// Operations involve adjusting supplies (minting or redeeming tokens) to reach a new collateral ratio (ncr).
/// We define:
///   dn = change in base supply (how many base tokens are added or removed)
///   df = change in stable coin token supply (how many stable coin tokens are added or removed)
///
/// By setting:
///   ((n + dn) * v) / ((nf + df)*vf) = ncr
///
/// and using the base equation n * v = nf * vf + nx * vx, we can derive formulas for dn and df
/// depending on whether we are minting or redeeming under a desired collateral ratio.

library FxStableMath {
  /*************
   * Constants *
   *************/

  /// @dev The precision (scaling factor) used for calculations.
  uint256 internal constant PRECISION = 1e18;

  /// @dev The maximum leverage ratio allowed.
  uint256 internal constant MAX_LEVERAGE_RATIO = 100e18;

  /***********
   * Structs *
   ***********/

  struct SwapState {
    // Current supply of the base token
    uint256 baseSupply;
    // Current NAV of the base token (scaled by 1e18)
    uint256 baseNav;
    // Current TWAP NAV of the base token (scaled by 1e18), used for stable calculations
    uint256 baseTwapNav;
    // Current supply of the stable coin token
    uint256 aSupply;
    // Current NAV of the stable coin token (scaled by 1e18)
    uint256 aNav;
    // Current supply of the leveraged token
    uint256 xSupply;
    // Current NAV of the leveraged token (scaled by 1e18)
    uint256 xNav;
    // A boolean parameter `beta` that may adjust behavior in some calculations
    bool beta;
  }

  /**
   * @notice Compute how much base token (dn) and stable coin tokens (df) can be minted to achieve a new collateral ratio,
   *         if the current collateral ratio is less than the new target.
   *
   * Variables (for reference):
   *   n: current total base supply
   *   v: baseNav
   *   nf: aSupply
   *   vf: aNav
   *   nx: xSupply
   *   vx: xNav
   *   ncr: newCollateralRatio
   *
   * Core equations:
   *   Initially:
   *       n * v = nf * vf + nx * vx
   *
   *   After adding some amount of base tokens (dn) and stable coin tokens (df):
   *       (n + dn) * v = (nf + df) * vf + nx * vx
   *
   *   Define collateral ratio as:
   *       ((n + dn) * v) / ((nf + df) * vf) = ncr
   *
   *   From the above, solving for df and dn:
   *       df = ((n * v) - (ncr * nf * vf)) / ((ncr - 1) * vf)
   *       dn = ((n * v) - (ncr * nf * vf)) / ((ncr - 1) * v)
   *
   * Here, df and dn tell us how much stable coin token and base token must be added to achieve ncr.
   * If dn > 0, we need to add that many base tokens; if df > 0, we can mint that many stable coin tokens.
   *
   * @dev If the current collateral ratio is already >= ncr, then we return 0 because no minting is needed.
   *
   * @param state Current state of the system.
   * @param _newCollateralRatio The desired new collateral ratio (scaled by 1e18).
   * @return _maxBaseIn The amount of base token required (corresponds to dn).
   * @return _maxATokenMintable The amount of stable coin token (aToken) that can be minted (corresponds to df).
   */
  function maxMintableAToken(
    SwapState memory state,
    uint256 _newCollateralRatio
  ) internal pure returns (uint256 _maxBaseIn, uint256 _maxATokenMintable) {
    // Calculate scaled values
    uint256 _baseVal = state.baseSupply * (state.baseNav) * (PRECISION);
    uint256 _aVal = _newCollateralRatio * (state.aSupply) * state.aNav;

    // If baseVal > aVal, we can mint
    if (_baseVal > _aVal) {
      // Adjust ncr to (ncr - 1)*PRECISION
      _newCollateralRatio = _newCollateralRatio - (PRECISION);
      uint256 _delta = _baseVal - _aVal;

      // dn = delta / ((ncr - 1)*v)
      _maxBaseIn = _delta / (state.baseNav * (_newCollateralRatio));

      // df = delta / ((ncr - 1)*vf)
      _maxATokenMintable = _delta / (state.aNav * (_newCollateralRatio));
    }
  }

  /**
   * @notice Compute how much base token (dn) and leveraged tokens (xToken) can be minted to achieve a new collateral ratio,
   *         if the current collateral ratio is less than the new target.
   *
   * Equations:
   *   n * v = nf * vf + nx * vx
   *
   * After adding dn base tokens and dx leveraged tokens:
   *   (n + dn)*v = nf*vf + (nx + dx)*vx
   *
   * The new collateral ratio condition:
   *   ((n + dn)*v) / (nf*vf) = ncr
   *
   * From this, solving for dn and dx:
   *   dn = (ncr * nf * vf - n * v) / v
   *   dx = (ncr * nf * vf - n * v) / vx
   *
   * @dev If the current collateral ratio >= ncr, we return 0 because no minting is needed.
   *
   * @param state The current state.
   * @param _newCollateralRatio The desired new collateral ratio (scaled by 1e18).
   * @return _maxBaseIn The amount of base token needed (dn).
   * @return _maxXTokenMintable The amount of leveraged token (xToken) that can be minted (dx).
   */
  function maxMintableXToken(
    SwapState memory state,
    uint256 _newCollateralRatio
  ) internal pure returns (uint256 _maxBaseIn, uint256 _maxXTokenMintable) {
    uint256 _baseVal = state.baseSupply * state.baseNav * PRECISION;
    uint256 _aVal = _newCollateralRatio * state.aSupply * state.aNav;

    if (_aVal > _baseVal) {
      uint256 _delta = _aVal - _baseVal;

      // dn = delta / (v * PRECISION)
      _maxBaseIn = _delta / (state.baseNav * (PRECISION));
      // dx = delta / (vx * PRECISION)
      _maxXTokenMintable = _delta / (state.xNav * (PRECISION));
    }
  }

  /**
   * @notice Compute how many stable coin tokens (aToken) can be redeemed and how much base token (dn) is released
   *         to reach the new collateral ratio if the current ratio is greater than the target.
   *
   * Equations:
   *   Initially:
   *       n * v = nf * vf + nx * vx
   *
   * After removing dn base tokens and df stable coin tokens:
   *       (n - dn)*v = (nf - df)*vf + nx*vx
   *
   * The new collateral ratio:
   *       ((n - dn)*v) / ((nf - df)*vf) = ncr
   *
   * Solve these for df and dn:
   *   df = (ncr * nf * vf - n * v) / ((ncr - 1)*vf)
   *   dn = (ncr * nf * vf - n * v) / ((ncr - 1)*v)
   *
   * Here, df and dn now represent how many stable coin tokens and base tokens must be removed (redeemed)
   * to achieve ncr. If df > 0, it means we should redeem that many aTokens; if dn > 0, that many base tokens
   * can be released.
   *
   * @dev If the current collateral ratio <= ncr, no redemption is needed, so return 0.
   *
   * @param state Current state.
   * @param _newCollateralRatio Desired collateral ratio (scaled by 1e18).
   * @return _maxBaseOut The amount of base token released (dn).
   * @return _maxATokenRedeemable The amount of stable coin token that can be redeemed (df).
   */
  function maxRedeemableAToken(
    SwapState memory state,
    uint256 _newCollateralRatio
  ) internal pure returns (uint256 _maxBaseOut, uint256 _maxATokenRedeemable) {
    uint256 _baseVal = state.baseSupply * (state.baseNav) * (PRECISION);
    uint256 _aVal = _newCollateralRatio * (state.aSupply) * (PRECISION);

    if (_aVal > _baseVal) {
      uint256 _delta = _aVal - _baseVal;
      // Adjust ncr to (ncr - 1)*PRECISION
      _newCollateralRatio = _newCollateralRatio - (PRECISION);

      // df = delta / ((ncr - 1)*vf)
      _maxATokenRedeemable = _delta / (_newCollateralRatio * (state.aNav));

      // dn = delta / ((ncr - 1)*v)
      _maxBaseOut = _delta / (_newCollateralRatio * (state.baseNav));
    } else {
      _maxBaseOut = 0;
      _maxATokenRedeemable = 0;
    }
  }

  /**
   * @notice Compute how many leveraged tokens (xToken) can be redeemed and how much base token is released
   *         if the current collateral ratio is greater than the target.
   *
   * Equations:
   *   n * v = nf * vf + nx * vx
   *
   * After removing dn base tokens and dx leveraged tokens:
   *   (n - dn)*v = nf*vf + (nx - dx)*vx
   *
   * The new collateral ratio:
   *   ((n - dn)*v) / (nf*vf) = ncr
   *
   * Solve for dn and dx:
   *   dn = (n * v - ncr * nf * vf) / v
   *   dx = (n * v - ncr * nf * vf) / vx
   *
   * If dn > 0, that means base tokens can be redeemed; if dx > 0, that many xTokens can be redeemed.
   *
   * @dev If current collateral ratio <= ncr, return 0.
   *
   * @param state Current state.
   * @param _newCollateralRatio Desired collateral ratio (scaled by 1e18).
   * @return _maxBaseOut The base token released (dn).
   * @return _maxXTokenRedeemable The leveraged tokens (xToken) redeemable (dx).
   */
  function maxRedeemableXToken(
    SwapState memory state,
    uint256 _newCollateralRatio
  ) internal pure returns (uint256 _maxBaseOut, uint256 _maxXTokenRedeemable) {
    uint256 _baseVal = state.baseSupply * (state.baseNav) * (PRECISION);
    uint256 _aVal = _newCollateralRatio * (state.aSupply) * (state.aNav);

    if (_baseVal > _aVal) {
      uint256 _delta = _baseVal - _aVal;

      // dx = delta / (vx * PRECISION)
      _maxXTokenRedeemable = _delta / (state.xNav * (PRECISION));
      // dn = delta / (v * PRECISION)
      _maxBaseOut = _delta / (state.baseNav * (PRECISION));
    } else {
      _maxBaseOut = 0;
      _maxXTokenRedeemable = 0;
    }
  }

  /**
   * @notice Mint stable coin tokens (aToken) given a certain amount of base tokens (dn).
   *
   * Equations:
   *   n * v = nf * vf + nx * vx
   * After adding dn base and df fraction tokens:
   *   (n + dn)*v = (nf + df)*vf + nx*vx
   *
   * Solve for df given dn:
   *   df = (dn * v) / vf
   *
   * @param state Current state.
   * @param _baseIn Amount of base token supplied.
   * @return _aTokenOut Amount of stable coin token minted (df).
   */
  function mintAToken(SwapState memory state, uint256 _baseIn) internal pure returns (uint256 _aTokenOut) {
    // df = (dn * v) / vf
    _aTokenOut = (_baseIn * state.baseNav) / state.aNav;
  }

  /**
   * @notice Mint leveraged tokens (xToken) given a certain amount of base tokens (dn).
   *
   * Equations:
   *   n * v = nf * vf + nx * vx
   * After adding dn base tokens and dx leveraged tokens:
   *   (n + dn)*v = nf*vf + (nx + dx)*vx
   *
   * Solve for dx:
   *   dx = (dn * v * nx) / (n * v - nf * vf)
   *
   * @param state Current state.
   * @param _baseIn Amount of base token supplied.
   * @return _xTokenOut Amount of leveraged token minted (dx).
   */
  function mintXToken(SwapState memory state, uint256 _baseIn) internal pure returns (uint256 _xTokenOut) {
    // dx = (dn * v * nx) / (n * v - nf * vf)
    _xTokenOut = _baseIn * state.baseNav * state.xSupply;
    _xTokenOut = _xTokenOut / (state.baseSupply * state.baseNav - state.aSupply * state.aNav);
  }

  /**
   * @notice Redeem base tokens by supplying stable coin tokens (aToken) and/or leveraged tokens (xToken).
   *
   * Equations:
   *   n * v = nf * vf + nx * vx
   * After removing df fraction tokens and dx leveraged tokens:
   *   (n - dn)*v = (nf - df)*vf + (nx - dx)*vx
   *
   * The amount of baseOut (dn*v) depends on how many fraction and leveraged tokens are provided.
   *
   * If xSupply = 0 (no leveraged tokens):
   *   baseOut = (aTokenIn * vf) / v
   *
   * If xSupply > 0:
   *   baseOut = [ (aTokenIn * vf) + (xTokenIn * (n*v - nf*vf) / nx ) ] / v
   *
   * @param state Current state.
   * @param _aTokenIn stable coin tokens supplied.
   * @param _xTokenIn Leveraged tokens supplied.
   * @return _baseOut Amount of base token redeemed.
   */
  function redeem(SwapState memory state, uint256 _aTokenIn, uint256 _xTokenIn) internal pure returns (uint256 _baseOut) {
    uint256 _xVal = state.baseSupply * state.baseNav - state.aSupply * state.aNav;

    if (state.xSupply == 0) {
      _baseOut = (_aTokenIn * state.aNav) / state.baseNav;
    } else {
      _baseOut = _aTokenIn * state.aNav;
      _baseOut += (_xTokenIn * _xVal) / state.xSupply;
      _baseOut /= state.baseNav;
    }
  }

  /**
   * @notice Compute the current leverage ratio for the xToken.
   *
   * Define:
   *   rho = (aSupply * aNav) / (baseSupply * baseTwapNav)
   *
   * When beta = false, leverage ratio = 1 / (1 - rho)
   * If under-collateralized (rho >= 1), leverage ratio = MAX_LEVERAGE_RATIO
   *
   * @param state Current state.
   * @return ratio Current leverage ratio.
   */
  function leverageRatio(SwapState memory state) internal pure returns (uint256 ratio) {
    if (state.beta) return PRECISION;

    if(state.baseSupply == 0 || state.baseNav == 0 || state.baseTwapNav == 0) return 0;

    // rho = (aSupply * aNav * PRECISION) / (baseSupply * baseTwapNav)
    uint256 rho = (state.aSupply * state.aNav * PRECISION) / (state.baseSupply * state.baseTwapNav);

    if (rho >= PRECISION) {
      // Under-collateralized
      ratio = MAX_LEVERAGE_RATIO;
    } else {
      // ratio = 1 / (1 - rho)
      ratio = (PRECISION * PRECISION) / (PRECISION - rho);
      if (ratio > MAX_LEVERAGE_RATIO) ratio = MAX_LEVERAGE_RATIO;
    }
  }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

/**
 * @title IPriceOracle
 * @notice Interface for the PriceOracle contract, managing and updating token price feeds.
 */
interface IPriceOracle {
  /**
   * @dev Emitted when a price feed is added for a token.
   * @param token The address of the token.
   * @param feed The address of the Chainlink price feed.
   */
  event FeedAdded(address indexed token, address indexed feed);

  /**
   * @dev Emitted when a price feed is removed for a token.
   * @param token The address of the token.
   */
  event FeedRemoved(address indexed token);

  /**
   * @dev Emitted when a price feed is updated for a token.
   * @param token The address of the token.
   * @param oldFeed The address of the old price feed.
   * @param newFeed The address of the new price feed.
   */
  event FeedUpdated(address indexed token, address indexed oldFeed, address indexed newFeed);

  // Custom Errors
  error ZeroAddress();
  error InvalidAddress();
  error InvalidOperation();
  error InvalidAmount();
  error StalePrice();
  error InvalidInput();
  error DuplicateEntry();

  /**
   * @notice Gets the latest price data for a specified token.
   * @param token The address of the token.
   * @return isValid Whether the price is valid.
   * @return price The last updated price (18 decimals).
   */
  function getPrice(address token) external view returns (bool isValid, uint256 price);

  /**
   *  @notice gets the token decimals from the feed
   */
  function getFeedDecimals(address token) external view returns (uint8 decimals);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

interface IDEXRouter {
    function swapExactTokensForTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    function swapExactETHForTokens(
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external payable returns (uint256[] memory amounts);

    function swapExactTokensForETH(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);

    // function getAmountsOut(
    //     uint256 amountIn,
    //     address[] calldata path
    // ) external view returns (uint256[] memory amounts);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

interface IStrategy {
    
    error ErrorNotPermitted();
    error ErrorZeroAmount();
    error ErrorZeroAddress();
    error ErrorCannotRecoverToken();
    error ZeroGroupId();

    function withdrawToTreasury(uint256 _diff) external returns (bool);
    function emergencyWithdraw() external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/extensions/ERC4626.sol)

pragma solidity ^0.8.0;

import "../ERC20Upgradeable.sol";
import "../utils/SafeERC20Upgradeable.sol";
import "../../../interfaces/IERC4626Upgradeable.sol";
import "../../../utils/math/MathUpgradeable.sol";
import {Initializable} from "../../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the ERC4626 "Tokenized Vault Standard" as defined in
 * https://eips.ethereum.org/EIPS/eip-4626[EIP-4626].
 *
 * This extension allows the minting and burning of "shares" (represented using the ERC20 inheritance) in exchange for
 * underlying "assets" through standardized {deposit}, {mint}, {redeem} and {burn} workflows. This contract extends
 * the ERC20 standard. Any additional extensions included along it would affect the "shares" token represented by this
 * contract and not the "assets" token which is an independent contract.
 *
 * [CAUTION]
 * ====
 * In empty (or nearly empty) ERC-4626 vaults, deposits are at high risk of being stolen through frontrunning
 * with a "donation" to the vault that inflates the price of a share. This is variously known as a donation or inflation
 * attack and is essentially a problem of slippage. Vault deployers can protect against this attack by making an initial
 * deposit of a non-trivial amount of the asset, such that price manipulation becomes infeasible. Withdrawals may
 * similarly be affected by slippage. Users can protect against this attack as well as unexpected slippage in general by
 * verifying the amount received is as expected, using a wrapper that performs these checks such as
 * https://github.com/fei-protocol/ERC4626#erc4626router-and-base[ERC4626Router].
 *
 * Since v4.9, this implementation uses virtual assets and shares to mitigate that risk. The `_decimalsOffset()`
 * corresponds to an offset in the decimal representation between the underlying asset's decimals and the vault
 * decimals. This offset also determines the rate of virtual shares to virtual assets in the vault, which itself
 * determines the initial exchange rate. While not fully preventing the attack, analysis shows that the default offset
 * (0) makes it non-profitable, as a result of the value being captured by the virtual shares (out of the attacker's
 * donation) matching the attacker's expected gains. With a larger offset, the attack becomes orders of magnitude more
 * expensive than it is profitable. More details about the underlying math can be found
 * xref:erc4626.adoc#inflation-attack[here].
 *
 * The drawback of this approach is that the virtual shares do capture (a very small) part of the value being accrued
 * to the vault. Also, if the vault experiences losses, the users try to exit the vault, the virtual shares and assets
 * will cause the first user to exit to experience reduced losses in detriment to the last users that will experience
 * bigger losses. Developers willing to revert back to the pre-v4.9 behavior just need to override the
 * `_convertToShares` and `_convertToAssets` functions.
 *
 * To learn more, check out our xref:ROOT:erc4626.adoc[ERC-4626 guide].
 * ====
 *
 * _Available since v4.7._
 */
abstract contract ERC4626Upgradeable is Initializable, ERC20Upgradeable, IERC4626Upgradeable {
    using MathUpgradeable for uint256;

    IERC20Upgradeable private _asset;
    uint8 private _underlyingDecimals;

    /**
     * @dev Set the underlying asset contract. This must be an ERC20-compatible contract (ERC20 or ERC777).
     */
    function __ERC4626_init(IERC20Upgradeable asset_) internal onlyInitializing {
        __ERC4626_init_unchained(asset_);
    }

    function __ERC4626_init_unchained(IERC20Upgradeable asset_) internal onlyInitializing {
        (bool success, uint8 assetDecimals) = _tryGetAssetDecimals(asset_);
        _underlyingDecimals = success ? assetDecimals : 18;
        _asset = asset_;
    }

    /**
     * @dev Attempts to fetch the asset decimals. A return value of false indicates that the attempt failed in some way.
     */
    function _tryGetAssetDecimals(IERC20Upgradeable asset_) private view returns (bool, uint8) {
        (bool success, bytes memory encodedDecimals) = address(asset_).staticcall(
            abi.encodeWithSelector(IERC20MetadataUpgradeable.decimals.selector)
        );
        if (success && encodedDecimals.length >= 32) {
            uint256 returnedDecimals = abi.decode(encodedDecimals, (uint256));
            if (returnedDecimals <= type(uint8).max) {
                return (true, uint8(returnedDecimals));
            }
        }
        return (false, 0);
    }

    /**
     * @dev Decimals are computed by adding the decimal offset on top of the underlying asset's decimals. This
     * "original" value is cached during construction of the vault contract. If this read operation fails (e.g., the
     * asset has not been created yet), a default of 18 is used to represent the underlying asset's decimals.
     *
     * See {IERC20Metadata-decimals}.
     */
    function decimals() public view virtual override(IERC20MetadataUpgradeable, ERC20Upgradeable) returns (uint8) {
        return _underlyingDecimals + _decimalsOffset();
    }

    /** @dev See {IERC4626-asset}. */
    function asset() public view virtual override returns (address) {
        return address(_asset);
    }

    /** @dev See {IERC4626-totalAssets}. */
    function totalAssets() public view virtual override returns (uint256) {
        return _asset.balanceOf(address(this));
    }

    /** @dev See {IERC4626-convertToShares}. */
    function convertToShares(uint256 assets) public view virtual override returns (uint256) {
        return _convertToShares(assets, MathUpgradeable.Rounding.Down);
    }

    /** @dev See {IERC4626-convertToAssets}. */
    function convertToAssets(uint256 shares) public view virtual override returns (uint256) {
        return _convertToAssets(shares, MathUpgradeable.Rounding.Down);
    }

    /** @dev See {IERC4626-maxDeposit}. */
    function maxDeposit(address) public view virtual override returns (uint256) {
        return type(uint256).max;
    }

    /** @dev See {IERC4626-maxMint}. */
    function maxMint(address) public view virtual override returns (uint256) {
        return type(uint256).max;
    }

    /** @dev See {IERC4626-maxWithdraw}. */
    function maxWithdraw(address owner) public view virtual override returns (uint256) {
        return _convertToAssets(balanceOf(owner), MathUpgradeable.Rounding.Down);
    }

    /** @dev See {IERC4626-maxRedeem}. */
    function maxRedeem(address owner) public view virtual override returns (uint256) {
        return balanceOf(owner);
    }

    /** @dev See {IERC4626-previewDeposit}. */
    function previewDeposit(uint256 assets) public view virtual override returns (uint256) {
        return _convertToShares(assets, MathUpgradeable.Rounding.Down);
    }

    /** @dev See {IERC4626-previewMint}. */
    function previewMint(uint256 shares) public view virtual override returns (uint256) {
        return _convertToAssets(shares, MathUpgradeable.Rounding.Up);
    }

    /** @dev See {IERC4626-previewWithdraw}. */
    function previewWithdraw(uint256 assets) public view virtual override returns (uint256) {
        return _convertToShares(assets, MathUpgradeable.Rounding.Up);
    }

    /** @dev See {IERC4626-previewRedeem}. */
    function previewRedeem(uint256 shares) public view virtual override returns (uint256) {
        return _convertToAssets(shares, MathUpgradeable.Rounding.Down);
    }

    /** @dev See {IERC4626-deposit}. */
    function deposit(uint256 assets, address receiver) public virtual override returns (uint256) {
        require(assets <= maxDeposit(receiver), "ERC4626: deposit more than max");

        uint256 shares = previewDeposit(assets);
        _deposit(_msgSender(), receiver, assets, shares);

        return shares;
    }

    /** @dev See {IERC4626-mint}.
     *
     * As opposed to {deposit}, minting is allowed even if the vault is in a state where the price of a share is zero.
     * In this case, the shares will be minted without requiring any assets to be deposited.
     */
    function mint(uint256 shares, address receiver) public virtual override returns (uint256) {
        require(shares <= maxMint(receiver), "ERC4626: mint more than max");

        uint256 assets = previewMint(shares);
        _deposit(_msgSender(), receiver, assets, shares);

        return assets;
    }

    /** @dev See {IERC4626-withdraw}. */
    function withdraw(uint256 assets, address receiver, address owner) public virtual override returns (uint256) {
        require(assets <= maxWithdraw(owner), "ERC4626: withdraw more than max");

        uint256 shares = previewWithdraw(assets);
        _withdraw(_msgSender(), receiver, owner, assets, shares);

        return shares;
    }

    /** @dev See {IERC4626-redeem}. */
    function redeem(uint256 shares, address receiver, address owner) public virtual override returns (uint256) {
        require(shares <= maxRedeem(owner), "ERC4626: redeem more than max");

        uint256 assets = previewRedeem(shares);
        _withdraw(_msgSender(), receiver, owner, assets, shares);

        return assets;
    }

    /**
     * @dev Internal conversion function (from assets to shares) with support for rounding direction.
     */
    function _convertToShares(uint256 assets, MathUpgradeable.Rounding rounding) internal view virtual returns (uint256) {
        return assets.mulDiv(totalSupply() + 10 ** _decimalsOffset(), totalAssets() + 1, rounding);
    }

    /**
     * @dev Internal conversion function (from shares to assets) with support for rounding direction.
     */
    function _convertToAssets(uint256 shares, MathUpgradeable.Rounding rounding) internal view virtual returns (uint256) {
        return shares.mulDiv(totalAssets() + 1, totalSupply() + 10 ** _decimalsOffset(), rounding);
    }

    /**
     * @dev Deposit/mint common workflow.
     */
    function _deposit(address caller, address receiver, uint256 assets, uint256 shares) internal virtual {
        // If _asset is ERC777, `transferFrom` can trigger a reentrancy BEFORE the transfer happens through the
        // `tokensToSend` hook. On the other hand, the `tokenReceived` hook, that is triggered after the transfer,
        // calls the vault, which is assumed not malicious.
        //
        // Conclusion: we need to do the transfer before we mint so that any reentrancy would happen before the
        // assets are transferred and before the shares are minted, which is a valid state.
        // slither-disable-next-line reentrancy-no-eth
        SafeERC20Upgradeable.safeTransferFrom(_asset, caller, address(this), assets);
        _mint(receiver, shares);

        emit Deposit(caller, receiver, assets, shares);
    }

    /**
     * @dev Withdraw/redeem common workflow.
     */
    function _withdraw(
        address caller,
        address receiver,
        address owner,
        uint256 assets,
        uint256 shares
    ) internal virtual {
        if (caller != owner) {
            _spendAllowance(owner, caller, shares);
        }

        // If _asset is ERC777, `transfer` can trigger a reentrancy AFTER the transfer happens through the
        // `tokensReceived` hook. On the other hand, the `tokensToSend` hook, that is triggered before the transfer,
        // calls the vault, which is assumed not malicious.
        //
        // Conclusion: we need to do the transfer after the burn so that any reentrancy would happen after the
        // shares are burned and after the assets are transferred, which is a valid state.
        _burn(owner, shares);
        SafeERC20Upgradeable.safeTransfer(_asset, receiver, assets);

        emit Withdraw(caller, receiver, owner, assets, shares);
    }

    function _decimalsOffset() internal view virtual returns (uint8) {
        return 0;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20Upgradeable.sol";
import "./extensions/IERC20MetadataUpgradeable.sol";
import "../../utils/ContextUpgradeable.sol";
import {Initializable} from "../../proxy/utils/Initializable.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20Upgradeable is Initializable, ContextUpgradeable, IERC20Upgradeable, IERC20MetadataUpgradeable {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    function __ERC20_init(string memory name_, string memory symbol_) internal onlyInitializing {
        __ERC20_init_unchained(name_, symbol_);
    }

    function __ERC20_init_unchained(string memory name_, string memory symbol_) internal onlyInitializing {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(address from, address to, uint256 amount) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(address from, address to, uint256 amount) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(address owner, address spender, uint256 amount) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 amount) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(address from, address to, uint256 amount) internal virtual {}

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[45] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC4626.sol)

pragma solidity ^0.8.0;

import "../token/ERC20/IERC20Upgradeable.sol";
import "../token/ERC20/extensions/IERC20MetadataUpgradeable.sol";

/**
 * @dev Interface of the ERC4626 "Tokenized Vault Standard", as defined in
 * https://eips.ethereum.org/EIPS/eip-4626[ERC-4626].
 *
 * _Available since v4.7._
 */
interface IERC4626Upgradeable is IERC20Upgradeable, IERC20MetadataUpgradeable {
    event Deposit(address indexed sender, address indexed owner, uint256 assets, uint256 shares);

    event Withdraw(
        address indexed sender,
        address indexed receiver,
        address indexed owner,
        uint256 assets,
        uint256 shares
    );

    /**
     * @dev Returns the address of the underlying token used for the Vault for accounting, depositing, and withdrawing.
     *
     * - MUST be an ERC-20 token contract.
     * - MUST NOT revert.
     */
    function asset() external view returns (address assetTokenAddress);

    /**
     * @dev Returns the total amount of the underlying asset that is “managed” by Vault.
     *
     * - SHOULD include any compounding that occurs from yield.
     * - MUST be inclusive of any fees that are charged against assets in the Vault.
     * - MUST NOT revert.
     */
    function totalAssets() external view returns (uint256 totalManagedAssets);

    /**
     * @dev Returns the amount of shares that the Vault would exchange for the amount of assets provided, in an ideal
     * scenario where all the conditions are met.
     *
     * - MUST NOT be inclusive of any fees that are charged against assets in the Vault.
     * - MUST NOT show any variations depending on the caller.
     * - MUST NOT reflect slippage or other on-chain conditions, when performing the actual exchange.
     * - MUST NOT revert.
     *
     * NOTE: This calculation MAY NOT reflect the “per-user” price-per-share, and instead should reflect the
     * “average-user’s” price-per-share, meaning what the average user should expect to see when exchanging to and
     * from.
     */
    function convertToShares(uint256 assets) external view returns (uint256 shares);

    /**
     * @dev Returns the amount of assets that the Vault would exchange for the amount of shares provided, in an ideal
     * scenario where all the conditions are met.
     *
     * - MUST NOT be inclusive of any fees that are charged against assets in the Vault.
     * - MUST NOT show any variations depending on the caller.
     * - MUST NOT reflect slippage or other on-chain conditions, when performing the actual exchange.
     * - MUST NOT revert.
     *
     * NOTE: This calculation MAY NOT reflect the “per-user” price-per-share, and instead should reflect the
     * “average-user’s” price-per-share, meaning what the average user should expect to see when exchanging to and
     * from.
     */
    function convertToAssets(uint256 shares) external view returns (uint256 assets);

    /**
     * @dev Returns the maximum amount of the underlying asset that can be deposited into the Vault for the receiver,
     * through a deposit call.
     *
     * - MUST return a limited value if receiver is subject to some deposit limit.
     * - MUST return 2 ** 256 - 1 if there is no limit on the maximum amount of assets that may be deposited.
     * - MUST NOT revert.
     */
    function maxDeposit(address receiver) external view returns (uint256 maxAssets);

    /**
     * @dev Allows an on-chain or off-chain user to simulate the effects of their deposit at the current block, given
     * current on-chain conditions.
     *
     * - MUST return as close to and no more than the exact amount of Vault shares that would be minted in a deposit
     *   call in the same transaction. I.e. deposit should return the same or more shares as previewDeposit if called
     *   in the same transaction.
     * - MUST NOT account for deposit limits like those returned from maxDeposit and should always act as though the
     *   deposit would be accepted, regardless if the user has enough tokens approved, etc.
     * - MUST be inclusive of deposit fees. Integrators should be aware of the existence of deposit fees.
     * - MUST NOT revert.
     *
     * NOTE: any unfavorable discrepancy between convertToShares and previewDeposit SHOULD be considered slippage in
     * share price or some other type of condition, meaning the depositor will lose assets by depositing.
     */
    function previewDeposit(uint256 assets) external view returns (uint256 shares);

    /**
     * @dev Mints shares Vault shares to receiver by depositing exactly amount of underlying tokens.
     *
     * - MUST emit the Deposit event.
     * - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the
     *   deposit execution, and are accounted for during deposit.
     * - MUST revert if all of assets cannot be deposited (due to deposit limit being reached, slippage, the user not
     *   approving enough underlying tokens to the Vault contract, etc).
     *
     * NOTE: most implementations will require pre-approval of the Vault with the Vault’s underlying asset token.
     */
    function deposit(uint256 assets, address receiver) external returns (uint256 shares);

    /**
     * @dev Returns the maximum amount of the Vault shares that can be minted for the receiver, through a mint call.
     * - MUST return a limited value if receiver is subject to some mint limit.
     * - MUST return 2 ** 256 - 1 if there is no limit on the maximum amount of shares that may be minted.
     * - MUST NOT revert.
     */
    function maxMint(address receiver) external view returns (uint256 maxShares);

    /**
     * @dev Allows an on-chain or off-chain user to simulate the effects of their mint at the current block, given
     * current on-chain conditions.
     *
     * - MUST return as close to and no fewer than the exact amount of assets that would be deposited in a mint call
     *   in the same transaction. I.e. mint should return the same or fewer assets as previewMint if called in the
     *   same transaction.
     * - MUST NOT account for mint limits like those returned from maxMint and should always act as though the mint
     *   would be accepted, regardless if the user has enough tokens approved, etc.
     * - MUST be inclusive of deposit fees. Integrators should be aware of the existence of deposit fees.
     * - MUST NOT revert.
     *
     * NOTE: any unfavorable discrepancy between convertToAssets and previewMint SHOULD be considered slippage in
     * share price or some other type of condition, meaning the depositor will lose assets by minting.
     */
    function previewMint(uint256 shares) external view returns (uint256 assets);

    /**
     * @dev Mints exactly shares Vault shares to receiver by depositing amount of underlying tokens.
     *
     * - MUST emit the Deposit event.
     * - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the mint
     *   execution, and are accounted for during mint.
     * - MUST revert if all of shares cannot be minted (due to deposit limit being reached, slippage, the user not
     *   approving enough underlying tokens to the Vault contract, etc).
     *
     * NOTE: most implementations will require pre-approval of the Vault with the Vault’s underlying asset token.
     */
    function mint(uint256 shares, address receiver) external returns (uint256 assets);

    /**
     * @dev Returns the maximum amount of the underlying asset that can be withdrawn from the owner balance in the
     * Vault, through a withdraw call.
     *
     * - MUST return a limited value if owner is subject to some withdrawal limit or timelock.
     * - MUST NOT revert.
     */
    function maxWithdraw(address owner) external view returns (uint256 maxAssets);

    /**
     * @dev Allows an on-chain or off-chain user to simulate the effects of their withdrawal at the current block,
     * given current on-chain conditions.
     *
     * - MUST return as close to and no fewer than the exact amount of Vault shares that would be burned in a withdraw
     *   call in the same transaction. I.e. withdraw should return the same or fewer shares as previewWithdraw if
     *   called
     *   in the same transaction.
     * - MUST NOT account for withdrawal limits like those returned from maxWithdraw and should always act as though
     *   the withdrawal would be accepted, regardless if the user has enough shares, etc.
     * - MUST be inclusive of withdrawal fees. Integrators should be aware of the existence of withdrawal fees.
     * - MUST NOT revert.
     *
     * NOTE: any unfavorable discrepancy between convertToShares and previewWithdraw SHOULD be considered slippage in
     * share price or some other type of condition, meaning the depositor will lose assets by depositing.
     */
    function previewWithdraw(uint256 assets) external view returns (uint256 shares);

    /**
     * @dev Burns shares from owner and sends exactly assets of underlying tokens to receiver.
     *
     * - MUST emit the Withdraw event.
     * - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the
     *   withdraw execution, and are accounted for during withdraw.
     * - MUST revert if all of assets cannot be withdrawn (due to withdrawal limit being reached, slippage, the owner
     *   not having enough shares, etc).
     *
     * Note that some implementations will require pre-requesting to the Vault before a withdrawal may be performed.
     * Those methods should be performed separately.
     */
    function withdraw(uint256 assets, address receiver, address owner) external returns (uint256 shares);

    /**
     * @dev Returns the maximum amount of Vault shares that can be redeemed from the owner balance in the Vault,
     * through a redeem call.
     *
     * - MUST return a limited value if owner is subject to some withdrawal limit or timelock.
     * - MUST return balanceOf(owner) if owner is not subject to any withdrawal limit or timelock.
     * - MUST NOT revert.
     */
    function maxRedeem(address owner) external view returns (uint256 maxShares);

    /**
     * @dev Allows an on-chain or off-chain user to simulate the effects of their redeemption at the current block,
     * given current on-chain conditions.
     *
     * - MUST return as close to and no more than the exact amount of assets that would be withdrawn in a redeem call
     *   in the same transaction. I.e. redeem should return the same or more assets as previewRedeem if called in the
     *   same transaction.
     * - MUST NOT account for redemption limits like those returned from maxRedeem and should always act as though the
     *   redemption would be accepted, regardless if the user has enough shares, etc.
     * - MUST be inclusive of withdrawal fees. Integrators should be aware of the existence of withdrawal fees.
     * - MUST NOT revert.
     *
     * NOTE: any unfavorable discrepancy between convertToAssets and previewRedeem SHOULD be considered slippage in
     * share price or some other type of condition, meaning the depositor will lose assets by redeeming.
     */
    function previewRedeem(uint256 shares) external view returns (uint256 assets);

    /**
     * @dev Burns exactly shares from owner and sends assets of underlying tokens to receiver.
     *
     * - MUST emit the Withdraw event.
     * - MAY support an additional flow in which the underlying tokens are owned by the Vault contract before the
     *   redeem execution, and are accounted for during redeem.
     * - MUST revert if all of shares cannot be redeemed (due to withdrawal limit being reached, slippage, the owner
     *   not having enough shares, etc).
     *
     * NOTE: some implementations will require pre-requesting to the Vault before a withdrawal may be performed.
     * Those methods should be performed separately.
     */
    function redeem(uint256 shares, address receiver, address owner) external returns (uint256 assets);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20Upgradeable.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20MetadataUpgradeable is IERC20Upgradeable {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}