// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

/// ---- External Interfaces ----

interface IMasterFarmer {
    function getVeFive(address user, uint256 timestamp) external view returns (uint256);
}

interface IDeFiveRouter {
    function addLiquidity(
        address tokenA,
        address tokenB,
        uint256 amountADesired,
        uint256 amountBDesired,
        uint256 amountAMin,
        uint256 amountBMin,
        address to,
        uint256 deadline
    ) external returns (uint256 amountA, uint256 amountB, uint256 liquidity);
}

interface IFiveToken is IERC20 {
    function burn(uint256 amount) external;
}

// sub-factories
interface IBurnToFunTokenFactory {
    function createToken(
        string calldata name_,
        string calldata symbol_,
        address to,
        uint256 supply
    ) external returns (address tokenAddr);
}
interface IBurnToFunVestingFactory {
    function createVesting(
        address token,
        address beneficiary,
        uint256 cliffTime,
        uint256 vestingEndTime,
        uint256 totalAllocation
    ) external returns (address vestingAddr);
}

/// parent factory getters
interface IBurnToFunFactoryGetters {
    function tokenFactory() external view returns (address);
    function vestingFactory() external view returns (address);
}

interface IBurnToFunFactoryHooks {
    function recordUserContribution(address user, uint256 amount) external;
    function recordCreatorContribution(address creator, uint256 amount) external;
}

/// ---- Custom Errors ----
error AlreadyFinalized();
error NotFinalized();
error NotActive();
error AlreadyParticipated();
error OverHardCap();
error ExceedsMaxBurn();
error ClaimAlreadyMade();
error NoAllocation();
error NotRefundable();
error NoRefundAvailable();
error LPMintFailed();
error InvalidCreator();
error InvalidToken();
error InvalidMasterFarmer();
error InvalidRouter();
error InvalidFactory();
error ZeroAmount();
error NoTiersConfigured();
error Reentrancy();
error AlreadyInitialized();
error NotFactory();
error InvalidTokenomics();

// ERC20 interaction errors
error TransferFromFailed();
error TransferFailed();
error ApproveTokenFailed();
error ApproveFiveFailed();
error TransferVestingFailed();

