Contract Source Code:

// File: contracts\openzeppelin\contracts\utils\ReentrancyGuard.sol
// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)
pragma solidity ^0.8.19;
/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.
    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;
    uint256 private _status;
    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();
    constructor() {
        _status = NOT_ENTERED;
    }
    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }
    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }
        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }
    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }
    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}
// File: contracts\openzeppelin\contracts\utils\Context.sol
pragma solidity ^0.8.19;
/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}
// File: contracts\openzeppelin\contracts\access\Ownable.sol
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)
pragma solidity ^0.8.19;
/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;
    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);
    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);
    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }
    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }
    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }
    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }
    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }
    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}
// File: contracts/sdaemon0x/games/sdaemon0xHeadOrTails.sol
pragma solidity ^0.8.19;
interface ISdaemon0x_GameTreasury {
    function compute_game_price(uint256 amount) external view returns (uint256, uint256);
    function betGame(address player, uint256 amount) external;
    function payPlayer(address player, uint256 amount) external;
}
interface sdeamon0xRandomItf 
{
    function beginRandom(sdeamon0xRandomCallback CA) external returns (uint256);
}
interface sdeamon0xRandomCallback 
{
    function onRandomCallback(uint256 uid, uint256 res) external;
}
/**
    Head or Tails game.
*/
contract sdaemon0xHeadOrTails is ReentrancyGuard, Ownable, sdeamon0xRandomCallback {
    constructor() Ownable(0x88524E752144C15dc1a12BA3978c2d700dc97498) {}
    
    uint256 public base_price = 50000 * 10 ** 18;
    ISdaemon0x_GameTreasury public treasury;
    sdeamon0xRandomItf public randomizer;
    function setBasePrice(uint256 price) external onlyOwner {
        base_price = price; 
    }
    
    function setGameTreasury(address addr) external onlyOwner {
        treasury = ISdaemon0x_GameTreasury(addr); 
    }
    
    function setRandomizer(address addr) external onlyOwner {
        randomizer = sdeamon0xRandomItf(addr);
    }
    
    mapping(uint256 => address) public uid_player;
    mapping(address => uint256) public player_uid;
    mapping(address => bool) public playing;
    mapping(address => bool) public games;
    function final_price() public view returns (uint256, uint256) {
         return treasury.compute_game_price(base_price);  
    }
    function play(bool face_) public nonReentrant returns (bool) {
        require(!playing[msg.sender]);
        playing[msg.sender] = true;
        treasury.betGame(msg.sender, base_price);
        uint256 uid = randomizer.beginRandom(this);
        uid_player[uid] = msg.sender;
        player_uid[msg.sender] = uid;
        games[msg.sender] = face_;
        return true;
    }
    struct SessionPlayed {
        address _player;        //the Player
        bool    _choice;        //the choice of the plyayer
        bool    _face;          //the result od random
    }        
    SessionPlayed[] public played_sessions;
    function getPlayedSessions() public view returns (uint256) {
        return played_sessions.length;
    }
    function onRandomCallback(uint256 uid, uint256 tos) external {
        require(msg.sender == address(randomizer));
        bool face = ((tos % 2) == 0);
        address player = uid_player[uid];
        bool choice_ = games[player];
        uid_player[uid] = address(0);
        player_uid[player] = 0;
        if (choice_ == face)
            treasury.payPlayer(player, base_price * 2);
        else 
            treasury.payPlayer(player, 0);
        playing[player] = false;    
        played_sessions.push(SessionPlayed(player, choice_, face));
    }
}