/// @title BurnToFunCampaign
/// @notice Clone-initializable campaign. Users burn FIVE to receive allocation in a new token.
///         Token + vesting are created via external factories (addresses pulled from parent factory).
contract BurnToFunCampaign {
    uint256 private constant ONE = 1e18;
    uint256 private constant MAX_OTHER_PCT = 8e17;

    // ===== Tier System =====
    struct Tier {
        uint256 veFiveThreshold; // Required veFIVE to reach this tier
        uint256 maxBurnAmount; // Max FIVE allowed to burn
        uint256 bonusMultiplier; // Multiplier on base burn ratio (1e18 = 1.0x)
    }

    // ===== Campaign Lifecycle Status =====
    enum CampaignStatus {
        Pending,
        Burning,
        Finalizing,
        Claimable,
        Refundable
    }

    // ===== Events =====
    event Initialized(address factory, address creator, string name, string symbol, uint256 id);
    event Burn(address indexed user, uint256 amount, uint256 allocatedTokens, uint256 tierIndex);
    event TokensClaimed(address indexed user, uint256 amount);
    event RefundClaimed(address indexed user, uint256 amount);
    event TokenDeployed(address indexed token, uint256 totalSupply);
    event CreatorVestingDeployed(address indexed vestingContract, address indexed creator, uint256 amount);
    event DevAllocationSent(address factory, uint256 tokenAmount, uint256 fiveAmount);
    event LiquidityAdded(uint256 amountToken, uint256 amountFIVE, uint256 lpTokensReceived, address receiver);
    event RemainingFIVEBurned(uint256 amount);
    event Finalized();

    // ===== Storage (no immutables in clones) =====
    address public factory; // parent factory (deployer)
    address public fiveToken; // FIVE token
    address public masterFarmer; // veFIVE source
    address public deFiveRouter; // AMM router
    address public creator; // campaign creator

    // sub-factories pulled from parent at init
    address public tokenFactoryAddr; // BurnToFunTokenFactory
    address public vestingFactoryAddr; // BurnToFunVestingFactory

    uint256 public startTime;
    uint256 public endTime;
    uint256 public softCap;
    uint256 public hardCap;
    uint256 public creatorTokenPercent; // e18
    uint256 public devPercent; // e18
    uint256 public lpTokenPercent; // e18
    uint256 public lpFivePercent; // e18
    uint256 public campaignId;
    uint256 public baseBurnRatio; // e18
    uint256 public vestingCliff; // seconds offset
    uint256 public vestingEnd; // seconds offset

    string public tokenName;
    string public tokenSymbol;
    string public metadataURI; // e.g. ipfs://..., https://..., ar://...

    Tier[] public tiers;

    // ===== State =====
    mapping(address => uint256) public burned; // FIVE burned by user
    mapping(address => uint256) public allocatedTo; // Meme tokens allocated to user
    mapping(address => bool) public claimed; // Whether user has claimed their meme tokens

    uint256 public totalBurned;
    uint256 public usersAllocated;
    uint256 public contributorsCount; // <— NEW: number of unique participants
    bool public finalized;

    address public token; // Deployed token address
    address public creatorVesting; // Vesting contract for creator tokens

    // ---- init + tiny nonReentrant flag ----
    bool private _initialized;
    bool private _entered;

    // ===== Reentrancy Guard =====
    modifier nonReentrant() {
        if (_entered) revert Reentrancy();
        _entered = true;
        _;
        _entered = false;
    }

    // ---- Constructor ----
    /// @dev Lock the implementation so it cannot be initialized.
    constructor() {
        _initialized = true;
    }

    // ===== Initialize (called by factory on the freshly cloned proxy) =====
    function initialize(
        address _factory,
        address _creator,
        address _fiveToken,
        address _masterFarmer,
        address _deFiveRouter,
        uint256 _baseBurnRatio,
        uint256 _startTime,
        uint256 _endTime,
        uint256 _softCap,
        uint256 _hardCap,
        uint256 _creatorTokenPercent,
        uint256 _devPercent,
        uint256 _lpTokenPercent,
        uint256 _lpFivePercent,
        string calldata _tokenName,
        string calldata _tokenSymbol,
        string calldata _metadataURI,
        Tier[] calldata _tiers,
        uint256 _campaignId,
        uint256 _vestingCliff,
        uint256 _vestingEnd,
        bytes calldata _extraInitData
    ) external {
        if (_initialized) revert AlreadyInitialized();

        // Only the factory may initialize
        if (msg.sender != _factory) revert NotFactory();
        if (_factory == address(0) || msg.sender.code.length == 0) revert InvalidFactory();

        if (_creator == address(0)) revert InvalidCreator();
        if (_fiveToken == address(0) || _fiveToken.code.length == 0) revert InvalidToken();
        if (_masterFarmer == address(0) || _masterFarmer.code.length == 0) revert InvalidMasterFarmer();

        if (_deFiveRouter == address(0) || _deFiveRouter.code.length == 0) revert InvalidRouter();

        // sanity: tokenomics must leave room for users
        if (_creatorTokenPercent + _lpTokenPercent + _devPercent > MAX_OTHER_PCT) revert InvalidTokenomics();

        // FIVE-side safety: dev + LP(FIVE) must be <= 80%
        if (_devPercent + _lpFivePercent > MAX_OTHER_PCT) revert InvalidTokenomics();

        // pull sub-factories from parent
        address _tokenFactoryAddr = IBurnToFunFactoryGetters(_factory).tokenFactory();
        address _vestingFactoryAddr = IBurnToFunFactoryGetters(_factory).vestingFactory();
        if (_tokenFactoryAddr == address(0) || _vestingFactoryAddr == address(0)) revert InvalidFactory();

        if (_tiers.length == 0) revert NoTiersConfigured();
        if (_tiers[0].veFiveThreshold != 0) revert NoTiersConfigured(); // anchor baseline
        for (uint256 i = 1; i < _tiers.length; ) {
            if (_tiers[i].veFiveThreshold <= _tiers[i - 1].veFiveThreshold) revert NoTiersConfigured();
            unchecked {
                ++i;
            }
        }

        _extraInitData;
        factory = _factory;
        creator = _creator;
        fiveToken = _fiveToken;
        masterFarmer = _masterFarmer;
        deFiveRouter = _deFiveRouter;
        tokenFactoryAddr = _tokenFactoryAddr;
        vestingFactoryAddr = _vestingFactoryAddr;

        baseBurnRatio = _baseBurnRatio;
        startTime = _startTime;
        endTime = _endTime;
        softCap = _softCap;
        hardCap = _hardCap;
        creatorTokenPercent = _creatorTokenPercent;
        devPercent = _devPercent;
        lpTokenPercent = _lpTokenPercent;
        lpFivePercent = _lpFivePercent;
        campaignId = _campaignId;
        vestingCliff = _vestingCliff;
        vestingEnd = _vestingEnd;

        tokenName = _tokenName;
        tokenSymbol = _tokenSymbol;
        metadataURI = _metadataURI;

        for (uint256 i; i < _tiers.length; ) {
            tiers.push(_tiers[i]);
            unchecked {
                ++i;
            }
        }

        _initialized = true;
        emit Initialized(_factory, _creator, _tokenName, _tokenSymbol, _campaignId);
    }

    // ===== Main Burn Entry Point =====

    /// @notice Contribute FIVE to the campaign, receive meme token allocation
    function burn(uint256 amount) external nonReentrant {
        if (block.timestamp < startTime || block.timestamp > endTime) revert NotActive();
        if (finalized) revert AlreadyFinalized();
        if (burned[msg.sender] > 0) revert AlreadyParticipated();
        if (amount == 0) revert ZeroAmount();

        if (amount > hardCap - totalBurned) revert OverHardCap();

        (uint256 maxBurn, uint256 burnRatio, uint256 tierIndex) = getUserLimits(msg.sender);
        if (amount > maxBurn) revert ExceedsMaxBurn();

        uint256 allocated = (amount * burnRatio) / ONE;

        burned[msg.sender] = amount;
        allocatedTo[msg.sender] = allocated;
        unchecked {
            totalBurned += amount;
            usersAllocated += allocated;
        }

        bool ok = IERC20(fiveToken).transferFrom(msg.sender, address(this), amount);
        if (!ok) revert TransferFromFailed();

        // first and only contribution per user -> count it
        unchecked {
            contributorsCount += 1;
        }

        emit Burn(msg.sender, amount, allocated, tierIndex);
    }

    // ===== Finalization and Token Launch =====

    /// @notice Finalizes campaign: deploy token (via factory), add LP, deploy creator vesting.
    function finalize() external nonReentrant {
        if (finalized) revert AlreadyFinalized();

        if (block.timestamp < endTime) {
            // 99% threshold without multiplication overflow
            uint256 threshold = hardCap - (hardCap / 100);
            if (totalBurned < threshold) revert NotFinalized();
        }

        if (totalBurned >= softCap) {
            // live tokenomics from current allocations
            (
                uint256 totalSupply,
                uint256 creatorAlloc,
                uint256 devTokenAlloc,
                uint256 tokenLpAmount,
                ,
                uint256 devFiveAlloc,
                uint256 fiveLpAmount,

            ) = _projectedBreakdownInternal();

            // Deploy token clone (mint full supply to this campaign)
            address tokenAddr = IBurnToFunTokenFactory(tokenFactoryAddr).createToken(
                tokenName,
                tokenSymbol,
                address(this),
                totalSupply
            );
            token = tokenAddr;
            emit TokenDeployed(tokenAddr, totalSupply);

            // Creator vesting clone
            if (creatorAlloc > 0) {
                address vesting = IBurnToFunVestingFactory(vestingFactoryAddr).createVesting(
                    tokenAddr,
                    creator,
                    block.timestamp + vestingCliff,
                    block.timestamp + vestingEnd,
                    creatorAlloc
                );
                creatorVesting = vesting;

                bool okV = IERC20(tokenAddr).transfer(vesting, creatorAlloc);
                if (!okV) revert TransferVestingFailed();

                emit CreatorVestingDeployed(vesting, creator, creatorAlloc);
            }

            // dev allocation goes to factory (where the dev wallet can claim it)
            if (devTokenAlloc > 0 && devFiveAlloc > 0) {
                bool okT = IERC20(tokenAddr).transfer(factory, devTokenAlloc);
                if (!okT) revert TransferFailed();
                bool okF = IERC20(fiveToken).transfer(factory, devFiveAlloc);
                if (!okF) revert TransferFailed();
                emit DevAllocationSent(factory, devTokenAlloc, devFiveAlloc);
            }

            // approve exact
            bool okA = IERC20(tokenAddr).approve(deFiveRouter, tokenLpAmount);
            if (!okA) revert ApproveTokenFailed();
            bool okB = IERC20(fiveToken).approve(deFiveRouter, fiveLpAmount);
            if (!okB) revert ApproveFiveFailed();

            // call router
            (, , uint256 liquidity) = IDeFiveRouter(deFiveRouter).addLiquidity(
                tokenAddr,
                fiveToken,
                tokenLpAmount,
                fiveLpAmount,
                0,
                0,
                address(0),
                block.timestamp
            );
            if (liquidity == 0) revert LPMintFailed();

            // clear any residual allowance (defense-in-depth)
            uint256 remT = IERC20(tokenAddr).allowance(address(this), deFiveRouter);
            if (remT != 0) IERC20(tokenAddr).approve(deFiveRouter, 0);
            uint256 remF = IERC20(fiveToken).allowance(address(this), deFiveRouter);
            if (remF != 0) IERC20(fiveToken).approve(deFiveRouter, 0);

            emit LiquidityAdded(tokenLpAmount, fiveLpAmount, liquidity, address(0));

            // Burn leftover FIVE
            uint256 remainingFive = IERC20(fiveToken).balanceOf(address(this));
            if (remainingFive > 0) {
                IFiveToken(fiveToken).burn(remainingFive);
                emit RemainingFIVEBurned(remainingFive);
            }

            // record at factory
            IBurnToFunFactoryHooks(factory).recordCreatorContribution(creator, totalBurned);
        }

        finalized = true;
        emit Finalized();
    }

    // ===== Claim Functions =====

    function claim() external nonReentrant {
        if (!finalized) revert NotFinalized();
        if (totalBurned < softCap) revert NotRefundable();
        if (claimed[msg.sender]) revert ClaimAlreadyMade();

        uint256 allocation = allocatedTo[msg.sender];
        if (allocation == 0) revert NoAllocation();

        claimed[msg.sender] = true;

        bool ok = IERC20(token).transfer(msg.sender, allocation);
        if (!ok) revert TransferFailed();

        // record at factory
        uint256 burnedAmount = burned[msg.sender];
        IBurnToFunFactoryHooks(factory).recordUserContribution(msg.sender, burnedAmount);

        emit TokensClaimed(msg.sender, allocation);
    }

    function claimRefund() external nonReentrant {
        if (!finalized) revert NotFinalized();
        if (totalBurned >= softCap) revert NotRefundable();

        uint256 amount = burned[msg.sender];
        if (amount == 0) revert NoRefundAvailable();

        burned[msg.sender] = 0;

        bool ok = IERC20(fiveToken).transfer(msg.sender, amount);
        if (!ok) revert TransferFailed();

        emit RefundClaimed(msg.sender, amount);
    }

    // ===== Tier Logic =====

    function tiersLength() external view returns (uint256) {
        return tiers.length;
    }

    function getUserLimits(
        address user
    ) public view returns (uint256 maxBurn, uint256 userBurnRatio, uint256 tierIndex) {
        Tier[] storage t = tiers;
        uint256 len = t.length;
        if (len == 0) revert NoTiersConfigured();

        uint256 checkTime;
        unchecked {
            checkTime = endTime + 7 days;
        }

        uint256 ve = IMasterFarmer(masterFarmer).getVeFive(user, checkTime);
        uint256 base = baseBurnRatio;

        // Descend and return on first match
        for (uint256 i = len; i > 0; ) {
            Tier storage tr = t[i - 1];
            if (ve >= tr.veFiveThreshold) {
                tierIndex = i - 1;
                maxBurn = tr.maxBurnAmount;
                userBurnRatio = (base * tr.bonusMultiplier) / ONE;
                return (maxBurn, userBurnRatio, tierIndex);
            }
            unchecked {
                --i;
            }
        }
    }

    // ===== Real-time Supply Helpers =====

    /// @notice Projected total supply based on current allocations and tokenomics.
    function projectedTotalSupply() external view returns (uint256) {
        uint256 otherPct = creatorTokenPercent + lpTokenPercent + devPercent;
        return (usersAllocated * ONE) / (ONE - otherPct);
    }

    /// @notice Projected breakdown: (totalSupply, creatorAllocation, devTokenAllocation, devFiveAllocation, tokenLpAmount).
    function projectedBreakdown()
        external
        view
        returns (
            uint256 totalSupply,
            uint256 creatorAllocation,
            uint256 devTokenAllocation,
            uint256 tokenLpAmount,
            uint256 claimableAmount,
            uint256 devFiveAllocation,
            uint256 fiveLpAmount,
            uint256 burnableFive
        )
    {
        return _projectedBreakdownInternal();
    }

    function _projectedBreakdownInternal()
        internal
        view
        returns (
            uint256 totalSupply,
            uint256 creatorAllocation,
            uint256 devTokenAllocation,
            uint256 tokenLpAmount,
            uint256 claimableAmount,
            uint256 devFiveAllocation,
            uint256 fiveLpAmount,
            uint256 burnableFive
        )
    {
        uint256 otherPct = creatorTokenPercent + lpTokenPercent + devPercent;
        totalSupply = (usersAllocated * ONE) / (ONE - otherPct);
        creatorAllocation = (totalSupply * creatorTokenPercent) / ONE;
        devTokenAllocation = (totalSupply * devPercent) / ONE;
        devFiveAllocation = (totalBurned * devPercent) / ONE;
        fiveLpAmount = (totalBurned * lpFivePercent) / ONE;

        unchecked {
            tokenLpAmount = totalSupply - (usersAllocated + creatorAllocation + devTokenAllocation);
            claimableAmount = usersAllocated;
            burnableFive = totalBurned - (devFiveAllocation + fiveLpAmount);
        }
    }

    // ===== Status =====

    function getStatus() external view returns (CampaignStatus) {
        if (!finalized) {
            if (block.timestamp < startTime) return CampaignStatus.Pending;
            if (block.timestamp <= endTime) return CampaignStatus.Burning;
            return CampaignStatus.Finalizing;
        } else {
            return totalBurned >= softCap ? CampaignStatus.Claimable : CampaignStatus.Refundable;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

{
  "optimizer": {
    "enabled": true,
    "runs": 999
  },
  "viaIR": true,
  "metadata": {
    "bytecodeHash": "none",
    "useLiteralContent": true
  },
  "evmVersion": "paris",
  "outputSelection": {
    "*": {
      "*": [
        "evm.bytecode",
        "evm.deployedBytecode",
        "devdoc",
        "userdoc",
        "metadata",
        "abi"
      ]
    }
  }
}

[{"inputs":[],"stateMutability":"nonpayable","type":"constructor"},{"inputs":[],"name":"AlreadyFinalized","type":"error"},{"inputs":[],"name":"AlreadyInitialized","type":"error"},{"inputs":[],"name":"AlreadyParticipated","type":"error"},{"inputs":[],"name":"ApproveFiveFailed","type":"error"},{"inputs":[],"name":"ApproveTokenFailed","type":"error"},{"inputs":[],"name":"ClaimAlreadyMade","type":"error"},{"inputs":[],"name":"ExceedsMaxBurn","type":"error"},{"inputs":[],"name":"InvalidCreator","type":"error"},{"inputs":[],"name":"InvalidFactory","type":"error"},{"inputs":[],"name":"InvalidMasterFarmer","type":"error"},{"inputs":[],"name":"InvalidRouter","type":"error"},{"inputs":[],"name":"InvalidToken","type":"error"},{"inputs":[],"name":"InvalidTokenomics","type":"error"},{"inputs":[],"name":"LPMintFailed","type":"error"},{"inputs":[],"name":"NoAllocation","type":"error"},{"inputs":[],"name":"NoRefundAvailable","type":"error"},{"inputs":[],"name":"NoTiersConfigured","type":"error"},{"inputs":[],"name":"NotActive","type":"error"},{"inputs":[],"name":"NotFactory","type":"error"},{"inputs":[],"name":"NotFinalized","type":"error"},{"inputs":[],"name":"NotRefundable","type":"error"},{"inputs":[],"name":"OverHardCap","type":"error"},{"inputs":[],"name":"Reentrancy","type":"error"},{"inputs":[],"name":"TransferFailed","type":"error"},{"inputs":[],"name":"TransferFromFailed","type":"error"},{"inputs":[],"name":"TransferVestingFailed","type":"error"},{"inputs":[],"name":"ZeroAmount","type":"error"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"allocatedTokens","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"tierIndex","type":"uint256"}],"name":"Burn","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"vestingContract","type":"address"},{"indexed":true,"internalType":"address","name":"creator","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"CreatorVestingDeployed","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"factory","type":"address"},{"indexed":false,"internalType":"uint256","name":"tokenAmount","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"fiveAmount","type":"uint256"}],"name":"DevAllocationSent","type":"event"},{"anonymous":false,"inputs":[],"name":"Finalized","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"address","name":"factory","type":"address"},{"indexed":false,"internalType":"address","name":"creator","type":"address"},{"indexed":false,"internalType":"string","name":"name","type":"string"},{"indexed":false,"internalType":"string","name":"symbol","type":"string"},{"indexed":false,"internalType":"uint256","name":"id","type":"uint256"}],"name":"Initialized","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"amountToken","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"amountFIVE","type":"uint256"},{"indexed":false,"internalType":"uint256","name":"lpTokensReceived","type":"uint256"},{"indexed":false,"internalType":"address","name":"receiver","type":"address"}],"name":"LiquidityAdded","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"RefundClaimed","type":"event"},{"anonymous":false,"inputs":[{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"RemainingFIVEBurned","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"token","type":"address"},{"indexed":false,"internalType":"uint256","name":"totalSupply","type":"uint256"}],"name":"TokenDeployed","type":"event"},{"anonymous":false,"inputs":[{"indexed":true,"internalType":"address","name":"user","type":"address"},{"indexed":false,"internalType":"uint256","name":"amount","type":"uint256"}],"name":"TokensClaimed","type":"event"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"allocatedTo","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"baseBurnRatio","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"amount","type":"uint256"}],"name":"burn","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"burned","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"campaignId","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"claim","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"claimRefund","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[{"internalType":"address","name":"","type":"address"}],"name":"claimed","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"contributorsCount","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"creator","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"creatorTokenPercent","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"creatorVesting","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"deFiveRouter","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"devPercent","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"endTime","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"factory","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"finalize","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"finalized","outputs":[{"internalType":"bool","name":"","type":"bool"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"fiveToken","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"getStatus","outputs":[{"internalType":"enum BurnToFunCampaign.CampaignStatus","name":"","type":"uint8"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"user","type":"address"}],"name":"getUserLimits","outputs":[{"internalType":"uint256","name":"maxBurn","type":"uint256"},{"internalType":"uint256","name":"userBurnRatio","type":"uint256"},{"internalType":"uint256","name":"tierIndex","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"hardCap","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"address","name":"_factory","type":"address"},{"internalType":"address","name":"_creator","type":"address"},{"internalType":"address","name":"_fiveToken","type":"address"},{"internalType":"address","name":"_masterFarmer","type":"address"},{"internalType":"address","name":"_deFiveRouter","type":"address"},{"internalType":"uint256","name":"_baseBurnRatio","type":"uint256"},{"internalType":"uint256","name":"_startTime","type":"uint256"},{"internalType":"uint256","name":"_endTime","type":"uint256"},{"internalType":"uint256","name":"_softCap","type":"uint256"},{"internalType":"uint256","name":"_hardCap","type":"uint256"},{"internalType":"uint256","name":"_creatorTokenPercent","type":"uint256"},{"internalType":"uint256","name":"_devPercent","type":"uint256"},{"internalType":"uint256","name":"_lpTokenPercent","type":"uint256"},{"internalType":"uint256","name":"_lpFivePercent","type":"uint256"},{"internalType":"string","name":"_tokenName","type":"string"},{"internalType":"string","name":"_tokenSymbol","type":"string"},{"internalType":"string","name":"_metadataURI","type":"string"},{"components":[{"internalType":"uint256","name":"veFiveThreshold","type":"uint256"},{"internalType":"uint256","name":"maxBurnAmount","type":"uint256"},{"internalType":"uint256","name":"bonusMultiplier","type":"uint256"}],"internalType":"struct BurnToFunCampaign.Tier[]","name":"_tiers","type":"tuple[]"},{"internalType":"uint256","name":"_campaignId","type":"uint256"},{"internalType":"uint256","name":"_vestingCliff","type":"uint256"},{"internalType":"uint256","name":"_vestingEnd","type":"uint256"},{"internalType":"bytes","name":"_extraInitData","type":"bytes"}],"name":"initialize","outputs":[],"stateMutability":"nonpayable","type":"function"},{"inputs":[],"name":"lpFivePercent","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"lpTokenPercent","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"masterFarmer","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"metadataURI","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"projectedBreakdown","outputs":[{"internalType":"uint256","name":"totalSupply","type":"uint256"},{"internalType":"uint256","name":"creatorAllocation","type":"uint256"},{"internalType":"uint256","name":"devTokenAllocation","type":"uint256"},{"internalType":"uint256","name":"tokenLpAmount","type":"uint256"},{"internalType":"uint256","name":"claimableAmount","type":"uint256"},{"internalType":"uint256","name":"devFiveAllocation","type":"uint256"},{"internalType":"uint256","name":"fiveLpAmount","type":"uint256"},{"internalType":"uint256","name":"burnableFive","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"projectedTotalSupply","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"softCap","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"startTime","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[{"internalType":"uint256","name":"","type":"uint256"}],"name":"tiers","outputs":[{"internalType":"uint256","name":"veFiveThreshold","type":"uint256"},{"internalType":"uint256","name":"maxBurnAmount","type":"uint256"},{"internalType":"uint256","name":"bonusMultiplier","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"tiersLength","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"token","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"tokenFactoryAddr","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"tokenName","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"tokenSymbol","outputs":[{"internalType":"string","name":"","type":"string"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"totalBurned","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"usersAllocated","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"vestingCliff","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"vestingEnd","outputs":[{"internalType":"uint256","name":"","type":"uint256"}],"stateMutability":"view","type":"function"},{"inputs":[],"name":"vestingFactoryAddr","outputs":[{"internalType":"address","name":"","type":"address"}],"stateMutability":"view","type":"function"}]